[gentoo-commits] gentoo-x86 commit in media-video/gnome-mplayer: metadata.xml ChangeLog gnome-mplayer-1.0.5_beta1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/11/18 15:01:34

  Modified:             metadata.xml ChangeLog
  Added:                gnome-mplayer-1.0.5_beta1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha73/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  media-video/gnome-mplayer/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	29 Aug 2009 16:51:16 -0000	1.4
+++ metadata.xml	18 Nov 2011 15:01:34 -0000	1.5
@@ -5,4 +5,7 @@
   <maintainer>
     <email>media-video@g.o</email>
   </maintainer>
+  <use>
+    <flag name='dconf'>Use dconf backend for settings</flag>
+  </use>
 </pkgmetadata>



1.65                 media-video/gnome-mplayer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	23 Oct 2011 12:06:07 -0000	1.64
+++ ChangeLog	18 Nov 2011 15:01:34 -0000	1.65
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/gnome-mplayer
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.64 2011/10/23 12:06:07 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/ChangeLog,v 1.65 2011/11/18 15:01:34 ssuominen Exp $
+
+*gnome-mplayer-1.0.5_beta1 (18 Nov 2011)
+
+  18 Nov 2011; Samuli Suominen <ssuominen@g.o>
+  +gnome-mplayer-1.0.5_beta1.ebuild:
+  Version bump.
 
   23 Oct 2011; Markus Meier <maekke@g.o> gnome-mplayer-1.0.4.ebuild:
   x86 stable, bug #386957



1.1                  media-video/gnome-mplayer/gnome-mplayer-1.0.5_beta1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.5_beta1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.5_beta1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-mplayer-1.0.5_beta1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/gnome-mplayer/gnome-mplayer-1.0.5_beta1.ebuild,v 1.1 2011/11/18 15:01:34 ssuominen Exp $

EAPI=4
inherit fdo-mime gnome2-utils

MY_P=${PN}-${PV/_beta/b}

DESCRIPTION="A GTK+ interface to MPlayer"
HOMEPAGE="http://code.google.com/p/gnome-mplayer/"
SRC_URI="http://${PN}.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="alsa +dbus dconf gnome ipod libnotify musicbrainz pulseaudio"

COMMON_DEPEND=">=dev-libs/glib-2.26:2
	>=media-libs/gmtk-${PV}[dconf=]
	x11-libs/gtk+:3
	x11-libs/libX11
	x11-libs/libXScrnSaver
	alsa? ( media-libs/alsa-lib )
	dbus? ( >=dev-libs/dbus-glib-0.92 )
	gnome? ( gnome-base/nautilus )
	ipod? ( >=media-libs/libgpod-0.7 )
	libnotify? ( x11-libs/libnotify )
	musicbrainz? ( net-misc/curl
		>=media-libs/musicbrainz-3 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.14 )"
RDEPEND="${COMMON_DEPEND}
	|| ( >=media-video/mplayer-1.0_rc4_p20100101[ass] media-video/mplayer2[ass] )
	gnome? ( gnome-base/gvfs )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig
	sys-devel/gettext"

DOCS="ChangeLog README DOCS/*.txt DOCS/tech/*.txt"

S=${WORKDIR}/${MY_P}

src_configure() {
	# FIXME: The only reason why --without-gpm-new-method is passed is lack of testing.
	econf \
		--enable-gtk3 \
		$(use_enable gnome nautilus) \
		--with-gio \
		$(use_with dbus) \
		$(use_with alsa) \
		$(use_with pulseaudio) \
		$(use_with libnotify) \
		$(use_with ipod libgpod) \
		$(use_with musicbrainz libmusicbrainz3) \
		--without-gpm-new-method \
		--without-gpm-old-method
}

src_install() {
	default
	rm -rf "${ED}"usr/share/doc/${PN}

	if use dconf; then
		insinto /usr/share/glib-2.0/schemas
		doins apps.*.xml || die
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
	gnome2_schemas_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
	gnome2_schemas_update --uninstall
}