[gentoo-commits] repo/proj/guru:dev commit in: games-fps/gzdoom/

[William Breathitt Gray]

commit:     5ad016ab948bcf49f443c2f4182f185e6e357782
Author:     William Breathitt Gray <vilhelm.gray <AT> gmail <DOT> com>
AuthorDate: Thu May  2 13:00:54 2019 +0000
Commit:     William Breathitt Gray <vilhelm.gray <AT> gmail <DOT> com>
CommitDate: Fri May 10 11:06:57 2019 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=5ad016ab

games-fps/gzdoom: New package

Package-Manager: Portage-2.3.65, Repoman-2.3.12
Signed-off-by: William Breathitt Gray <vilhelm.gray <AT> gmail.com>

 games-fps/gzdoom/Manifest            |  1 +
 games-fps/gzdoom/gzdoom-4.1.1.ebuild | 69 ++++++++++++++++++++++++++++++++++++
 games-fps/gzdoom/metadata.xml        | 19 ++++++++++
 3 files changed, 89 insertions(+)

diff --git a/games-fps/gzdoom/Manifest b/games-fps/gzdoom/Manifest
new file mode 100644
index 0000000..21c3976
--- /dev/null
+++ b/games-fps/gzdoom/Manifest
@@ -0,0 +1 @@
+DIST gzdoom-4.1.1.tar.gz 13008847 BLAKE2B ac2bddbcc618148ed9de15dfe9105d1f3b9f319496b995d2af06834eb1349415ab3ee48beaa3e1acac04c81152e32bc89b71ac53576cf7789c1471a29a0a5339 SHA512 649e8bbf7f7f669d1bda13f1ab654428b69fa3e03a97eefb2ff1e996dbf62c66df72dddee9b8c139664ce5374ffbcdd8a10d1c4e3d0e6e65848ed5660b547d34

diff --git a/games-fps/gzdoom/gzdoom-4.1.1.ebuild b/games-fps/gzdoom/gzdoom-4.1.1.ebuild
new file mode 100644
index 0000000..2ebc1c2
--- /dev/null
+++ b/games-fps/gzdoom/gzdoom-4.1.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils desktop xdg
+
+DESCRIPTION="GZDoom - a modder-friendly OpenGL source port based on the DOOM engine"
+HOMEPAGE="https://zdoom.org"
+SRC_URI="https://github.com/coelckers/${PN}/archive/g${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD BZIP2 DUMB-0.9.2 GPL-3 LGPL-3 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk openal openmp midi"
+
+DEPEND="
+	app-arch/bzip2
+	dev-util/glslang
+	media-libs/libsdl2[opengl]
+	sys-libs/zlib
+	virtual/jpeg:0
+	gtk? ( x11-libs/gtk+:* )
+	midi? ( media-sound/wildmidi )
+	openal? (
+		media-libs/libsndfile
+		media-libs/openal
+		media-sound/mpg123
+	)"
+RDEPEND="
+	${DEPEND}
+	midi? (
+		media-sound/fluidsynth
+		media-sound/timidity++
+	)"
+
+S="${WORKDIR}/${PN}-g${PV}"
+
+src_prepare() {
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_DOCS_PATH="${EPREFIX}/usr/share/doc/${P}/docs"
+		-DNO_GTK="$(usex !gtk)"
+		-DNO_OPENAL="$(usex !openal)"
+		-DNO_OPENMP="$(usex !openmp)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	newicon src/posix/zdoom.xpm "${PN}.xpm"
+	make_desktop_entry "${PN}" "GZDoom" "${PN}" "Game;ActionGame"
+	cmake-utils_src_install
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}

diff --git a/games-fps/gzdoom/metadata.xml b/games-fps/gzdoom/metadata.xml
new file mode 100644
index 0000000..6a4872a
--- /dev/null
+++ b/games-fps/gzdoom/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<longdescription lang="en">
+		GZDoom is a modder-friendly OpenGL source port based on the DOOM engine
+	</longdescription>
+	<maintainer type="person">
+		<email>vilhelm.gray@×××××.com</email>
+		<name>William Breathitt Gray</name>
+	</maintainer>
+	<use>
+		<flag name="midi">Enables MIDI support</flag>
+	</use>
+	<upstream>
+		<bugs-to>https://forum.zdoom.org/viewforum.php?f=2</bugs-to>
+		<doc lang="en">https://zdoom.org</doc>
+		<remote-id type="github">coelckers/gzdoom</remote-id>
+	</upstream>
+</pkgmetadata>