[gentoo-commits] gentoo-x86 commit in dev-python/ipython: metadata.xml ipython-0.13.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    12/07/30 22:57:46

  Modified:             metadata.xml ChangeLog
  Added:                ipython-0.13.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha120/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 dev-python/ipython/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/metadata.xml?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/metadata.xml?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/metadata.xml?r1=1.9&r2=1.10

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/ipython/metadata.xml,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- metadata.xml	28 Jun 2012 11:31:18 -0000	1.9
+++ metadata.xml	30 Jul 2012 22:57:45 -0000	1.10
@@ -40,9 +40,10 @@
 * 他のPython言語プログラムを組み込むのが簡単。
 * pdbデバッガとprofilerへの統合アクセス。
 </longdescription>
-	<use>
-		<flag name="matplotlib">Add support for <pkg>dev-python/matplotlib</pkg></flag>
-		<flag name="mongodb">Enable support for MongoDB via <pkg>dev-python/pymongo</pkg></flag>
-		<flag name="notebook">Install requirements for the web notebook based on <pkg>www-servers/tornado</pkg></flag>
-	</use>
+<use>
+  <flag name="matplotlib">Add support for <pkg>dev-python/matplotlib</pkg></flag>
+  <flag name="mongodb">Enable support for MongoDB via <pkg>dev-python/pymongo</pkg></flag>
+  <flag name="notebook">Install requirements for the web notebook based on <pkg>www-servers/tornado</pkg></flag>
+  <flag name="octave">Enable octave bridge via <pkg>dev-python/oct2py</pkg></flag>
+</use>
 </pkgmetadata>



1.96                 dev-python/ipython/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?rev=1.96&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?rev=1.96&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?r1=1.95&r2=1.96

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v
retrieving revision 1.95
retrieving revision 1.96
diff -u -r1.95 -r1.96
--- ChangeLog	28 Jun 2012 11:31:18 -0000	1.95
+++ ChangeLog	30 Jul 2012 22:57:45 -0000	1.96
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/ipython
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.95 2012/06/28 11:31:18 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.96 2012/07/30 22:57:45 bicatali Exp $
+
+*ipython-0.13 (30 Jul 2012)
+
+  30 Jul 2012; Sébastien Fabbro <bicatali@g.o> +ipython-0.13.ebuild,
+  metadata.xml:
+  Version bump
 
   28 Jun 2012; Justin Lecher <jlec@g.o> ipython-0.12-r1.ebuild,
   ipython-0.12.1.ebuild, metadata.xml:
@@ -408,4 +414,3 @@
 
   13 Jun 2003; Alastair Tse <liquidx@g.o> ipython-0.4.0.ebuild:
   New Package. Ebuild Submitted by John Landahl <john@×××××××.org>.
-



1.1                  dev-python/ipython/ipython-0.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-0.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-0.13.ebuild?rev=1.1&content-type=text/plain

Index: ipython-0.13.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-0.13.ebuild,v 1.1 2012/07/30 22:57:45 bicatali Exp $

EAPI=4

# python eclass cruft
PYTHON_DEPEND="*:2.6"
PYTHON_USE_WITH="readline sqlite"
PYTHON_MODNAME="IPython"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.5 *-jython *-pypy-*"

inherit distutils elisp-common eutils virtualx

DESCRIPTION="Advanced interactive shell for Python"
HOMEPAGE="http://ipython.org/"
SRC_URI="http://archive.ipython.org/release/${PV}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc emacs examples matplotlib mongodb notebook octave
	qt4 +smp test wxwidgets"

CDEPEND="dev-python/decorator
	|| ( dev-python/argparse =dev-lang/python-2.7* >=dev-lang/python-3.2 )
	dev-python/pexpect
	dev-python/pyparsing
	dev-python/simplegeneric
	emacs? ( app-emacs/python-mode virtual/emacs )
	matplotlib? ( dev-python/matplotlib )
	mongodb? ( dev-python/pymongo )
	octave? ( dev-python/oct2py )
	smp? ( dev-python/pyzmq )
	wxwidgets? ( dev-python/wxpython )"
RDEPEND="${CDEPEND}
	notebook? ( >=www-servers/tornado-2.1
			dev-python/pygments
			dev-python/pyzmq )
	qt4? ( || ( dev-python/PyQt4 dev-python/pyside )
			dev-python/pygments
			dev-python/pyzmq )"
DEPEND="${CDEPEND}
	test? ( dev-python/nose )"

src_prepare() {
	distutils_src_prepare
	epatch "${FILESDIR}"/${PN}-0.12-globalpath.patch

	# fix for gentoo python scripts
	sed -i \
		-e "/ipython_cmd/s/ipython3/ipython/g" \
		IPython/frontend/terminal/console/tests/test_console.py \
		IPython/lib/irunner.py \
		IPython/testing/tools.py || die

	sed -i \
		-e "s/find_scripts(True, suffix='3')/find_scripts(True)/" \
		setup.py || die

	# disable failing tests
	sed -i \
		-e 's/test_pylab_import_all_disabled/_&/' \
		-e 's/test_pylab_import_all_enabled/_&/' \
		IPython/lib/tests/test_irunner_pylab_magic.py || die

	# fix gentoo installation directory for documentation
	sed -i \
		-e "/docdirbase  = pjoin/s/ipython/${PF}/" \
		-e "/pjoin(docdirbase,'manual')/s/manual/html/" \
		setupbase.py || die "sed failed"

	if ! use doc; then
		sed -i \
			-e "/(pjoin(docdirbase, 'extensions'), igridhelpfiles),/d" \
			-e 's/ + manual_files//' \
			setupbase.py || die
	fi

	if ! use examples; then
		sed -i \
			-e 's/+ example_files//' \
			setupbase.py || die
	fi
}

src_compile() {
	distutils_src_compile
	use emacs && elisp-compile docs/emacs/ipython.el
}

src_test() {
	# https://github.com/ipython/ipython/issues/2083
	unset PYTHONWARNINGS

	if use mongodb; then
		mkdir -p "${T}/mongo.db"
		mongod --dbpath "${T}/mongo.db" --fork --logpath "${T}/mongo.log"
	fi

	testing() {
		"$(PYTHON)" setup.py \
			build -b "build-${PYTHON_ABI}" \
			install --root="${T}/tests-${PYTHON_ABI}" > /dev/null || die
		# Initialize ~/.ipython directory.
		PATH="${T}/tests-${PYTHON_ABI}${EPREFIX}/usr/bin:${PATH}" \
			PYTHONPATH="${T}/tests-${PYTHON_ABI}${EPREFIX}$(python_get_sitedir)" \
			ipython <<< "" > /dev/null || return 1
		# Run tests (-v for more verbosity).
		PATH="${T}/tests-${PYTHON_ABI}${EPREFIX}/usr/bin:${PATH}" \
			PYTHONPATH="${T}/tests-${PYTHON_ABI}${EPREFIX}$(python_get_sitedir)" \
			iptest -v || return 1
	}
	VIRTUALX_COMMAND="python_execute_function" virtualmake testing

	use mongodb && killall -u "$(id -nu)" mongod
}

src_install() {
	distutils_src_install
	if use emacs; then
		pushd docs/emacs > /dev/null
		elisp-install ${PN} ${PN}.el*
		elisp-site-file-install "${FILESDIR}"/62ipython-gentoo.el
		popd > /dev/null
	fi
}

pkg_postinst() {
	distutils_pkg_postinst
	use emacs && elisp-site-regen
}

pkg_postrm() {
	distutils_pkg_postrm
	use emacs && elisp-site-regen
}