[gentoo-commits] gentoo-x86 commit in x11-libs/libdrm: libdrm-2.4.59.ebuild ChangeLog

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    15/01/29 16:51:02

  Modified:             ChangeLog
  Added:                libdrm-2.4.59.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x2324E7B566DF2611!)

Revision  Changes    Path
1.273                x11-libs/libdrm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.273&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.273&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?r1=1.272&r2=1.273

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v
retrieving revision 1.272
retrieving revision 1.273
diff -u -r1.272 -r1.273
--- ChangeLog	9 Jan 2015 20:53:43 -0000	1.272
+++ ChangeLog	29 Jan 2015 16:51:02 -0000	1.273
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/libdrm
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.272 2015/01/09 20:53:43 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.273 2015/01/29 16:51:02 chithanh Exp $
+
+*libdrm-2.4.59 (29 Jan 2015)
+
+  29 Jan 2015; Chí-Thanh Christopher Nguyễn <chithanh@g.o>
+  +libdrm-2.4.59.ebuild:
+  Version bump.
 
   09 Jan 2015; Tobias Klausmann <klausman@g.o> libdrm-2.4.58.ebuild:
   Stable on alpha, bug 513736



1.1                  x11-libs/libdrm/libdrm-2.4.59.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.59.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.59.ebuild?rev=1.1&content-type=text/plain

Index: libdrm-2.4.59.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/libdrm-2.4.59.ebuild,v 1.1 2015/01/29 16:51:02 chithanh Exp $

EAPI=5

XORG_MULTILIB=yes
inherit xorg-2

DESCRIPTION="X.Org libdrm library"
HOMEPAGE="http://dri.freedesktop.org/"
if [[ ${PV} = 9999* ]]; then
	EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"
else
	SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
fi

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
VIDEO_CARDS="exynos freedreno intel nouveau omap radeon tegra vmware"
for card in ${VIDEO_CARDS}; do
	IUSE_VIDEO_CARDS+=" video_cards_${card}"
done

IUSE="${IUSE_VIDEO_CARDS} libkms"
RESTRICT="test" # see bug #236845

RDEPEND=">=dev-libs/libpthread-stubs-0.3-r1:=[${MULTILIB_USEDEP}]
	video_cards_intel? ( >=x11-libs/libpciaccess-0.13.1-r1:=[${MULTILIB_USEDEP}] )
	abi_x86_32? ( !app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}"

PATCHES=(
	"${FILESDIR}"/${PN}-2.4.58-solaris.patch
)

src_prepare() {
	if [[ ${PV} = 9999* ]]; then
		# tests are restricted, no point in building them
		sed -ie 's/tests //' "${S}"/Makefile.am
	fi
	xorg-2_src_prepare
}

src_configure() {
	XORG_CONFIGURE_OPTIONS=(
		--enable-udev
		$(use_enable video_cards_exynos exynos-experimental-api)
		$(use_enable video_cards_freedreno freedreno)
		$(use_enable video_cards_intel intel)
		$(use_enable video_cards_nouveau nouveau)
		$(use_enable video_cards_omap omap-experimental-api)
		$(use_enable video_cards_radeon radeon)
		$(use_enable video_cards_tegra tegra-experimental-api)
		$(use_enable video_cards_vmware vmwgfx)
		$(use_enable libkms)
	)
	xorg-2_src_configure
}