[gentoo-commits] gentoo-x86 commit in media-video/mjpg-streamer: mjpg-streamer-0_pre20110522.ebuild ChangeLog metadata.xml

[Amadeusz Zolnowski (aidecoe)]

aidecoe     11/11/17 20:00:39

  Added:                mjpg-streamer-0_pre20110522.ebuild ChangeLog
                        metadata.xml
  Log:
  media-video/mjpg-streamer: Initial ebuild. Fixes bug #260969.
  
  Proxy commit on behalf of Andrzej Pauli <andrzej.pauli@×××××.com>.
  
  (Portage version: 2.1.10.34/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  media-video/mjpg-streamer/mjpg-streamer-0_pre20110522.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/mjpg-streamer-0_pre20110522.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/mjpg-streamer-0_pre20110522.ebuild?rev=1.1&content-type=text/plain

Index: mjpg-streamer-0_pre20110522.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/mjpg-streamer-0_pre20110522.ebuild,v 1.1 2011/11/17 20:00:39 aidecoe Exp $

EAPI=4

inherit eutils

DESCRIPTION="MJPG-streamer takes JPGs from Linux-UVC compatible webcams"
HOMEPAGE="http://sourceforge.net/projects/mjpg-streamer"
SRC_URI="http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

INPUT_PLUGINS="input_testpicture input_control input_file input_uvc "
OUTPUT_PLUGINS="output_file output_udp output_http output_autofocus output_rtsp"
IUSE_PLUGINS="${INPUT_PLUGINS} ${OUTPUT_PLUGINS}"
IUSE="${IUSE_PLUGINS} www v4l"
REQUIRED_USE="|| ( ${INPUT_PLUGINS} )
	|| ( ${OUTPUT_PLUGINS} )
	v4l? ( input_uvc )"

RDEPEND="media-libs/jpeg
	v4l? ( input_uvc? ( media-libs/libv4l ) )"
DEPEND="${RDEPEND}
	input_testpicture? ( media-gfx/imagemagick )"

src_prepare() {
	epatch "${FILESDIR}/${PV}-make-var-instead-of-cmd.patch"

	local flag switch

	for flag in ${IUSE_PLUGINS}; do
		use ${flag} && switch='' || switch='#'
		sed -i \
			-e "s|^#*PLUGINS +\?= ${flag}.so|${switch}PLUGINS += ${flag}.so|" \
			Makefile
	done
}

src_compile() {
	local v4l=$(use v4l && use input_uvc && echo 'USE_LIBV4L2=true')
	emake ${v4l}
}

src_install() {
	into /usr
	dobin ${PN//-/_}
	dolib.so *.so

	if use www ; then
		insinto /usr/share/${PN}
		doins -r www
	fi

	dodoc README TODO

	newinitd "${FILESDIR}"/${PN}.initd ${PN}
	newconfd "${FILESDIR}"/${PN}.confd ${PN}
}

pkg_postinst() {
	elog "Remember to set an input and output plugin for mjpg-streamer."

	if use www ; then
		echo
		elog "An example webinterface has been installed into"
		elog "/usr/share/mjpg-streamer/www for your usage."
	fi
}



1.1                  media-video/mjpg-streamer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-video/mjpg-streamer
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/ChangeLog,v 1.1 2011/11/17 20:00:39 aidecoe Exp $

*mjpg-streamer-0_pre20110522 (17 Nov 2011)

  17 Nov 2011; Amadeusz Żołnowski <aidecoe@g.o>
  +files/0_pre20110522-make-var-instead-of-cmd.patch,
  +mjpg-streamer-0_pre20110522.ebuild, +files/mjpg-streamer.confd,
  +files/mjpg-streamer.initd, +metadata.xml:
  Proxy commit on behalf of Andrzej Pauli <andrzej.pauli@×××××.com>. Initial
  ebuild. Fixes bug #260969.




1.1                  media-video/mjpg-streamer/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>andrzej.pauli@×××××.com</email>
		<name>Andrzej Pauli</name>
		<description>Maintainer.  Assign bugs to him.</description>
	</maintainer>
	<maintainer>
		<email>aidecoe@g.o</email>
		<name>Amadeusz Żołnowski</name>
		<description>Proxy maintainer.  CC him on bugs.</description>
	</maintainer>
	<longdescription lang="en">
		MJPG-streamer takes JPGs from Linux-UVC compatible webcams, filesystem or
		other input plugins and streams them as M-JPEG via HTTP to webbrowsers,
		VLC and other software.  It is the successor of uvc-streamer, a Linux-UVC
		streaming application with Pan/Tilt
	</longdescription>
	<use>
		<flag name='input_testpicture'>Plugin for sending compiled in, test
			pictures</flag>
		<flag name='input_control'>Plugin giving ability to control camera
			movement (only specific cameras)</flag>
		<flag name='input_file'>Plugin that watches given directory and send
			it's content</flag>
		<flag name='input_uvc'>Plugin that sends video stream from UVC
			compatible camera</flag>
		<flag name='output_file'>Plugin that saves received content under given
			location</flag>
		<flag name='output_udp'>Plugin receiving content over UDP and storing to
			a directory</flag>
		<flag name='output_http'>Small HTTP server plugin which sends WWW
			directory content and streams image content</flag>
		<flag name='output_autofocus'>Auto focusing plugin</flag>
		<flag name='output_rtsp'>Plugin which provides a mechanism to take
			snapshots with a trigger from a UDP packet</flag>
		<flag name='www'>Installs WWW content</flag>
		<flag name='v4l'>Uses <pkg>media-libs/libv4l</pkg> function mapping for
			input_uvc plugin</flag>
	</use>
</pkgmetadata>