[gentoo-commits] gentoo-x86 commit in sci-electronics/eagle: ChangeLog eagle-5.1.0.ebuild eagle-5.2.0.ebuild eagle-4.16_p1.ebuild

[Joe Sapp (nixphoeni)]

nixphoeni    08/10/02 02:43:18

  Modified:             ChangeLog eagle-5.1.0.ebuild
  Added:                eagle-5.2.0.ebuild
  Removed:              eagle-4.16_p1.ebuild
  Log:
  Revision bump and cleanup of old ebuilds.  Also modified the warning at the end of installation to be a little more severe per UPDATE_en.
  (Portage version: 2.2_rc9/cvs/Linux 2.6.22-ck1 x86_64)

Revision  Changes    Path
1.14                 sci-electronics/eagle/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/eagle/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/eagle/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/eagle/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-electronics/eagle/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	17 Jul 2008 00:12:09 -0000	1.13
+++ ChangeLog	2 Oct 2008 02:43:17 -0000	1.14
@@ -1,6 +1,15 @@
 # ChangeLog for sci-electronics/eagle
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-electronics/eagle/ChangeLog,v 1.13 2008/07/17 00:12:09 nixphoeni Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/eagle/ChangeLog,v 1.14 2008/10/02 02:43:17 nixphoeni Exp $
+
+*eagle-5.2.0 (02 Oct 2008)
+
+  02 Oct 2008; Joe Sapp <nixphoeni@g.o> -eagle-4.16_p1.ebuild,
+  eagle-5.1.0.ebuild, +eagle-5.2.0.ebuild:
+  Revision bump. Also modified the warning at the end of installation to be
+  a little more severe per UPDATE_en.
+  Thanks to Alex <nabrozidhs@×××××.com> on bug #235380 for notifying me.
+  Cleaned up old ebuilds a little too.
 
   17 Jul 2008; Joe Sapp <nixphoeni@g.o> ChangeLog:
   Revised ebuild for eagle version 5, which uses a new packaging system and



1.2                  sci-electronics/eagle/eagle-5.1.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/eagle/eagle-5.1.0.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/eagle/eagle-5.1.0.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/eagle/eagle-5.1.0.ebuild?r1=1.1&r2=1.2

Index: eagle-5.1.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-electronics/eagle/eagle-5.1.0.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- eagle-5.1.0.ebuild	17 Jul 2008 00:12:09 -0000	1.1
+++ eagle-5.1.0.ebuild	2 Oct 2008 02:43:17 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-electronics/eagle/eagle-5.1.0.ebuild,v 1.1 2008/07/17 00:12:09 nixphoeni Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/eagle/eagle-5.1.0.ebuild,v 1.2 2008/10/02 02:43:17 nixphoeni Exp $
 
 inherit eutils
 
@@ -81,7 +81,11 @@
 	elog "Run \`env-update && source /etc/profile\` from within \${ROOT}"
 	elog "now to set up the correct paths."
 	elog "You must first run eagle as root to invoke product registration."
-	elog
-	elog "Please read /usr/share/doc/${PF}/UPDATE_${MY_LANG} if you are upgrading from 4.xx."
+	echo
+	ewarn "Due to some necessary changes in the data structure, once you edit"
+	ewarn "a file with version 5.x you will no longer be able to edit it"
+	ewarn "with versions prior to 5.0!"
+	ewarn
+	ewarn "Please read /usr/share/doc/${PF}/UPDATE_${MY_LANG} if you are upgrading from 4.xx."
 
 }



1.1                  sci-electronics/eagle/eagle-5.2.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/eagle/eagle-5.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-electronics/eagle/eagle-5.2.0.ebuild?rev=1.1&content-type=text/plain

Index: eagle-5.2.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/eagle/eagle-5.2.0.ebuild,v 1.1 2008/10/02 02:43:17 nixphoeni Exp $

inherit eutils

DESCRIPTION="EAGLE Layout Editor"
HOMEPAGE="http://www.cadsoft.de"

KEYWORDS="~amd64 ~x86"
IUSE="linguas_de doc"
LICENSE="cadsoft"
RESTRICT="strip"
SLOT="0"

# Cadsoft has used the suffix "_p" in the past which we translate to "r"
MY_PV=${PV/_p/r}

SRC_URI="ftp://ftp.cadsoft.de/pub/program/${PV%\.[0-9]}/${PN}-lin-${MY_PV}.run"

RDEPEND="sys-libs/glibc
	x11-libs/libXext
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp"

# Append ${PV} since that's what upstream installs to
INSTALLDIR="/opt/eagle-${PV}"
case "${LINGUAS}" in
	*de*)
		MY_LANG="de";;
	*)
		MY_LANG="en";;
esac
# Mandatory documentation being installed
DOCS="README_${MY_LANG} UPDATE_${MY_LANG} library_${MY_LANG}.txt"

src_unpack() {

	# Extract the built-in .tar.bz2 file starting at __DATA__
	sed  -e '1,/^__DATA__$/d' "${DISTDIR}/${A}" | tar xj || die "unpacking failed"

}

src_install() {

	cd "${S}"
	dodir ${INSTALLDIR}
	# Copy all to INSTALLDIR
	cp -r . "${D}"/${INSTALLDIR}

	# Install wrapper (suppressing leading tabs)
	# see bug #188368 or http://www.cadsoft.de/faq.htm#17040701
	exeinto /usr/bin
	newexe "${FILESDIR}/eagle_wrapper_script" eagle
	# Finally, append the path of the eagle binary respecting INSTALLDIR and any
	# arguments passed to the script (thanks Denilson)
	echo "${INSTALLDIR}/bin/eagle" '"$@"' >> "${D}/usr/bin/eagle"

	# Install the documentation
	cd doc
	dodoc ${DOCS}
	# Install extra documentation if requested
	use doc && dodoc elektro-tutorial.pdf manual_${MY_LANG}.pdf tutorial_${MY_LANG}.pdf
	doman eagle.1
	# Remove docs left in INSTALLDIR
	rm -rf "${D}${INSTALLDIR}/doc/*"
	cd ..

	echo -e "ROOTPATH=${INSTALLDIR}/bin\nPRELINK_PATH_MASK=${INSTALLDIR}" > "${S}/90eagle"
	doenvd "${S}/90eagle"

	# Create desktop entry
	doicon bin/${PN}icon50.png
	make_desktop_entry "${ROOT}/usr/bin/eagle" ${PN} ${PN}icon50.png "Graphics;Electronics"

}

pkg_postinst() {

	elog "Run \`env-update && source /etc/profile\` from within \${ROOT}"
	elog "now to set up the correct paths."
	elog "You must first run eagle as root to invoke product registration."
	echo
	ewarn "Due to some necessary changes in the data structure, once you edit"
	ewarn "a file with version 5.x you will no longer be able to edit it"
	ewarn "with versions prior to 5.0!"
	ewarn
	ewarn "Please read /usr/share/doc/${PF}/UPDATE_${MY_LANG} if you are upgrading from 4.xx."
}