[gentoo-commits] repo/gentoo:master commit in: dev-ruby/i18n/

[Hans de Graaff]

commit:     f15f1e856a5f86b44ced778e8cef0b7fd8f92298
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Fri May  4 05:45:43 2018 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Fri May  4 05:46:38 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f15f1e85

dev-ruby/i18n: add ruby25

Package-Manager: Portage-2.3.24, Repoman-2.3.6

 dev-ruby/i18n/i18n-0.9.5-r1.ebuild | 56 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/dev-ruby/i18n/i18n-0.9.5-r1.ebuild b/dev-ruby/i18n/i18n-0.9.5-r1.ebuild
new file mode 100644
index 00000000000..360a808b58d
--- /dev/null
+++ b/dev-ruby/i18n/i18n-0.9.5-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_RECIPE_TEST="test"
+RUBY_FAKEGEM_RECIPE_DOC="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem versionator
+
+DESCRIPTION="Add Internationalization support to your Ruby application"
+HOMEPAGE="http://rails-i18n.org/"
+SRC_URI="https://github.com/svenfuchs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="$(get_version_component_range 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+ruby_add_rdepend "dev-ruby/concurrent-ruby:1"
+
+ruby_add_bdepend "test? (
+	>=dev-ruby/activesupport-4.2
+	dev-ruby/bundler
+	>=dev-ruby/mocha-0.13
+	dev-ruby/test_declarative )"
+
+all_ruby_prepare() {
+	rm -f gemfiles/*.lock || die
+
+	# Remove optional unpackaged oj gem
+	sed -i -e '/oj/ s:^:#:' gemfiles/* || die
+}
+
+each_ruby_test() {
+	case ${RUBY} in
+		*ruby25)
+			versions="5.1"
+			;;
+		*ruby23|*ruby24)
+			versions="4.2 5.0 5.1"
+			;;
+	esac
+
+	for version in ${versions} ; do
+		if has_version "dev-ruby/activesupport:${version}" ; then
+			einfo "Running tests with activesupport ${version}"
+			BUNDLE_GEMFILE="${S}/gemfiles/Gemfile.rails-${version}.x" ${RUBY} -S bundle exec ${RUBY} -S rake test || die
+		fi
+	done
+}