[gentoo-commits] gentoo-x86 commit in net-libs/rb_libtorrent: ChangeLog rb_libtorrent-0.15.1.ebuild

[Markos Chandras (hwoarang)]

hwoarang    10/07/01 08:32:25

  Modified:             ChangeLog
  Added:                rb_libtorrent-0.15.1.ebuild
  Log:
  Version bump.Fixes bug #325313. Remove old configure options. FIx pthread linking
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.87                 net-libs/rb_libtorrent/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?r1=1.86&r2=1.87

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- ChangeLog	16 Jun 2010 17:40:38 -0000	1.86
+++ ChangeLog	1 Jul 2010 08:32:25 -0000	1.87
@@ -1,6 +1,14 @@
 # ChangeLog for net-libs/rb_libtorrent
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.86 2010/06/16 17:40:38 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.87 2010/07/01 08:32:25 hwoarang Exp $
+
+*rb_libtorrent-0.15.1 (01 Jul 2010)
+
+  01 Jul 2010; Markos Chandras <hwoarang@g.o>
+  +rb_libtorrent-0.15.1.ebuild,
+  +files/rb_libtorrent-0.15.1-ax_pthread_asneeded.patch:
+  Version bump. Fixes tracker announcement bug wrt bug #325313. Remove
+  obsolete configure options. Proper fix for lpthread linking
 
 *rb_libtorrent-0.15.0 (16 Jun 2010)
 



1.1                  net-libs/rb_libtorrent/rb_libtorrent-0.15.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.15.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.15.1.ebuild?rev=1.1&content-type=text/plain

Index: rb_libtorrent-0.15.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.15.1.ebuild,v 1.1 2010/07/01 08:32:25 hwoarang Exp $

EAPI="2"
WANT_AUTOMAKE="1.11.1"
inherit autotools eutils versionator

MY_P=${P/rb_/}
MY_P=${MY_P/torrent/torrent-rasterbar}
S=${WORKDIR}/${MY_P}

DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
HOMEPAGE="http://www.rasterbar.com/products/libtorrent/"
SRC_URI="http://libtorrent.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="debug doc examples python"
RESTRICT="test"

DEPEND="|| ( >=dev-libs/boost-1.35
		( ~dev-libs/boost-1.34.1 dev-cpp/asio ) )
	python? ( >=dev-libs/boost-1.35.0-r5[python] dev-lang/python:2.6[threads] )
	=sys-devel/libtool-2.2*
	sys-libs/zlib
	examples? ( !net-p2p/mldonkey )"  #292998
RDEPEND="${DEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${P}-ax_pthread_asneeded.patch
	eautoreconf
}

src_configure() {
	# use multi-threading versions of boost libs
	local BOOST_LIBS="--with-boost-system=boost_system-mt \
		--with-boost-filesystem=boost_filesystem-mt \
		--with-boost-thread=boost_thread-mt \
		--with-boost-python=boost_python-mt"

	# detect boost version and location, bug 295474
	BOOST_PKG="$(best_version ">=dev-libs/boost-1.34.1")"
	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
	BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
	BOOST_INC="/usr/include/boost-${BOOST_VER}"
	BOOST_LIB="/usr/$(get_libdir)/boost-${BOOST_VER}"

	local LOGGING
	use debug && LOGGING="--with-logging=verbose"

	econf $(use_enable debug) \
		$(use_enable test tests) \
		$(use_enable examples) \
		$(use_enable python python-binding) \
		--with-zlib=system \
		${LOGGING} \
		--with-boost=${BOOST_INC} \
		--with-boost-libdir=${BOOST_LIB} \
		${BOOST_LIBS}
}

src_install() {
	emake DESTDIR="${D}" install || die 'emake install failed'
	dodoc ChangeLog AUTHORS NEWS README || die 'dodoc failed'
	if use doc ; then
		dohtml docs/* || die "Could not install HTML documentation"
	fi
}