[gentoo-commits] repo/gentoo:master commit in: mail-filter/libdkim/

[Anthony G. Basile]

commit:     6619a0e3b86fbb8949961deb3c863a511bd8e188
Author:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 11 00:15:35 2015 +0000
Commit:     Anthony G. Basile <blueness <AT> gentoo <DOT> org>
CommitDate: Sun Oct 11 00:15:35 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6619a0e3

mail-filter/libdkim: add libressl support

Package-Manager: portage-2.2.20.1

 mail-filter/libdkim/libdkim-1.0.21-r3.ebuild | 54 ++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/mail-filter/libdkim/libdkim-1.0.21-r3.ebuild b/mail-filter/libdkim/libdkim-1.0.21-r3.ebuild
new file mode 100644
index 0000000..4fac329
--- /dev/null
+++ b/mail-filter/libdkim/libdkim-1.0.21-r3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+AUTOTOOLS_AUTORECONF=1
+AUTOTOOLS_IN_SOURCE_BUILD=1
+
+inherit autotools-utils eutils toolchain-funcs
+
+DESCRIPTION="DomainKeys Identified Mail library from Alt-N Inc"
+HOMEPAGE="http://libdkim.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.zip"
+
+LICENSE="Apache-2.0 yahoo-patent-license-1.2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl static-libs"
+
+DEPEND="
+	!libressl? ( dev-libs/openssl:0 )
+	libressl? ( dev-libs/libressl )
+	app-arch/unzip"
+RDEPEND="
+	!mail-filter/libdkim-exim
+	dev-libs/openssl"
+
+S="${WORKDIR}/${PN}/src"
+
+src_prepare() {
+	ecvs_clean
+	cp  "${FILESDIR}"/debianize/* "${S}"
+	epatch "${FILESDIR}"/patches/*.patch
+	epatch "${FILESDIR}"/libdkim-extra-options.patch
+
+	# Bug 476772
+	if ! use static-libs; then
+		 sed -i \
+			-e '/^TARGETS/s/libdkim.a//' \
+			-e '/install -m 644 libdkim.a/d' \
+			Makefile.in || die 'sed on Makefile.in failed'
+	fi
+
+	# Bug 476770
+	tc-export AR
+
+	autotools-utils_src_prepare
+}
+
+src_install() {
+	autotools-utils_src_install
+	dodoc ../README
+}