[gentoo-commits] repo/gentoo:master commit in: dev-libs/ell/

[Ben Kohler]

commit:     264646cfc6cb07e0ffa75955cf202b8d515fc280
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Tue May  4 17:27:17 2021 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Tue May  4 17:40:42 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=264646cf

dev-libs/ell: bump to 0.40

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 dev-libs/ell/Manifest        |  1 +
 dev-libs/ell/ell-0.40.ebuild | 60 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-libs/ell/Manifest b/dev-libs/ell/Manifest
index 5a893928587..f531f497684 100644
--- a/dev-libs/ell/Manifest
+++ b/dev-libs/ell/Manifest
@@ -1,2 +1,3 @@
 DIST ell-0.38.tar.xz 520744 BLAKE2B 24d552ed1bdd55c78aef7d427c40cb391ddedf8f06e77ddd188509a9eca71135b9fe282377bec1a225cb617c7a8bcc4efe6da6eb1dd86596e03ed6ba790b9619 SHA512 e482df8d810b866479c97a096efb8d2badb903bb7fda35ee3bbbaa65652c63f8058188a5ab9f477f835f6a5789a7c5d2eb7db2d9e30493ecd75bd7e71017b6c2
 DIST ell-0.39.tar.xz 523932 BLAKE2B de1cb68347ed9047bb1fe79dc91ed1db7ab466a5610647660a4eb50519c620f8ea28767538d0cb79e3c3de17f884227f1dd957453c56df322ffff2c5856e94ee SHA512 ee525268276aec13bd8004c8211c768c682fbbe4b50d5dfa886a76cfa20be98e867cb2b1850b23fc16cf47b942e21ad272f19ae3d5cff36ce856ae8811938dc0
+DIST ell-0.40.tar.xz 524256 BLAKE2B de7326cfc7d00970fdeb5f19e38b9c68e6443544f5a6397aa031a7dcd0d61c77ab72303ad51d36e8fbc2c34c954631636f7f42bae0c40cd75498882ab78e2c85 SHA512 bc721e300e5b689dc51f794019e731eb252ad74dd199bec7685373ffa32ad42950aae9e36cb74d3b6590016c046589acb3ae8c009c4a14bd89331913392e923e

diff --git a/dev-libs/ell/ell-0.40.ebuild b/dev-libs/ell/ell-0.40.ebuild
new file mode 100644
index 00000000000..752fd7b7e63
--- /dev/null
+++ b/dev-libs/ell/ell-0.40.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic linux-info multilib-minimal
+
+DESCRIPTION="Embedded Linux Library provides core, low-level functionality for system daemons"
+HOMEPAGE="https://01.org/ell"
+if [[ "${PV}" == *9999 ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git"
+else
+	SRC_URI="https://mirrors.edge.kernel.org/pub/linux/libs/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+fi
+LICENSE="LGPL-2.1"
+SLOT="0"
+
+IUSE="glib pie test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	glib? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( sys-apps/dbus )
+"
+
+CONFIG_CHECK="
+	~TIMERFD
+	~EVENTFD
+	~CRYPTO_USER_API
+	~CRYPTO_USER_API_HASH
+	~CRYPTO_MD5
+	~CRYPTO_SHA1
+	~KEY_DH_OPERATIONS
+"
+
+src_prepare() {
+	default
+	[[ "${PV}" == *9999 ]] && eautoreconf
+}
+
+multilib_src_configure() {
+	append-cflags "-fsigned-char" #662694
+	local myeconfargs=(
+		$(use_enable glib)
+		$(use_enable pie)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	local DOCS=( ChangeLog README )
+	einstalldocs
+
+	find "${ED}" -name "*.la" -delete || die
+}