[gentoo-commits] gentoo-x86 commit in app-laptop/laptop-mode-tools: ChangeLog laptop-mode-tools-1.54.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/05/04 00:25:33

  Modified:             ChangeLog
  Added:                laptop-mode-tools-1.54.ebuild
  Log:
  Version bump and keepdir /var/run/laptop-mode-tools wrt #300905. Remove USE hal wrt #313429.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.47                 app-laptop/laptop-mode-tools/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	24 Oct 2009 10:54:37 -0000	1.46
+++ ChangeLog	4 May 2010 00:25:33 -0000	1.47
@@ -1,6 +1,13 @@
 # ChangeLog for app-laptop/laptop-mode-tools
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog,v 1.46 2009/10/24 10:54:37 nixnut Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/ChangeLog,v 1.47 2010/05/04 00:25:33 ssuominen Exp $
+
+*laptop-mode-tools-1.54 (04 May 2010)
+
+  04 May 2010; Samuli Suominen <ssuominen@g.o>
+  +laptop-mode-tools-1.54.ebuild:
+  Version bump and keepdir /var/run/laptop-mode-tools wrt #300905. Remove
+  USE hal wrt #313429.
 
   24 Oct 2009; nixnut <nixnut@g.o> laptop-mode-tools-1.47-r1.ebuild:
   ppc stable #284794



1.1                  app-laptop/laptop-mode-tools/laptop-mode-tools-1.54.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/laptop-mode-tools/laptop-mode-tools-1.54.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/laptop-mode-tools/laptop-mode-tools-1.54.ebuild?rev=1.1&content-type=text/plain

Index: laptop-mode-tools-1.54.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-laptop/laptop-mode-tools/laptop-mode-tools-1.54.ebuild,v 1.1 2010/05/04 00:25:33 ssuominen Exp $

EAPI=2
inherit eutils

MY_P=${PN}_${PV}

DESCRIPTION="Linux kernel laptop_mode user-space utilities"
HOMEPAGE="http://www.samwel.tk/laptop_mode/"
SRC_URI="http://www.samwel.tk/laptop_mode/tools/downloads/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="acpi apm bluetooth scsi"

DEPEND=""

RDEPEND="sys-apps/ethtool
		acpi? ( >=sys-power/acpid-2.0.4-r2 )
		apm? ( sys-apps/apmd )
		bluetooth? (
			|| (
				net-wireless/bluez
				net-wireless/bluez-utils
			)
		)
		scsi? ( sys-apps/sdparm )
		sys-apps/hdparm"

S=${WORKDIR}/${MY_P}

src_compile() { :; }

src_install() {
	dodir /etc/pm/sleep.d
	DESTDIR="${D}" \
		MAN_D="/usr/share/man" \
		INIT_D="none" \
		APM="$(use apm && echo force || echo disabled)" \
		ACPI="$(use acpi && echo force || echo disabled)" \
		PMU="$(false && echo force || echo disabled)" \
		./install.sh || die

	dodoc Documentation/laptop-mode.txt README || die
	newinitd "${FILESDIR}"/laptop_mode.init-1.4 laptop_mode

	exeinto /etc/pm/power.d
	newexe "${FILESDIR}"/laptop_mode_tools.pmutils laptop_mode_tools

	keepdir /var/run/laptop-mode-tools
}

pkg_postinst() {
	if ! use acpi && ! use apm; then
		ewarn
		ewarn "Without USE=\"acpi\" or USE=\"apm\" ${PN} can not"
		ewarn "automatically disable laptop_mode on low battery."
		ewarn
		ewarn "This means you can lose up to 10 minutes of work if running"
		ewarn "out of battery while laptop_mode is enabled."
		ewarn
		ewarn "Please see /usr/share/doc/${PF}/laptop-mode.txt.gz for further"
		ewarn "information."
		ewarn
	fi
}