[gentoo-commits] gentoo-x86 commit in dev-db/mongodb: ChangeLog mongodb-2.2.2.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    12/11/28 10:00:24

  Modified:             ChangeLog
  Added:                mongodb-2.2.2.ebuild
  Log:
  version bump
  
  (Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key B658FA13)

Revision  Changes    Path
1.53                 dev-db/mongodb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	22 Nov 2012 03:45:06 -0000	1.52
+++ ChangeLog	28 Nov 2012 10:00:23 -0000	1.53
@@ -1,6 +1,11 @@
 # ChangeLog for dev-db/mongodb
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v 1.52 2012/11/22 03:45:06 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v 1.53 2012/11/28 10:00:23 ultrabug Exp $
+
+*mongodb-2.2.2 (28 Nov 2012)
+
+  28 Nov 2012; Ultrabug <ultrabug@g.o> +mongodb-2.2.2.ebuild:
+  Version bump
 
   22 Nov 2012; Diego E. Pettenò <flameeyes@g.o> mongodb-2.0.7-r1.ebuild,
   mongodb-2.0.7-r2.ebuild, mongodb-2.2.0-r1.ebuild, mongodb-2.2.0-r2.ebuild:



1.1                  dev-db/mongodb/mongodb-2.2.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/mongodb-2.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/mongodb-2.2.2.ebuild?rev=1.1&content-type=text/plain

Index: mongodb-2.2.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/mongodb-2.2.2.ebuild,v 1.1 2012/11/28 10:00:23 ultrabug Exp $

EAPI=4
SCONS_MIN_VERSION="1.2.0"

inherit eutils flag-o-matic multilib pax-utils scons-utils user versionator

MY_P=${PN}-src-r${PV/_rc/-rc}

DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
HOMEPAGE="http://www.mongodb.org"
SRC_URI="http://downloads.mongodb.org/src/${MY_P}.tar.gz
	mms-agent? ( http://dev.gentoo.org/~ultrabug/20121128-10gen-mms-agent.zip )"

LICENSE="AGPL-3 Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="mms-agent static-libs v8"

PDEPEND="mms-agent? ( dev-python/pymongo )"
RDEPEND="
	v8? ( dev-lang/v8 )
	>=dev-libs/boost-1.50[threads(+)]
	dev-libs/libpcre[cxx]
	dev-util/google-perftools
	net-libs/libpcap
	app-arch/snappy"
DEPEND="${RDEPEND}
	sys-libs/readline
	sys-libs/ncurses"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	enewgroup mongodb
	enewuser mongodb -1 -1 /var/lib/${PN} mongodb

	scons_opts="  --cc=$(tc-getCC) --cxx=$(tc-getCXX)"
	scons_opts+=" --use-system-tcmalloc"
	scons_opts+=" --use-system-pcre"
	scons_opts+=" --use-system-snappy"
	scons_opts+=" --use-system-boost"

	if use v8; then
		scons_opts+=" --usev8"
	else
		scons_opts+=" --usesm"
	fi
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-2.2-r1-fix-scons.patch"
	epatch "${FILESDIR}/${PN}-2.2-r1-fix-boost.patch"
	epatch "${FILESDIR}/${PN}-2.2-r2-boost-1.50.patch"

	# FIXME: apply only this fix [1] on x86 boxes as it breaks /usr/lib symlink
	# on amd64 machines [2].
	# [1] https://jira.mongodb.org/browse/SERVER-5575
	# [2] https://bugs.gentoo.org/show_bug.cgi?id=434664
	if use !prefix && [[ "$(get_libdir)" == "lib" ]]; then
		epatch "${FILESDIR}/${PN}-2.2-fix-x86client.patch"
	fi
}

src_compile() {
	escons ${scons_opts} all
}

src_install() {
	escons ${scons_opts} --full --nostrip install --prefix="${ED}"/usr

	use static-libs || rm "${ED}/usr/$(get_libdir)/libmongoclient.a"

	use v8 && pax-mark m "${ED}"/usr/bin/{mongo,mongod}

	for x in /var/{lib,log,run}/${PN}; do
		keepdir "${x}"
		fowners mongodb:mongodb "${x}"
	done

	doman debian/mongo*.1
	dodoc README docs/building.md

	newinitd "${FILESDIR}/${PN}.initd" ${PN}
	newconfd "${FILESDIR}/${PN}.confd" ${PN}
	newinitd "${FILESDIR}/${PN/db/s}.initd" ${PN/db/s}
	newconfd "${FILESDIR}/${PN/db/s}.confd" ${PN/db/s}

	insinto /etc/logrotate.d/
	newins "${FILESDIR}/${PN}.logrotate" ${PN}

	if use mms-agent; then
		local MY_PN="mms-agent"
		local MY_D="/opt/${MY_PN}"
		insinto ${MY_D}
		doins "${WORKDIR}/${MY_PN}/"*
		fowners -R mongodb:mongodb ${MY_D}
		newinitd "${FILESDIR}/${MY_PN}.initd" ${MY_PN}
		newconfd "${FILESDIR}/${MY_PN}.confd" ${MY_PN}
	fi
}

src_test() {
	escons ${scons_opts} test
	"${S}"/test --dbpath=unittest || die
}

pkg_postinst() {
	if [[ ${REPLACING_VERSIONS} < 1.8 ]]; then
		ewarn "You just upgraded from a previous version of mongodb !"
		ewarn "Make sure you run 'mongod --upgrade' before using this version."
	fi
	elog "Journaling is now enabled by default, see /etc/conf.d/${PN}"
}