[gentoo-commits] gentoo-x86 commit in dev-util/global: ChangeLog global-5.9.2.ebuild

[Jeroen Roovers (jer)]

jer         10/09/01 13:40:39

  Modified:             ChangeLog
  Added:                global-5.9.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2_rc72/cvs/Linux i686)

Revision  Changes    Path
1.64                 dev-util/global/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	19 Aug 2010 16:57:52 -0000	1.63
+++ ChangeLog	1 Sep 2010 13:40:39 -0000	1.64
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/global
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.63 2010/08/19 16:57:52 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.64 2010/09/01 13:40:39 jer Exp $
+
+*global-5.9.2 (01 Sep 2010)
+
+  01 Sep 2010; Jeroen Roovers <jer@g.o> +global-5.9.2.ebuild,
+  +files/global-5.9.2-localstatedir.patch:
+  Version bump.
 
   19 Aug 2010; Jeroen Roovers <jer@g.o> metadata.xml:
   Remove arfrever.



1.1                  dev-util/global/global-5.9.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/global-5.9.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/global-5.9.2.ebuild?rev=1.1&content-type=text/plain

Index: global-5.9.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/global/global-5.9.2.ebuild,v 1.1 2010/09/01 13:40:39 jer Exp $

EAPI="3"

inherit autotools elisp-common

DESCRIPTION="GNU Global is a tag system to find the locations of a specified object in various sources."
HOMEPAGE="http://www.gnu.org/software/global/global.html"
SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.gz"
LICENSE="GPL-3"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="doc vim emacs"

RDEPEND="vim? ( || ( app-editors/vim app-editors/gvim ) )
	emacs? ( virtual/emacs )"
DEPEND="${DEPEND}
	doc? ( app-text/texi2html sys-apps/texinfo )"

SITEFILE="50gtags-gentoo.el"

src_prepare() {
	epatch "${FILESDIR}"/${P}-localstatedir.patch
	eautoreconf
}

src_compile() {
	if use doc; then
		texi2pdf -q -o doc/global.pdf doc/global.texi
		texi2html -o doc/global.html doc/global.texi
	fi

	if use emacs; then
		elisp-compile *.el || die "elisp-compile failed"
	fi

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	if use doc; then
		dohtml doc/global.html
		[[ -f doc/global.pdf ]] && dodoc doc/global.pdf
	fi

	dodoc AUTHORS FAQ NEWS README THANKS

	insinto /etc
	doins gtags.conf

	if use vim; then
		insinto /usr/share/vim/vimfiles/plugin
		doins gtags.vim
	fi

	if use emacs; then
		elisp-install gtags *.{el,elc}
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}