[gentoo-commits] gentoo-x86 commit in net-fs/nfs-utils: nfs-utils-1.2.3.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      10/10/08 19:48:08

  Modified:             ChangeLog
  Added:                nfs-utils-1.2.3.ebuild
  Log:
  Version bump #339288.
  
  (Portage version: 2.2_rc86/cvs/Linux x86_64)

Revision  Changes    Path
1.174                net-fs/nfs-utils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/ChangeLog?rev=1.174&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/ChangeLog?rev=1.174&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/ChangeLog?r1=1.173&r2=1.174

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/ChangeLog,v
retrieving revision 1.173
retrieving revision 1.174
diff -u -r1.173 -r1.174
--- ChangeLog	19 Sep 2010 22:39:27 -0000	1.173
+++ ChangeLog	8 Oct 2010 19:48:08 -0000	1.174
@@ -1,6 +1,11 @@
 # ChangeLog for net-fs/nfs-utils
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/ChangeLog,v 1.173 2010/09/19 22:39:27 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/ChangeLog,v 1.174 2010/10/08 19:48:08 vapier Exp $
+
+*nfs-utils-1.2.3 (08 Oct 2010)
+
+  08 Oct 2010; Mike Frysinger <vapier@g.o> +nfs-utils-1.2.3.ebuild:
+  Version bump #339288.
 
   19 Sep 2010; Mike Frysinger <vapier@g.o> nfs-utils-1.2.2-r2.ebuild:
   Fix multilib dir handling with backed up /var/lib/nfs.



1.1                  net-fs/nfs-utils/nfs-utils-1.2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.2.3.ebuild?rev=1.1&content-type=text/plain

Index: nfs-utils-1.2.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.2.3.ebuild,v 1.1 2010/10/08 19:48:08 vapier Exp $

EAPI="2"

inherit eutils flag-o-matic multilib

DESCRIPTION="NFS client and server daemons"
HOMEPAGE="http://linux-nfs.org/"
SRC_URI="mirror://sourceforge/nfs/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="caps ipv6 kerberos +nfsv3 +nfsv4 tcpd elibc_glibc"
RESTRICT="test" #315573

# kth-krb doesn't provide the right include
# files, and nfs-utils doesn't build against heimdal either,
# so don't depend on virtual/krb.
# (04 Feb 2005 agriffis)
DEPEND_COMMON="tcpd? ( sys-apps/tcp-wrappers )
	caps? ( sys-libs/libcap )
	sys-libs/e2fsprogs-libs
	net-nds/rpcbind
	net-libs/libtirpc
	nfsv4? (
		>=dev-libs/libevent-1.0b
		>=net-libs/libnfsidmap-0.21-r1
		kerberos? (
			net-libs/librpcsecgss
			net-libs/libgssglue
			net-libs/libtirpc[kerberos]
			app-crypt/mit-krb5
		)
	)"
RDEPEND="${DEPEND_COMMON} !net-nds/portmap"
# util-linux dep is to prevent man-page collision
DEPEND="${DEPEND_COMMON}
	>=sys-apps/util-linux-2.12r-r7"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.1.4-mtab-sym.patch
	epatch "${FILESDIR}"/${PN}-1.1.4-no-exec.patch
}

src_configure() {
	econf \
		--with-statedir=/var/lib/nfs \
		--enable-tirpc \
		$(use_with tcpd tcp-wrappers) \
		$(use_enable nfsv3) \
		$(use_enable nfsv4) \
		$(use_enable ipv6) \
		$(use_enable caps) \
		$(use nfsv4 && use_enable kerberos gss || echo "--disable-gss")
}

src_install() {
	emake DESTDIR="${D}" install || die

	# Don't overwrite existing xtab/etab, install the original
	# versions somewhere safe...  more info in pkg_postinst
	keepdir /var/lib/nfs/{,sm,sm.bak}
	mv "${D}"/var/lib "${D}"/usr/$(get_libdir) || die

	# Install some client-side binaries in /sbin
	dodir /sbin
	mv "${D}"/usr/sbin/rpc.statd "${D}"/sbin/ || die

	dodoc ChangeLog README
	docinto linux-nfs ; dodoc linux-nfs/*

	insinto /etc
	doins "${FILESDIR}"/exports

	local f list="" opt_need=""
	if use nfsv4 ; then
		opt_need="rpc.idmapd"
		list="${list} rpc.idmapd rpc.pipefs"
		use kerberos && list="${list} rpc.gssd rpc.svcgssd"
	fi
	for f in nfs nfsmount rpc.statd ${list} ; do
		newinitd "${FILESDIR}"/${f}.initd ${f} || die "doinitd ${f}"
	done
	newconfd "${FILESDIR}"/nfs.confd nfs
	dosed "/^NFS_NEEDED_SERVICES=/s:=.*:=\"${opt_need}\":" /etc/conf.d/nfs #234132

	# uClibc doesn't provide rpcgen like glibc, so lets steal it from nfs-utils
	if ! use elibc_glibc ; then
		dobin tools/rpcgen/rpcgen || die "rpcgen"
		newdoc tools/rpcgen/README README.rpcgen
	fi
}

pkg_postinst() {
	# Install default xtab and friends if there's none existing.  In
	# src_install we put them in /usr/lib/nfs for safe-keeping, but
	# the daemons actually use the files in /var/lib/nfs.  #30486
	local f
	for f in "${ROOT}"/usr/$(get_libdir)/nfs/*; do
		[[ -e ${ROOT}/var/lib/nfs/${f##*/} ]] && continue
		einfo "Copying default ${f##*/} from /usr/$(get_libdir)/nfs to /var/lib/nfs"
		cp -pPR "${f}" "${ROOT}"/var/lib/nfs/
	done
}