[gentoo-commits] repo/gentoo:master commit in: app-text/cuneiform/

[David Seifert]

commit:     376733c6e79af63bc5d5a436cf8ef0d80d4a05f4
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 11 19:21:57 2017 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Feb 11 19:46:59 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=376733c6

app-text/cuneiform: Use sub-slot operators for imagemagick

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Closes: https://github.com/gentoo/gentoo/pull/3907

 app-text/cuneiform/cuneiform-1.1.0-r1.ebuild | 53 ---------------------------
 app-text/cuneiform/cuneiform-1.1.0-r2.ebuild | 54 ++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+), 53 deletions(-)

diff --git a/app-text/cuneiform/cuneiform-1.1.0-r1.ebuild b/app-text/cuneiform/cuneiform-1.1.0-r1.ebuild
deleted file mode 100644
index 42e1207449..0000000000
--- a/app-text/cuneiform/cuneiform-1.1.0-r1.ebuild
+++ /dev/null
@@ -1,53 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="4"
-inherit cmake-utils versionator
-
-PV_MAJ=$(get_version_component_range 1-2)
-MY_P=${PN}-linux-${PV}
-
-DESCRIPTION="An enterprise quality optical character recognition (OCR) engine by Cognitive Technologies"
-HOMEPAGE="https://launchpad.net/cuneiform-linux"
-SRC_URI="https://launchpad.net/${PN}-linux/${PV_MAJ}/${PV_MAJ}/+download/${MY_P}.tar.bz2"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-IUSE="debug +imagemagick graphicsmagick"
-
-REQUIRED_USE="^^ ( imagemagick graphicsmagick )"
-
-RDEPEND="imagemagick? ( media-gfx/imagemagick )
-		graphicsmagick? ( media-gfx/graphicsmagick )"
-DEPEND=">=dev-util/cmake-2.6.2
-	${RDEPEND}"
-
-DOCS="readme.txt"
-
-S=${WORKDIR}/${MY_P}
-
-src_prepare(){
-	epatch "${FILESDIR}/c-assert.diff"
-	epatch "${FILESDIR}/libm.diff"
-	if use graphicsmagick; then
-		epatch "${FILESDIR}/graphicsmagick.diff"
-	fi
-	# respect LDFLAGS
-	sed -i 's:\(set[(]CMAKE_SHARED_LINKER_FLAGS "[^"]*\):\1 $ENV{LDFLAGS}:' \
-		"${S}/cuneiform_src/CMakeLists.txt" || die "failed to sed for LDFLAGS"
-	# Fix automagic dependencies / linking
-	if ! use imagemagick; then
-		sed -i "s:find_package(ImageMagick COMPONENTS Magick++):#DONOTFIND:" \
-			"${S}/cuneiform_src/CMakeLists.txt" \
-		|| die "Sed for ImageMagick automagic dependency failed."
-	fi
-}
-
-src_install() {
-	#default
-	cmake-utils_src_install
-	doman "${FILESDIR}/${PN}.1"
-}

diff --git a/app-text/cuneiform/cuneiform-1.1.0-r2.ebuild b/app-text/cuneiform/cuneiform-1.1.0-r2.ebuild
new file mode 100644
index 0000000000..564bbd04d8
--- /dev/null
+++ b/app-text/cuneiform/cuneiform-1.1.0-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils versionator
+
+PV_MAJ=$(get_version_component_range 1-2)
+MY_P=${PN}-linux-${PV}
+
+DESCRIPTION="An enterprise quality OCR engine by Cognitive Technologies"
+HOMEPAGE="https://launchpad.net/cuneiform-linux"
+SRC_URI="https://launchpad.net/${PN}-linux/${PV_MAJ}/${PV_MAJ}/+download/${MY_P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="debug graphicsmagick"
+
+RDEPEND="
+	!graphicsmagick? ( media-gfx/imagemagick:= )
+	graphicsmagick? ( media-gfx/graphicsmagick:= )"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( readme.txt )
+PATCHES=(
+	"${FILESDIR}/c-assert.diff"
+	"${FILESDIR}/libm.diff"
+)
+
+src_prepare(){
+	use graphicsmagick && PATCHES+=( "${FILESDIR}/graphicsmagick.diff" )
+	cmake-utils_src_prepare
+
+	# respect LDFLAGS
+	sed -i 's:\(set[(]CMAKE_SHARED_LINKER_FLAGS "[^"]*\):\1 $ENV{LDFLAGS}:' \
+		cuneiform_src/CMakeLists.txt || die "failed to sed for LDFLAGS"
+
+	# Fix automagic dependencies / linking
+	if use graphicsmagick; then
+		sed -i "s:find_package(ImageMagick COMPONENTS Magick++):#DONOTFIND:" \
+			cuneiform_src/CMakeLists.txt \
+			|| die "Sed for ImageMagick automagic dependency failed."
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+	doman "${FILESDIR}/${PN}.1"
+}