[gentoo-commits] repo/gentoo:master commit in: dev-libs/openobex/files/, dev-libs/openobex/

[Andrew Savchenko]

commit:     fca438d6d05126e7ff981a5dda43b53bbf37b835
Author:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 27 18:08:49 2018 +0000
Commit:     Andrew Savchenko <bircoph <AT> gentoo <DOT> org>
CommitDate: Sat Oct 27 18:40:26 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fca438d6

dev-libs/openobex: fix version.h and docs

- Fix version.h to contain valib version information, invalid one
  after switch to cmake cause  bug 660400.
- Build and install doxygen API docs correctly.

Bug: https://bugs.gentoo.org/660400
Signed-off-by: Andrew Savchenko <bircoph <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 .../openobex/files/openobex-1.7.2-version.h.patch  | 13 +++++++
 dev-libs/openobex/openobex-1.7.2-r1.ebuild         | 41 ++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/dev-libs/openobex/files/openobex-1.7.2-version.h.patch b/dev-libs/openobex/files/openobex-1.7.2-version.h.patch
new file mode 100644
index 00000000000..cfcf68595b4
--- /dev/null
+++ b/dev-libs/openobex/files/openobex-1.7.2-version.h.patch
@@ -0,0 +1,13 @@
+--- openobex-1.7.2-Source/include/openobex/version.h.in.orig	2013-07-21 21:27:14.000000000 +0400
++++ openobex-1.7.2-Source/include/openobex/version.h.in	2018-10-27 19:35:53.921795023 +0300
+@@ -1,6 +1,6 @@
+ 
+-#define OPENOBEX_VERSION       "@VERSION@"
++#define OPENOBEX_VERSION       "@openobex_VERSION@"
+ 
+-#define OPENOBEX_VERSION_MAJOR @VERSION_MAJOR@
+-#define OPENOBEX_VERSION_MINOR @VERSION_MINOR@
+-#define OPENOBEX_VERSION_PATCH @VERSION_PATCH@
++#define OPENOBEX_VERSION_MAJOR @openobex_VERSION_MAJOR@
++#define OPENOBEX_VERSION_MINOR @openobex_VERSION_MINOR@
++#define OPENOBEX_VERSION_PATCH @openobex_VERSION_PATCH@

diff --git a/dev-libs/openobex/openobex-1.7.2-r1.ebuild b/dev-libs/openobex/openobex-1.7.2-r1.ebuild
new file mode 100644
index 00000000000..814f435076c
--- /dev/null
+++ b/dev-libs/openobex/openobex-1.7.2-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils udev
+
+DESCRIPTION="Implementation of the OBEX protocol used for transferring data to mobile devices"
+HOMEPAGE="https://sourceforge.net/projects/openobex/"
+SRC_URI="mirror://sourceforge/${PN}/${PV}/${P}-Source.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/2"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="bluetooth doc irda usb"
+
+RDEPEND="
+	bluetooth? ( net-wireless/bluez:= )
+	usb? ( virtual/libusb:= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/${P}-Source"
+
+PATCHES=( "${FILESDIR}/${P}-version.h.patch" )
+DOCS=( AUTHORS ChangeLog README UPGRADING.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCUMENTATION=$(usex doc)
+		-DOPENOBEX_BLUETOOTH=$(usex bluetooth)
+		-DOPENOBEX_IRDA=$(usex irda)
+		-DOPENOBEX_USB=$(usex usb)
+
+		-DCMAKE_INSTALL_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DCMAKE_INSTALL_UDEVRULESDIR="$(get_udevdir)/rules.d"
+	)
+
+	cmake-utils_src_configure
+}