[gentoo-commits] repo/gentoo:master commit in: games-mud/circlemud/

[Sam James]

commit:     0d88561f6b44b75d68875bc5793c2068293f844f
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Mar 31 09:09:08 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Mar 31 10:04:59 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0d88561f

games-mud/circlemud: port to EAPI 7, drop games.eclass

Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-mud/circlemud/circlemud-3.1-r1.ebuild | 62 ++++++++++++++++++++++++++++
 games-mud/circlemud/circlemud-3.1.ebuild    | 63 -----------------------------
 2 files changed, 62 insertions(+), 63 deletions(-)

diff --git a/games-mud/circlemud/circlemud-3.1-r1.ebuild b/games-mud/circlemud/circlemud-3.1-r1.ebuild
new file mode 100644
index 00000000000..ff9a32c5494
--- /dev/null
+++ b/games-mud/circlemud/circlemud-3.1-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="A multi-user dungeon game system server"
+HOMEPAGE="https://www.circlemud.org/"
+SRC_URI="https://www.circlemud.org/pub/CircleMUD/3.x/circle-${PV}.tar.bz2"
+S="${WORKDIR}"/circle-${PV}
+
+LICENSE="circlemud"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="dev-libs/openssl:0="
+RDEPEND="
+	${DEPEND}
+	acct-group/gamestat
+"
+
+src_prepare() {
+	default
+
+	cd src || die
+
+	touch .accepted || die
+
+	sed -i \
+		-e 's:^read.*::' licheck || die
+
+	# Now let's rename binaries (too many are very generic)
+	sed -i \
+		-e "s:\.\./bin/autowiz:${PN}-autowiz:" limits.c || die
+
+	tc-export CC
+	eapply "${FILESDIR}"/${P}-ldflags.patch
+}
+
+src_compile() {
+	emake -C src
+}
+
+src_install() {
+	local bin
+
+	for bin in autowiz delobjs listrent mudpasswd play2to3 purgeplay \
+	           shopconv showplay sign split wld2html ; do
+		newbin bin/${bin} ${PN}-${bin}
+	done
+
+	dobin bin/circle
+
+	insinto /var/lib/${PN}
+	doins -r lib/*
+
+	insinto /etc/${PN}
+	doins lib/etc/*
+
+	dodoc doc/{README.UNIX,*.pdf,*.txt} ChangeLog FAQ README release_notes.${PV}.txt
+}

diff --git a/games-mud/circlemud/circlemud-3.1.ebuild b/games-mud/circlemud/circlemud-3.1.ebuild
deleted file mode 100644
index 0e4c0eb1a25..00000000000
--- a/games-mud/circlemud/circlemud-3.1.ebuild
+++ /dev/null
@@ -1,63 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit eutils games
-
-DESCRIPTION="a multi-user dungeon game system server"
-HOMEPAGE="https://www.circlemud.org/"
-SRC_URI="https://www.circlemud.org/pub/CircleMUD/3.x/circle-${PV}.tar.bz2"
-
-LICENSE="circlemud"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-DEPEND="dev-libs/openssl:0="
-RDEPEND=${DEPEND}
-
-S=${WORKDIR}/circle-${PV}
-
-src_prepare() {
-	cd src
-	touch .accepted
-	sed -i \
-		-e 's:^read.*::' licheck || die
-
-	# make circlemud fit into Gentoo nicely
-	sed -i \
-		-e "s:\"lib\":\"${GAMES_DATADIR}/${PN}\":g" \
-		-e "s:\(LOGNAME = \)NULL:\1\"${GAMES_LOGDIR}/${PN}.log\":g" \
-		config.c || die
-	sed -i \
-		-e "s:etc/:${GAMES_SYSCONFDIR}/${PN}/:g" db.h || die
-
-	# now lets rename binaries (too many are very generic)
-	sed -i \
-		-e "s:\.\./bin/autowiz:${PN}-autowiz:" limits.c || die
-	epatch "${FILESDIR}"/${P}-ldflags.patch
-}
-
-src_compile() {
-	emake -C src
-}
-
-src_install() {
-	local bin
-
-	for bin in autowiz delobjs listrent mudpasswd play2to3 purgeplay \
-	           shopconv showplay sign split wld2html ; do
-		newgamesbin bin/${bin} ${PN}-${bin}
-	done
-	dogamesbin bin/circle
-
-	dodir "${GAMES_DATADIR}/${PN}"
-	cp -r lib/*  "${D}/${GAMES_DATADIR}/${PN}" || die
-
-	insinto "${GAMES_SYSCONFDIR}/${PN}"
-	doins lib/etc/*
-
-	dodoc doc/{README.UNIX,*.pdf,*.txt} ChangeLog FAQ README release_notes.${PV}.txt
-	prepgamesdirs
-	fperms 770 "${GAMES_SYSCONFDIR}/${PN}/players"
-}