[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgdata/

[Mart Raudsepp]

commit:     78293e70b833f3b37e9a4b2990d51ebe6f7a4998
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 28 20:11:49 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Feb 28 20:12:04 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=78293e70

dev-libs/libgdata: bump to 0.7.12

OAuth1 support is dropped unconditionally, as no known servies
use this anymore (everything on oauth is using OAuth2). This
drops liboauth dependency together with it.

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 dev-libs/libgdata/Manifest                |  1 +
 dev-libs/libgdata/libgdata-0.17.12.ebuild | 65 +++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/dev-libs/libgdata/Manifest b/dev-libs/libgdata/Manifest
index 09a94d47adf..3c8609ce033 100644
--- a/dev-libs/libgdata/Manifest
+++ b/dev-libs/libgdata/Manifest
@@ -1 +1,2 @@
 DIST libgdata-0.17.11.tar.xz 843948 BLAKE2B 8be79ea5840a585c5bdd5b51aa99401aedce0562ceaa98c7e323cdb2354384db635288d05c740993da49fa9c60c2cafab4e7c43ab82de4295afc0ca6b690d4dd SHA512 5abb00e6ebee1010fb6d9eab675e03d94883cac88e42b403a7d750bff73d65d0b35aae5c9e8f17a182819193b4a049ac7e9fc644ad9fa79872924ed5704c8982
+DIST libgdata-0.17.12.tar.xz 845420 BLAKE2B 636ff5ba7df48f671cdb5da09c011f620619051e30470bb3ebb400f8c093e89885e0c3c7ac54e569cff2c350bd08f7e346f1529c07c41f570b7255002fc69c44 SHA512 22571c9b0cecbaf617fc8fa43a312bba4eaf36267264546f55c9c9067514cc6ae1db755536c7413427ebf6121115512dcab4201549c128fb1a25afe75a3daa2b

diff --git a/dev-libs/libgdata/libgdata-0.17.12.ebuild b/dev-libs/libgdata/libgdata-0.17.12.ebuild
new file mode 100644
index 00000000000..f9c87147c2c
--- /dev/null
+++ b/dev-libs/libgdata/libgdata-0.17.12.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgdata"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/22" # subslot = libgdata soname version
+
+IUSE="+crypt gnome-online-accounts gtk-doc +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/json-glib-0.15[introspection?]
+	>=dev-libs/libxml2-2:2
+	>=net-libs/libsoup-2.55.90:2.4[introspection?,vala?]
+	crypt? ( app-crypt/gcr:= )
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8:=[introspection?,vala?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-util/meson-0.50.0
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.25
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( >=net-libs/uhttpmock-0.5.0
+		>=x11-libs/gdk-pixbuf-2.14:2
+	)
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+	# Don't waste time building a couple small demos that aren't installed
+	sed -i -e '/subdir.*demos/d' meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgtk=disabled # only for demos
+		$(meson_feature crypt gnome)
+		$(meson_feature gnome-online-accounts goa)
+		-Doauth1=disabled
+		$(meson_use test always_build_tests)
+		-Dinstalled_tests=false
+		-Dman=true
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}