[gentoo-commits] gentoo-x86 commit in net-mail/notmuch: notmuch-0.10.2-r2.ebuild ChangeLog

[Amadeusz Zolnowski (aidecoe)]

aidecoe     12/02/29 07:41:23

  Modified:             ChangeLog
  Added:                notmuch-0.10.2-r2.ebuild
  Log:
  net-mail/notmuch-0.10.2: Fixes bug #406175 and bug #406177.
  
  Fixes bug #406175 (security fix for Emacs UI) and bug #406177 (Python bindings
  tests used to fail). I have backported patches from 0.11.1 and 0.11 releases.
  
  (Portage version: 2.1.10.48/cvs/Linux x86_64)

Revision  Changes    Path
1.28                 net-mail/notmuch/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	29 Feb 2012 07:36:13 -0000	1.27
+++ ChangeLog	29 Feb 2012 07:41:23 -0000	1.28
@@ -1,6 +1,16 @@
 # ChangeLog for net-mail/notmuch
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v 1.27 2012/02/29 07:36:13 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/ChangeLog,v 1.28 2012/02/29 07:41:23 aidecoe Exp $
+
+*notmuch-0.10.2-r2 (29 Feb 2012)
+
+  29 Feb 2012; Amadeusz Żołnowski <aidecoe@g.o>
+  +files/0.10.2-emacsui-mml-tags-quoting-fix.patch,
+  +files/0.10.2-emacsui-mml-tags-quoting-test.patch,
+  +files/0.10.2-lib-call-g_mime_init-db-open.patch, +notmuch-0.10.2-r2.ebuild:
+  Fixes bug #406175 (security fix for Emacs UI) and bug #406177 (Python
+  bindings tests used to fail). I have backported patches from 0.11.1 and 0.11
+  releases.
 
   28 Feb 2012; Amadeusz Żołnowski <aidecoe@g.o> notmuch-0.10.2.ebuild,
   notmuch-0.10.2-r1.ebuild, notmuch-0.11.1-r1.ebuild, notmuch-0.11.1-r2.ebuild:



1.1                  net-mail/notmuch/notmuch-0.10.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/notmuch-0.10.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/notmuch/notmuch-0.10.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: notmuch-0.10.2-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/notmuch/notmuch-0.10.2-r2.ebuild,v 1.1 2012/02/29 07:41:23 aidecoe Exp $

EAPI=4

PYTHON_DEPEND="python? 2:2.6"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.[45] 3.*"

inherit elisp-common distutils
inherit autotools-utils

DESCRIPTION="The mail indexer"
HOMEPAGE="http://notmuchmail.org/"
SRC_URI="${HOMEPAGE}/releases/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
REQUIRED_USE="test? ( crypt emacs )"
IUSE="bash-completion crypt debug doc emacs python test vim zsh-completion"

CDEPEND="
	>=dev-libs/glib-2.22
	dev-libs/gmime:2.4
	dev-libs/xapian
	doc? ( python? ( dev-python/sphinx ) )
	sys-libs/talloc
	debug? ( dev-util/valgrind )
	emacs? ( >=virtual/emacs-23 )
	x86? ( >=dev-libs/xapian-1.2.7-r2 )
	vim? ( || ( >=app-editors/vim-7.0 >=app-editors/gvim-7.0 ) )
	"
DEPEND="${CDEPEND}
	dev-util/pkgconfig
	test? ( app-misc/dtach sys-devel/gdb )
	"
RDEPEND="${CDEPEND}
	crypt? ( app-crypt/gnupg )
	zsh-completion? ( app-shells/zsh )
	"

PATCHES=(
	"${FILESDIR}/${PV}-fix-test-build.patch"
	"${FILESDIR}/${PV}-emacsui-mml-tags-quoting-test.patch"
	"${FILESDIR}/${PV}-emacsui-mml-tags-quoting-fix.patch"
	"${FILESDIR}/${PV}-lib-call-g_mime_init-db-open.patch"
	)
DOCS=( AUTHORS NEWS README TODO )
SITEFILE="50${PN}-gentoo.el"

bindings() {
	if use $1; then
		pushd bindings/$1 || die
		shift
		$@
		popd || die
	fi
}

pkg_setup() {
	if use emacs; then
		elisp-need-emacs 23 || die "Emacs version too low"
	fi
	use python && python_pkg_setup
}

src_prepare() {
	autotools-utils_src_prepare
	bindings python distutils_src_prepare
}

src_configure() {
	local myeconfargs=(
		--bashcompletiondir="${ROOT}/usr/share/bash-completion"
		--emacslispdir="${ROOT}/${SITELISP}/${PN}"
		--emacsetcdir="${ROOT}/${SITEETC}/${PN}"
		--zshcompletiondir="${ROOT}/usr/share/zsh/site-functions"
		$(use_with bash-completion)
		$(use_with emacs)
		$(use_with zsh-completion)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile
	bindings python distutils_src_compile

	if use doc; then
		pydocs() {
			pushd docs || die
			emake html
			mv html ../python || die
			popd || die
		}
		LD_LIBRARY_PATH="${WORKDIR}/${PF}_build/lib" bindings python pydocs
	fi
}

src_install() {
	autotools-utils_src_install

	if use emacs; then
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
	fi

	if use vim; then
		insinto /usr/share/vim/vimfiles
		doins -r vim/plugin vim/syntax
	fi

	DOCS="" bindings python distutils_src_install

	if use doc; then
		bindings python dohtml -r python
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
	use python && distutils_pkg_postinst
}

pkg_postrm() {
	use emacs && elisp-site-regen
	use python && distutils_pkg_postrm
}