[gentoo-commits] repo/gentoo:master commit in: dev-libs/link-grammar/

[David Seifert]

commit:     17ac6a90c21775f4a6d237a820d998d0d1a37c81
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 22 13:12:42 2022 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Jan 22 13:12:42 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=17ac6a90

dev-libs/link-grammar: add 5.10.2

Signed-off-by: David Seifert <soap <AT> gentoo.org>

 dev-libs/link-grammar/Manifest                   |   1 +
 dev-libs/link-grammar/link-grammar-5.10.2.ebuild | 113 +++++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/dev-libs/link-grammar/Manifest b/dev-libs/link-grammar/Manifest
index b873ef15a703..e40a0cacbd15 100644
--- a/dev-libs/link-grammar/Manifest
+++ b/dev-libs/link-grammar/Manifest
@@ -1,3 +1,4 @@
+DIST link-grammar-5.10.2.tar.gz 3853934 BLAKE2B d2cb64a6b0146f40ce5b197c21ded94f1256360615c2332a1c546f6b6c71c98d2500e97b0fcabae964377a04143fa13ba3af324f2de729cfccd280e53f6fb7c3 SHA512 71bc881cb628fe1898403024d8e949b2fbf44f5d20445f6fff7bb6038646840556d734434beb7eb43b63f661e18333657deaeb1b8c96b50d5fe3b6ef727565c2
 DIST link-grammar-5.8.0.tar.gz 3782125 BLAKE2B 8027e91212d3269b8e3ceaa5c837ad961cd2dfd92849d3989094ab771d97d30f4b228cfc1e32e9e843676aa439d790fb444823f7db69004538ad068c7bf28a45 SHA512 1262e2faf1de6f05a62f9d622f43c02253b4c241342df9b443a70ae04bd328d1fc49cd2f91c881e694f67215005833fec8b1fa9d395b1e547985b376c7415d2e
 DIST link-grammar-5.8.1.tar.gz 3791847 BLAKE2B 8c89b95eaae87f0b576374c3f8c00529d61b62004718424d1ac1a41b694d8b56ba75d0a7068e1411376c260781f5adae8512976a6572e54f18d84abe98c1839e SHA512 0ef99d3ccb3d922a946f1f73b8b81cee9ece156886dab3367837e1e9f79944967da1391daf7f96ea5a95a0abdd346b642111a7939eb9aa079557c10b3efe8022
 DIST link-grammar-5.9.1.tar.gz 3809872 BLAKE2B fe0c407e2e4ea4201036647cbea7d4c2606fa9943653fcc2d3505963a00773006912b8af5c2762acf498220d2f48319a031736d59790c0fed616432973ea24ec SHA512 c8d8bc99ddd6f6190ebcb24fcafc79497c3eeab1deb3099691f55c735a0a607a8372a8dca5cd86ce7c20cd3a45e4f1cbf91bef39dc781a5b5a2246006b4f601e

diff --git a/dev-libs/link-grammar/link-grammar-5.10.2.ebuild b/dev-libs/link-grammar/link-grammar-5.10.2.ebuild
new file mode 100644
index 000000000000..9cd72d301f29
--- /dev/null
+++ b/dev-libs/link-grammar/link-grammar-5.10.2.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit autotools python-r1 out-of-source
+
+DESCRIPTION="A Syntactic English parser"
+HOMEPAGE="https://www.abisource.com/projects/link-grammar/ https://www.link.cs.cmu.edu/link/"
+SRC_URI="https://www.abisource.com/downloads/${PN}/${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="aspell +hunspell python" # pcre
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# XXX: sqlite is automagic
+# Does not build with >=sci-mathematics/minisat-2, bug #593662
+# add pcre support: pcre? ( dev-libs/libpcre )
+RDEPEND="
+	dev-db/sqlite:3
+	aspell? ( app-text/aspell )
+	hunspell? ( app-text/hunspell )
+	python? ( ${PYTHON_DEPS} )
+	!sci-mathematics/minisat"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/swig:0
+	sys-devel/autoconf-archive
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-5.8.1-lld.patch )
+
+pkg_setup() {
+	if use aspell && use hunspell; then
+		ewarn "You have enabled 'aspell' and 'hunspell' support, but both cannot coexist,"
+		ewarn "only hunspell will be built. Press Ctrl+C and set only 'aspell' USE flag if"
+		ewarn "you want aspell support."
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+my_src_configure() {
+	local myconf=(
+		--disable-maintainer-mode
+		--disable-editline
+		# java is hopelessly broken, invokes maven at build time (bug #806157)
+		--disable-java-bindings
+		--disable-perl-bindings
+		--disable-static
+		--enable-sat-solver=bundled
+		$(use_enable aspell)
+		$(use_enable hunspell)
+		$(usev hunspell --with-hunspell-dictdir="${EPREFIX}"/usr/share/myspell)
+		# $(use_enable pcre regex-tokenizer)
+		# $(use_with pcre)
+	)
+
+	econf \
+		--disable-python-bindings \
+		"${myconf[@]}"
+
+	if use python; then
+		python_configure() {
+			econf \
+				--enable-python-bindings \
+				"${myconf[@]}"
+		}
+		python_foreach_impl run_in_build_dir python_configure
+	fi
+}
+
+my_src_compile() {
+	local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+	default
+
+	if use python; then
+		python_compile() {
+			emake -C bindings/python \
+				VPATH="${S}:${MAIN_BUILD_DIR}" \
+				_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+				_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la
+		}
+		python_foreach_impl run_in_build_dir python_compile
+	fi
+}
+
+my_src_install() {
+	local -x MAIN_BUILD_DIR="${BUILD_DIR}"
+	default
+
+	if use python; then
+		python_install() {
+			emake -C bindings/python \
+				VPATH="${S}:${MAIN_BUILD_DIR}" \
+				_clinkgrammar_la_DEPENDENCIES="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+				_clinkgrammar_la_LIBADD="${MAIN_BUILD_DIR}"/link-grammar/liblink-grammar.la \
+				DESTDIR="${D}" \
+				install
+		}
+		python_foreach_impl run_in_build_dir python_install
+	fi
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}