[gentoo-commits] gentoo-x86 commit in games-arcade/stepmania: ChangeLog stepmania-3.9-r1.ebuild stepmania-3.9.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    09/06/20 23:05:23

  Modified:             ChangeLog
  Added:                stepmania-3.9-r1.ebuild
  Removed:              stepmania-3.9.ebuild
  Log:
  Bump patchset to fix FFmpeg >= 0.5 compability wrt #269080, thanks to Wai Ling.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.29                 games-arcade/stepmania/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-arcade/stepmania/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	24 Mar 2009 21:21:23 -0000	1.28
+++ ChangeLog	20 Jun 2009 23:05:23 -0000	1.29
@@ -1,6 +1,13 @@
 # ChangeLog for games-arcade/stepmania
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-arcade/stepmania/ChangeLog,v 1.28 2009/03/24 21:21:23 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/stepmania/ChangeLog,v 1.29 2009/06/20 23:05:23 ssuominen Exp $
+
+*stepmania-3.9-r1 (20 Jun 2009)
+
+  20 Jun 2009; Samuli Suominen <ssuominen@g.o> -stepmania-3.9.ebuild,
+  +stepmania-3.9-r1.ebuild, -files/stepmania-3.9-newerffmpeg.diff,
+  -files/stepmania-3.9-newffmpeg.diff:
+  Bump patchset to fix FFmpeg >= 0.5 compability wrt #269080, thanks to Wai Ling.
 
   24 Mar 2009; Michael Sterrett <mr_bones_@g.o> stepmania-3.9.ebuild:
   add joystick use dep for bug #263553
@@ -8,12 +15,6 @@
   19 Jan 2009; Michael Sterrett <mr_bones_@g.o> stepmania-3.9.ebuild:
   EAPI=2; add use-based dep
 
-  24 Nov 2008; <ssuominen@g.o> stepmania-3.9.ebuild:
-  Move patchset tarball out of my old dev space to gentoo mirrors.
-
-  24 Nov 2008; <ssuominen@g.o> metadata.xml:
-  Remove my old e-mail from metadata.xml. I don't play this.
-
   15 Oct 2008; Peter Alfredsen <loki_val@g.o>
   +files/stepmania-3.9-newerffmpeg.diff, stepmania-3.9.ebuild:
   Fix for ffmpeg 20081014. Bug 242054.



1.1                  games-arcade/stepmania/stepmania-3.9-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/stepmania-3.9-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/stepmania/stepmania-3.9-r1.ebuild?rev=1.1&content-type=text/plain

Index: stepmania-3.9-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-arcade/stepmania/stepmania-3.9-r1.ebuild,v 1.1 2009/06/20 23:05:23 ssuominen Exp $

EAPI=2
inherit autotools eutils games

MY_P=StepMania-${PV}
DESCRIPTION="An advanced DDR simulator"
HOMEPAGE="http://www.stepmania.com/stepmania/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}-src.tar.gz
	mirror://sourceforge/${PN}/${MY_P}-linux.tar.gz
	http://dev.gentoo.org/~ssuominen/distfiles/${P}-patches-4.tar.gz
	mirror://gentoo/${P}-patches-4.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug ffmpeg force-oss gtk jpeg mad vorbis"

RESTRICT="test"

RDEPEND="gtk? ( x11-libs/gtk+:2 )
	mad? ( media-libs/libmad )
	>=dev-lang/lua-5
	media-libs/libsdl[joystick,opengl]
	jpeg? ( media-libs/jpeg )
	media-libs/libpng
	ffmpeg? ( >=media-video/ffmpeg-0.5 )
	vorbis? ( media-libs/libvorbis )
	virtual/opengl
	virtual/glu"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}-src

src_prepare() {
	sed "s:/usr/share/games/${PN}:${GAMES_DATADIR}/${PN}:" \
		"${FILESDIR}"/${P}-gentoo.patch > "${T}"/${P}.patch

	EPATCH_SUFFIX=patch epatch "${T}"/${P}.patch "${WORKDIR}"/patches
	AT_M4DIR=autoconf/m4 eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		$(use_with debug) \
		$(use_with jpeg) \
		$(use_with vorbis) \
		$(use_with mad mp3) \
		$(use_enable gtk gtk2) \
		$(use_enable force-oss)
}

src_install() {
	local dir=${GAMES_DATADIR}/${PN}

	exeinto "${dir}"
	doexe src/stepmania || die "doexe failed"

	if use gtk; then
		doexe src/GtkModule.so || die "doexe failed"
	fi

	cd "${WORKDIR}"/${MY_P}

	insinto "${dir}"
	doins -r Announcers BGAnimations CDTitles Characters Courses Data Docs \
		NoteSkins RandomMovies Songs Themes Visualizations || die "doins failed"

	dodoc Copying.txt NEWS
	dohtml README-FIRST.html

	newicon "Themes/default/Graphics/Common window icon.png" ${PN}.png
	make_desktop_entry ${PN} StepMania

	games_make_wrapper ${PN} "${dir}"/${PN} "${dir}"
	prepgamesdirs
}