[gentoo-commits] repo/gentoo:master commit in: sys-cluster/ceph/

[Patrick McLean]

commit:     a449eb7c433b7d6c0cd4597dc83a40f86a6273f6
Author:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Thu Mar  3 01:52:00 2022 +0000
Commit:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Thu Mar  3 01:52:00 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a449eb7c

sys-cluster/ceph: remove old

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>

 sys-cluster/ceph/Manifest               |   1 -
 sys-cluster/ceph/ceph-15.2.15-r2.ebuild | 407 --------------------------------
 2 files changed, 408 deletions(-)

diff --git a/sys-cluster/ceph/Manifest b/sys-cluster/ceph/Manifest
index 88d06bae3ea1..93b972d33a05 100644
--- a/sys-cluster/ceph/Manifest
+++ b/sys-cluster/ceph/Manifest
@@ -1,5 +1,4 @@
 DIST ceph-14.2.22.tar.gz 130597047 BLAKE2B 58bbb3243de076ed1d25dfd7bd75717c50ad15d16690dcbd1511d1b506477845efc3ff7fbe713cf18fb8cfcc8c16707ad2a0f30159e3198ff82e57fbd2eb3cf2 SHA512 1c66661e1a39fa9151e95e33c390b810ffe269465d8785e2197cc15b8d83bd2edde77de48a8abd71a4da68cd5830ff14bcdf6b98fd17edabe85caeb1eca018d3
-DIST ceph-15.2.15.tar.gz 148584988 BLAKE2B 6ff629846a74c9b30c7e5d54731e2c85c67942f1871194cc8e704c56826b86cdd6163d6693805d9d6210bc0e3fc4d84fada12b9d81a5640e34d76be83cfe6e47 SHA512 e4d929ffda5c3e31767d93340fb97b5d49ca1d5641f6c30134ce5542486fc4f72684aef2ef47cb940a332e8b9144d8cec63ce8a9f86c773dbc0ccebdd8e7fb19
 DIST ceph-15.2.16.tar.gz 148628915 BLAKE2B 4f624078027c706428eae3eddd5b5479efe3b4442c19a4e6b6cdf8d3839cf56e2863b18249dc3c5079a7e25f60796bfec3202ffd695537587654f5e2f820caaa SHA512 532b8a5073e157fe9ed552b26976faeb64dc29b79a249910c0982134ad5f945d4f57d8bf451adf63487b6d285c6e4bd5c39f0e3fcd449230d6fb3087539f8c3b
 DIST ceph-16.2.5.tar.gz 155933825 BLAKE2B 3c8f3f1663b91d4de1e3736317add0b88d9083db5ab2fc3e2e913278977deec076bd4410e309f4e47ccc169d74356c2ab1221c94532cc45ee75ec73673fc42a0 SHA512 5c32f9aa817ecfa788725bcfe5743756853ca9b3f9ee453242110f1b5e1bdd1feaef79ad9ccf2b185445c9644bcecb1355e151a2255bfd27edc9818e0d6d4c4a
 DIST ceph-16.2.6.tar.gz 156087762 BLAKE2B e2595d1a958200e4f1877e4597c53319a9eee2e95606ea1b3ba2966a0d17f1cfcf52e05cca59752cc6ac383e32d944c380920d111aec840631235aef273a4de1 SHA512 f01e29088ae566d4111c21b5d0c173ddb02badaa0d8272f7f1548eb8e66a95dc7052b3945d9fb342e6c97a65c57648fda394317340d1f4236a57af7580073658

diff --git a/sys-cluster/ceph/ceph-15.2.15-r2.ebuild b/sys-cluster/ceph/ceph-15.2.15-r2.ebuild
deleted file mode 100644
index 6faac62ff814..000000000000
--- a/sys-cluster/ceph/ceph-15.2.15-r2.ebuild
+++ /dev/null
@@ -1,407 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-PYTHON_COMPAT=( python3_{7..9} )
-CMAKE_MAKEFILE_GENERATOR=emake
-
-DISTUTILS_OPTIONAL=1
-
-inherit check-reqs bash-completion-r1 cmake distutils-r1 flag-o-matic \
-		python-r1 udev readme.gentoo-r1 toolchain-funcs systemd tmpfiles \
-		multiprocessing
-
-if [[ ${PV} == *9999* ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/ceph/ceph.git"
-	SRC_URI=""
-else
-	SRC_URI="https://download.ceph.com/tarballs/${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm64 ~ppc64"
-fi
-
-DESCRIPTION="Ceph distributed filesystem"
-HOMEPAGE="https://ceph.com/"
-
-LICENSE="Apache-2.0 LGPL-2.1 CC-BY-SA-3.0 GPL-2 GPL-2+ LGPL-2+ LGPL-2.1 LGPL-3 GPL-3 BSD Boost-1.0 MIT public-domain"
-SLOT="0"
-
-CPU_FLAGS_X86=(sse{,2,3,4_1,4_2} ssse3)
-
-IUSE="babeltrace +cephfs custom-cflags diskprediction dpdk fuse grafana jemalloc
-	kafka kerberos ldap lttng +mgr numa pmdk rabbitmq +radosgw rbd-rwl +ssl spdk
-	+system-boost systemd +tcmalloc test uring xfs zfs"
-IUSE+=" $(printf "cpu_flags_x86_%s\n" ${CPU_FLAGS_X86[@]})"
-
-DEPEND="
-	acct-group/ceph
-	acct-user/ceph
-	virtual/libudev:=
-	app-arch/bzip2:=
-	app-arch/lz4:=
-	app-arch/snappy:=
-	|| ( >=app-arch/snappy-1.1.9-r1 <app-arch/snappy-1.1.9 )
-	app-arch/zstd:=
-	app-shells/bash:0
-	app-misc/jq:=
-	dev-libs/crypto++:=
-	dev-cpp/gflags:=
-	dev-libs/leveldb:=[snappy,tcmalloc(-)?]
-	dev-libs/libaio:=
-	dev-libs/libfmt:=
-	dev-libs/libnl:3=
-	dev-libs/libxml2:=
-	<dev-libs/rocksdb-6.15:=
-	dev-libs/xmlsec:=[openssl]
-	dev-cpp/yaml-cpp:=
-	dev-libs/nss:=
-	dev-libs/protobuf:=
-	net-dns/c-ares:=
-	net-libs/gnutls:=
-	sys-auth/oath-toolkit:=
-	sys-apps/coreutils
-	sys-apps/grep
-	sys-apps/hwloc:=
-	sys-apps/keyutils:=
-	sys-apps/util-linux:=
-	sys-apps/sed
-	sys-apps/util-linux
-	sys-libs/libcap-ng:=
-	sys-libs/ncurses:0=
-	sys-libs/zlib:=
-	sys-process/numactl:=
-	virtual/libcrypt:=
-	x11-libs/libpciaccess:=
-	babeltrace? ( dev-util/babeltrace )
-	fuse? ( sys-fs/fuse:0= )
-	jemalloc? ( dev-libs/jemalloc:= )
-	!jemalloc? ( >=dev-util/google-perftools-2.6.1:= )
-	kafka? ( dev-libs/librdkafka:= )
-	kerberos? ( virtual/krb5 )
-	ldap? ( net-nds/openldap:= )
-	lttng? ( dev-util/lttng-ust:= )
-	pmdk? ( dev-libs/pmdk:= )
-	rabbitmq? ( net-libs/rabbitmq-c:= )
-	radosgw? (
-		dev-libs/expat:=
-		dev-libs/openssl:=
-		net-misc/curl:=[curl_ssl_openssl]
-	)
-	rbd-rwl? ( dev-libs/pmdk:= )
-	ssl? ( dev-libs/openssl:= )
-	system-boost? ( >=dev-libs/boost-1.72:=[threads(+),context,python,${PYTHON_USEDEP}] )
-	!system-boost? ( <sys-libs/glibc-2.34 )
-	uring? ( sys-libs/liburing:= )
-	xfs? ( sys-fs/xfsprogs:= )
-	zfs? ( sys-fs/zfs:= )
-"
-BDEPEND="
-	${PYTHON_DEPS}
-	amd64? ( dev-lang/yasm )
-	x86? ( dev-lang/yasm )
-	app-arch/cpio
-	>=dev-util/cmake-3.5.0
-	dev-python/cython[${PYTHON_USEDEP}]
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	dev-python/sphinx
-	dev-util/cunit
-	dev-util/gperf
-	dev-util/ragel
-	dev-util/valgrind
-	sys-apps/coreutils
-	sys-apps/grep
-	sys-apps/sed
-	sys-apps/which
-	sys-devel/bc
-	sys-devel/patch
-	virtual/pkgconfig
-	test? (
-		dev-python/coverage[${PYTHON_USEDEP}]
-		dev-python/virtualenv[${PYTHON_USEDEP}]
-		dev-python/requests-mock[${PYTHON_USEDEP}]
-		sys-apps/grep[pcre]
-		sys-fs/btrfs-progs
-	)
-"
-RDEPEND="${DEPEND}
-	${PYTHON_DEPS}
-	app-admin/sudo
-	net-misc/socat
-	sys-apps/gptfdisk
-	sys-apps/nvme-cli
-	>=sys-apps/smartmontools-7.0
-	sys-block/parted
-	sys-fs/cryptsetup
-	sys-fs/lsscsi
-	sys-fs/lvm2[-device-mapper-only(-)]
-	virtual/awk
-	dev-python/bcrypt[${PYTHON_USEDEP}]
-	dev-python/cherrypy[${PYTHON_USEDEP}]
-	dev-python/python-dateutil[${PYTHON_USEDEP}]
-	dev-python/flask[${PYTHON_USEDEP}]
-	dev-python/jinja[${PYTHON_USEDEP}]
-	dev-python/pecan[${PYTHON_USEDEP}]
-	dev-python/prettytable[${PYTHON_USEDEP}]
-	dev-python/pyopenssl[${PYTHON_USEDEP}]
-	dev-python/requests[${PYTHON_USEDEP}]
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	dev-python/werkzeug[${PYTHON_USEDEP}]
-	mgr? (
-		dev-python/jsonpatch[${PYTHON_USEDEP}]
-		dev-python/more-itertools[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/pyjwt[${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-		dev-python/routes[${PYTHON_USEDEP}]
-		sci-libs/scikit-learn[${PYTHON_USEDEP}]
-		dev-python/six[${PYTHON_USEDEP}]
-	)
-"
-# diskprediction needs older scipy not compatible with py38
-# bug #724438
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	?? ( jemalloc tcmalloc )
-	diskprediction? ( mgr !python_targets_python3_8 )
-	kafka? ( radosgw )
-	mgr? ( cephfs )
-	rabbitmq? ( radosgw )
-"
-RESTRICT="!test? ( test )"
-
-# the tests need root access
-RESTRICT="test? ( userpriv )"
-
-# distribution tarball does not include everything needed for tests
-RESTRICT+=" test"
-
-# create a non-debug release
-CMAKE_BUILD_TYPE=RelWithDebInfo
-
-# false positives unless all USE flags are on
-CMAKE_WARN_UNUSED_CLI=no
-
-PATCHES=(
-	"${FILESDIR}/ceph-12.2.0-use-provided-cpu-flag-values.patch"
-	"${FILESDIR}/ceph-14.2.0-cflags.patch"
-	"${FILESDIR}/ceph-12.2.4-boost-build-none-options.patch"
-	"${FILESDIR}/ceph-13.2.0-cflags.patch"
-	"${FILESDIR}/ceph-15.2.15-no-virtualenvs.patch"
-	"${FILESDIR}/ceph-13.2.2-dont-install-sysvinit-script.patch"
-	"${FILESDIR}/ceph-14.2.0-dpdk-cflags.patch"
-	"${FILESDIR}/ceph-14.2.0-cython-0.29.patch"
-	"${FILESDIR}/ceph-15.2.0-rocksdb-cmake.patch"
-	"${FILESDIR}/ceph-15.2.2-systemd-unit.patch"
-	"${FILESDIR}/ceph-15.2.3-spdk-compile.patch"
-	"${FILESDIR}/ceph-15.2.4-system-uring.patch"
-	"${FILESDIR}/ceph-15.2.9-dont-compile-isal_compress-if-don-t-have-SSE4_1.patch"
-	"${FILESDIR}/ceph-15.2.15-snappy-1.1.9.patch"
-)
-
-check-reqs_export_vars() {
-	CHECKREQS_DISK_BUILD="5400M"
-	CHECKREQS_DISK_USR="510M"
-
-	export CHECKREQS_DISK_BUILD CHECKREQS_DISK_USR
-}
-
-pkg_pretend() {
-	check-reqs_export_vars
-	check-reqs_pkg_pretend
-}
-
-pkg_setup() {
-	python_setup
-	check-reqs_export_vars
-	check-reqs_pkg_setup
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	if use system-boost; then
-		find "${S}" -name '*.cmake' -or -name 'CMakeLists.txt' -print0 \
-			| xargs --null sed -r \
-			-e 's|Boost::|boost_|g' \
-			-e 's|Boost_|boost_|g' \
-			-e 's|[Bb]oost_boost|boost_system|g' -i || die
-	fi
-
-	sed -r -e "s:DESTINATION .+\\):DESTINATION $(get_bashcompdir)\\):" \
-		-i src/bash_completion/CMakeLists.txt || die
-
-	sed  -e "s:objdump -p:$(tc-getOBJDUMP) -p:" -i CMakeLists.txt || die
-
-	if ! use diskprediction; then
-		rm -rf src/pybind/mgr/diskprediction_local || die
-	fi
-
-	# remove tests that need root access
-	rm src/test/cli/ceph-authtool/cap*.t || die
-}
-
-ceph_src_configure() {
-	local flag
-	local mycmakeargs=(
-		-DWITH_BABELTRACE=$(usex babeltrace)
-		-DWITH_BLUESTORE_PMEM=$(usex pmdk)
-		-DWITH_CEPHFS=$(usex cephfs)
-		-DWITH_CEPHFS_SHELL=$(usex cephfs)
-		-DWITH_DPDK=$(usex dpdk)
-		-DWITH_SPDK=$(usex spdk)
-		-DWITH_FUSE=$(usex fuse)
-		-DWITH_LTTNG=$(usex lttng)
-		-DWITH_GSSAPI=$(usex kerberos)
-		-DWITH_GRAFANA=$(usex grafana)
-		-DWITH_MGR=$(usex mgr)
-		-DWITH_MGR_DASHBOARD_FRONTEND=OFF
-		-DWITH_NUMA=$(usex numa)
-		-DWITH_OPENLDAP=$(usex ldap)
-		-DWITH_PYTHON3=3
-		-DWITH_RADOSGW=$(usex radosgw)
-		-DWITH_RADOSGW_AMQP_ENDPOINT=$(usex rabbitmq)
-		-DWITH_RADOSGW_KAFKA_ENDPOINT=$(usex kafka)
-		-DWITH_RBD_RWL=$(usex rbd-rwl)
-		-DWITH_SSL=$(usex ssl)
-		-DWITH_SYSTEMD=$(usex systemd)
-		-DWITH_TESTS=$(usex test)
-		-DWITH_LIBURING=$(usex uring)
-		-DWITH_XFS=$(usex xfs)
-		-DWITH_ZFS=$(usex zfs)
-		-DENABLE_SHARED="ON"
-		-DALLOCATOR=$(usex tcmalloc 'tcmalloc' "$(usex jemalloc 'jemalloc' 'libc')")
-		-DWITH_SYSTEM_PMDK=$(usex pmdk 'YES' "$(usex rbd-rwl)")
-		-DWITH_SYSTEM_BOOST=$(usex system-boost)
-		-DBOOST_J=$(makeopts_jobs)
-		-DWITH_SYSTEM_ROCKSDB=ON
-		-DWITH_RDMA=OFF
-		-DWITH_TBB=OFF
-		-DSYSTEMD_UNITDIR=$(systemd_get_systemunitdir)
-		-DCMAKE_INSTALL_SYSTEMD_SERVICEDIR=$(systemd_get_systemunitdir)
-		-DEPYTHON_VERSION="${EPYTHON#python}"
-		-DCMAKE_INSTALL_DOCDIR="${EPREFIX}/usr/share/doc/${PN}-${PVR}"
-		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
-		-Wno-dev
-	)
-	if use amd64 || use x86; then
-		for flag in ${CPU_FLAGS_X86[@]}; do
-			mycmakeargs+=("$(usex cpu_flags_x86_${flag} "-DHAVE_INTEL_${flag^^}=1")")
-		done
-	fi
-
-	# needed for >=glibc-2.32
-	has_version '>=sys-libs/glibc-2.32' && mycmakeargs+=(-DWITH_REENTRANT_STRSIGNAL:BOOL=ON)
-
-	rm -f "${BUILD_DIR:-${S}}/CMakeCache.txt" \
-		|| die "failed to remove cmake cache"
-
-	cmake_src_configure
-
-	# bug #630232
-	sed -i "s:\"${T//:\\:}/${EPYTHON}/bin/python\":\"${PYTHON}\":" \
-		"${BUILD_DIR:-${S}}"/include/acconfig.h \
-		|| die "sed failed"
-}
-
-src_configure() {
-	use custom-cflags || strip-flags
-	ceph_src_configure
-}
-
-python_compile() {
-	local CMAKE_USE_DIR="${S}"
-	ceph_src_configure
-
-	pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
-	emake VERBOSE=1 clean
-	emake VERBOSE=1 all
-
-	# python modules are only compiled with "make install" so we need to do this to
-	# prevent doing a bunch of compilation in src_install
-	DESTDIR="${T}" emake VERBOSE=1 install
-	popd >/dev/null || die
-}
-
-src_compile() {
-	cmake_build VERBOSE=1 all
-
-	# we have to do this here to prevent from building everything multiple times
-	python_copy_sources
-	python_foreach_impl python_compile
-}
-
-src_test() {
-	make check || die "make check failed"
-}
-
-python_install() {
-	local CMAKE_USE_DIR="${S}"
-	pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
-	DESTDIR="${ED}" emake VERBOSE=1 install
-	popd >/dev/null || die
-
-	python_optimize
-}
-
-src_install() {
-	cmake_src_install
-	python_foreach_impl python_install
-
-	find "${ED}" -name '*.la' -type f -delete || die
-
-	exeinto /usr/$(get_libdir)/ceph
-	newexe "${BUILD_DIR}/bin/init-ceph" init-ceph
-
-	insinto /etc/logrotate.d/
-	newins "${FILESDIR}"/ceph.logrotate-r2 ${PN}
-
-	keepdir /var/lib/${PN}{,/tmp} /var/log/${PN}/stat
-
-	fowners -R ceph:ceph /var/log/ceph
-
-	newinitd "${FILESDIR}/rbdmap.initd-r1" rbdmap
-	newinitd "${FILESDIR}/${PN}.initd-r12" ${PN}
-	newconfd "${FILESDIR}/${PN}.confd-r5" ${PN}
-
-	insinto /etc/sysctl.d
-	newins "${FILESDIR}"/sysctld 90-${PN}.conf
-
-	use tcmalloc && newenvd "${FILESDIR}"/envd-tcmalloc 99${PN}-tcmalloc
-
-	# units aren't installed by the build system unless systemd is enabled
-	# so no point installing these with the USE flag disabled
-	if use systemd; then
-		systemd_install_serviced "${FILESDIR}/ceph-mds_at.service.conf" \
-			"ceph-mds@.service"
-
-		systemd_install_serviced "${FILESDIR}/ceph-osd_at.service.conf" \
-			"ceph-osd@.service"
-
-	fi
-
-	udev_dorules udev/*.rules
-	newtmpfiles "${FILESDIR}"/ceph-tmpfilesd ${PN}.conf
-
-	readme.gentoo_create_doc
-
-	python_setup
-
-	# bug #630232
-	sed -i -r "s:${T//:/\\:}/${EPYTHON}:/usr:" "${ED}"/usr/bin/ceph{,-crash} \
-		|| die "sed failed"
-
-	python_fix_shebang "${ED}"/usr/{,s}bin/
-
-	# python_fix_shebang apparently is not idempotent
-	local shebang_regex='(/usr/lib/python-exec/python[0-9]\.[0-9]/python)[0-9]\.[0-9]'
-	grep -r -E -l --null "${shebang_regex}" "${ED}"/usr/{s,}bin/ \
-		| xargs --null --no-run-if-empty -- sed -i -r  "s:${shebang_regex}:\1:" || die
-
-	local -a rados_classes=( "${ED}/usr/$(get_libdir)/rados-classes"/* )
-	dostrip -x "${rados_classes[@]#${ED}}"
-}
-
-pkg_postinst() {
-	readme.gentoo_print_elog
-	tmpfiles_process ${PN}.conf
-}