[gentoo-commits] gentoo-x86 commit in net-irc/anope: ChangeLog anope-1.8.7.ebuild anope-1.8.5.ebuild

[Bjarke Istrup Pedersen (gurligebis)]

gurligebis    11/12/28 20:25:49

  Modified:             ChangeLog
  Added:                anope-1.8.7.ebuild
  Removed:              anope-1.8.5.ebuild
  Log:
  Bumping to 1.8.7, removing old version  and moving out of /opt.
  Thanks to everybody who helped out. Fixing bug #395089
  
  (Portage version: 2.2.0_alpha83/cvs/Linux i686)

Revision  Changes    Path
1.19                 net-irc/anope/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/anope/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/anope/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/anope/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/anope/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	18 Jan 2011 21:34:37 -0000	1.18
+++ ChangeLog	28 Dec 2011 20:25:48 -0000	1.19
@@ -1,6 +1,16 @@
 # ChangeLog for net-irc/anope
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/anope/ChangeLog,v 1.18 2011/01/18 21:34:37 gurligebis Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/anope/ChangeLog,v 1.19 2011/12/28 20:25:48 gurligebis Exp $
+
+*anope-1.8.7 (28 Dec 2011)
+
+  28 Dec 2011; <gurligebis@g.o> -anope-1.8.5.ebuild,
+  +anope-1.8.7.ebuild, +files/anope-1.8.7-ldflags-fix.patch,
+  +files/anope-1.8.7-libdir-gentoo.patch, +files/anope-conf.d,
+  +files/anope-init.d, -files/anope.confd, -files/anope.initd,
+  -files/ldflags-fix.patch:
+  Bumping to 1.8.7, removing old version and moving out of /opt.
+  Thanks to everybody who helped out. Fixing bug #395089
 
   18 Jan 2011; <gurligebis@g.o> files/ldflags-fix.patch:
   Fixing patch to work with portage-multilib, fixing bug #351414



1.1                  net-irc/anope/anope-1.8.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/anope/anope-1.8.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/anope/anope-1.8.7.ebuild?rev=1.1&content-type=text/plain

Index: anope-1.8.7.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/anope/anope-1.8.7.ebuild,v 1.1 2011/12/28 20:25:48 gurligebis Exp $

EAPI=4

inherit autotools eutils multilib versionator

DESCRIPTION="Anope IRC Services"
HOMEPAGE="http://www.anope.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="mysql"

DEPEND="mysql? ( virtual/mysql )"
RDEPEND="${DEPEND}"

pkg_pretend() {
	local replaced_version
	for replaced_version in ${REPLACING_VERSIONS} ; do
		if ! version_is_at_least 1.8.7 ${replaced_version} && [[ -f ${ROOT}opt/anope/data/nick.db ]]; then
			eerror "It looks like you have an older version of Anope installed."
			eerror "To upgrade, shut down Anope and copy your databases to"
			eerror "${ROOT}var/lib/anope and your configuration to ${ROOT}etc/anope"
			eerror "You can do this by:"
			eerror "# mkdir -p ${ROOT}var/lib/anope ${ROOT}etc/anope"
			eerror "# chown anope:anope ${ROOT}var/lib/anope"
			eerror "# mv ${ROOT}opt/anope/data/*.db ${ROOT}var/lib/anope"
			eerror "# mv ${ROOT}opt/anope/data/services.conf ${ROOT}etc/anope"
			die "Please move your anope database files from /opt/anope/data"
		fi
	done
}

pkg_setup() {
	enewgroup anope
	enewuser anope -1 -1 -1 anope
}

src_prepare() {
	epatch "${FILESDIR}/pid-patch.diff"
	epatch "${FILESDIR}/${P}-ldflags-fix.patch"
	epatch "${FILESDIR}/${P}-libdir-gentoo.patch"
	eautoconf
}

src_configure() {
	local myconf
	if ! use mysql; then
		myconf="${myconf} --without-mysql"
	fi

	econf \
		${myconf} \
		--with-bindir=/usr/bin/ \
		--with-datadir=/var/lib/anope \
		--with-libdir=/usr/$(get_libdir)/anope/ \
		--with-rungroup=anope \
		--with-permissions=077

	sed -i -e "/^build:/s:$: language:g" "${S}"/Makefile || die "sed failed"
}

src_install() {
	keepdir /var/{lib,log,run}/anope
	fowners anope:anope /var/{lib,log,run}/anope

	local baselibdir
	baselibdir="${D}/usr/$(get_libdir)/anope"

	dodir /usr/$(get_libdir)/anope/{lang,modules}
	emake DATDEST="${baselibdir}" \
		BINDEST="${D}/usr/bin" \
		MODULE_PATH="${baselibdir}/modules" \
		install

	newinitd "${FILESDIR}/anope-init.d" anope
	newconfd "${FILESDIR}/anope-conf.d" anope

	dodoc Changes Changes.conf Changes.lang Changes.mysql docs/* data/example.conf
	use mysql && dodoc data/tables.sql

	insinto /etc/anope
	newins data/example.conf services.conf
}

pkg_preinst() {
	if has_version net-irc/anope ; then
		local directory
		directory="${ROOT}"var/lib/anope/pre-update
		elog "Making a backup of your databases to ${directory}"
		if [ ! -d "${directory}" ]; then
			mkdir -p "${directory}" || die "failed to create backup directory"
			chown anope:anope "${directory}"/../ || die "failed to chown data directory"
		fi
		# don't die otherwise merge will fail if there are no existing databases
		cp "${ROOT}"/var/lib/anope/*.db "${directory}"
	fi
}

pkg_postinst() {
	echo
	ewarn "Anope won't run out of the box, you still have to configure it to match your IRCD's configuration."
	ewarn "Edit /etc/anope/services.conf to configure Anope."

	if use mysql; then
		echo
		ewarn "!!! ATTENTION !!!"
		ewarn "Be sure to read Changes.mysql to update your MySQL"
		ewarn "tables or anope will break after restart"
		ewarn "!!! ATTENTION !!!"
		echo
		einfo "The mysql script for updating the tables is located in the"
		einfo "/usr/share/doc/${PF} directory"
	fi
}