[gentoo-commits] gentoo-x86 commit in sys-cluster/knem: knem-0.9.8.ebuild ChangeLog

[Alexey Shvetsov (alexxy)]

alexxy      12/04/29 13:00:11

  Modified:             ChangeLog
  Added:                knem-0.9.8.ebuild
  Log:
  [sys-cluster/knem] Version bump
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  sys-cluster/knem/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/knem/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	29 Apr 2012 12:50:29 -0000	1.3
+++ ChangeLog	29 Apr 2012 13:00:11 -0000	1.4
@@ -1,6 +1,11 @@
 # ChangeLog for sys-cluster/knem
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/knem/ChangeLog,v 1.3 2012/04/29 12:50:29 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/knem/ChangeLog,v 1.4 2012/04/29 13:00:11 alexxy Exp $
+
+*knem-0.9.8 (29 Apr 2012)
+
+  29 Apr 2012; Alexey Shvetsov <alexxy@g.o> +knem-0.9.8.ebuild:
+  [sys-cluster/knem] Version bump
 
   29 Apr 2012; Alexey Shvetsov <alexxy@g.o> files/45-knem.rules:
   [sys-cluster/knem] Fix udev rules bug #410019



1.1                  sys-cluster/knem/knem-0.9.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/knem-0.9.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/knem-0.9.8.ebuild?rev=1.1&content-type=text/plain

Index: knem-0.9.8.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/knem/knem-0.9.8.ebuild,v 1.1 2012/04/29 13:00:11 alexxy Exp $

EAPI=4

inherit autotools linux-mod multilib

DESCRIPTION="High-Performance Intra-Node MPI Communication"
HOMEPAGE="http://runtime.bordeaux.inria.fr/knem/"
SRC_URI="http://runtime.bordeaux.inria.fr/knem/download/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug modules"

DEPEND="
		sys-apps/hwloc
		virtual/linux-sources"
RDEPEND="
		sys-apps/hwloc
		virtual/modutils"

MODULE_NAMES="knem(misc:${S}/driver/linux)"
BUILD_TARGETS="all"
BUILD_PARAMS="KDIR=${KERNEL_DIR}"

pkg_setup() {
	linux-mod_pkg_setup
}

src_prepare() {
	sed 's:driver/linux::g' -i Makefile.am
	eautoreconf
}

src_configure() {
	econf \
		--enable-hwloc \
		--with-linux="${KERNEL_DIR}" \
		--with-linux-release=${KV_FULL} \
		$(use_enable debug)
}

src_compile() {
	default
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_compile || die "failed to build driver"
	fi
}

src_install() {
	default
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_install || die "failed to install driver"
	fi

	# Drop funny unneded stuff
	rm "${ED}/usr/sbin/knem_local_install" || die
	rmdir "${ED}/usr/sbin" || die
	# install udev rules
	dodir /etc/udev/rules.d
	insinto /etc/udev/rules.d
	doins "${FILESDIR}/45-knem.rules" || die
	rm "${ED}/etc/10-knem.rules" || die
}