[gentoo-commits] repo/gentoo:master commit in: dev-python/ply/

[Justin Lecher]

commit:     8ad387acd52815a6cda63e079cd8b83ddfe06f2c
Author:     Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 11 10:31:59 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Sun Oct 11 11:24:29 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8ad387ac

dev-python/ply: Add python3.5 support

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>

 dev-python/ply/ply-3.8-r1.ebuild | 44 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

diff --git a/dev-python/ply/ply-3.8-r1.ebuild b/dev-python/ply/ply-3.8-r1.ebuild
new file mode 100644
index 0000000..d32b5aa
--- /dev/null
+++ b/dev-python/ply/ply-3.8-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Lex-Yacc library"
+HOMEPAGE="http://www.dabeaz.com/ply/ https://pypi.python.org/pypi/ply"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
+IUSE="examples"
+
+RDEPEND=""
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+
+# See bug #458648 for reference
+RESTRICT="test"
+
+DOCS=( ANNOUNCE CHANGES TODO )
+
+PATCHES=( "${FILESDIR}/3.6-picklefile-IOError.patch" )
+
+python_test() {
+	cp -r -l test "${BUILD_DIR}"/ || die
+	cd "${BUILD_DIR}"/test || die
+
+	local t
+	for t in testlex.py testyacc.py; do
+		"${PYTHON}" "${t}" || die "${t} fails with ${EPYTHON}"
+	done
+}
+
+python_install_all() {
+	local HTML_DOCS=( doc/. )
+	use examples && local EXAMPLES=( example/. )
+	distutils-r1_python_install_all
+}