[gentoo-commits] gentoo-x86 commit in www-apps/dokuwiki: ChangeLog dokuwiki-20101107a.ebuild

[Lance Albertson (ramereth)]

ramereth    11/02/28 02:55:56

  Modified:             ChangeLog
  Added:                dokuwiki-20101107a.ebuild
  Log:
  Version bump, resolves #354549
  
  (Portage version: 2.1.9.25/cvs/Linux x86_64)

Revision  Changes    Path
1.49                 www-apps/dokuwiki/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	9 Nov 2010 22:17:08 -0000	1.48
+++ ChangeLog	28 Feb 2011 02:55:56 -0000	1.49
@@ -1,6 +1,14 @@
 # ChangeLog for www-apps/dokuwiki
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/ChangeLog,v 1.48 2010/11/09 22:17:08 ramereth Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/ChangeLog,v 1.49 2011/02/28 02:55:56 ramereth Exp $
+
+*dokuwiki-20101107a (28 Feb 2011)
+
+  28 Feb 2011; Lance Albertson <ramereth@g.o>
+  +dokuwiki-20101107a.ebuild:
+  Version bump, resolves #354549
+
+  Thanks to Azamat H. Hackimov for the user contributed ebuild bump.
 
 *dokuwiki-20101107 (09 Nov 2010)
 



1.1                  www-apps/dokuwiki/dokuwiki-20101107a.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/dokuwiki-20101107a.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/dokuwiki/dokuwiki-20101107a.ebuild?rev=1.1&content-type=text/plain

Index: dokuwiki-20101107a.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/dokuwiki/dokuwiki-20101107a.ebuild,v 1.1 2011/02/28 02:55:56 ramereth Exp $

EAPI="2"

inherit webapp depend.php

# upstream uses dashes in the datestamp
MY_BASE_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}"
MY_PV="${MY_BASE_PV}${PV:8:1}"

DESCRIPTION="DokuWiki is a simple to use Wiki aimed at a small company's documentation needs."
HOMEPAGE="http://wiki.splitbrain.org/wiki:dokuwiki"
SRC_URI="http://www.splitbrain.org/_media/projects/${PN}/${PN}-${MY_PV}.tgz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="gd"

DEPEND=""
RDEPEND="dev-lang/php[xml]
	gd? ( || ( dev-lang/php[gd]
		media-gfx/imagemagick )
	)"

need_httpd_cgi
need_php_httpd

S="${WORKDIR}/${PN}-${MY_PV}"

src_prepare() {
	# create initial changes file
	touch data/changes.log
}

src_install() {
	webapp_src_preinst

	dodoc README
	rm -f README COPYING VERSION

	docinto scripts
	dodoc bin/*
	rm -rf bin

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	for x in $(find data/ -not -name '.htaccess'); do
		webapp_serverowned "${MY_HTDOCSDIR}"/${x}
	done

	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess.dist
	webapp_configfile "${MY_HTDOCSDIR}"/conf

	for x in $(find conf/ -not -name 'msg'); do
		webapp_configfile "${MY_HTDOCSDIR}"/${x}
	done

	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_src_install
}