[gentoo-commits] gentoo-x86 commit in net-misc/apt-cacher-ng: ChangeLog apt-cacher-ng-0.8.2.ebuild apt-cacher-ng-0.8.0-r1.ebuild

[Jeroen Roovers (jer)]

jer         15/04/30 04:29:58

  Modified:             ChangeLog
  Added:                apt-cacher-ng-0.8.2.ebuild
  Removed:              apt-cacher-ng-0.8.0-r1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.52                 net-misc/apt-cacher-ng/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	12 Apr 2015 06:16:14 -0000	1.51
+++ ChangeLog	30 Apr 2015 04:29:58 -0000	1.52
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/apt-cacher-ng
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v 1.51 2015/04/12 06:16:14 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/ChangeLog,v 1.52 2015/04/30 04:29:58 jer Exp $
+
+*apt-cacher-ng-0.8.2 (30 Apr 2015)
+
+  30 Apr 2015; Jeroen Roovers <jer@g.o> -apt-cacher-ng-0.8.0-r1.ebuild,
+  +apt-cacher-ng-0.8.2.ebuild:
+  Version bump.
 
 *apt-cacher-ng-0.8.1 (12 Apr 2015)
 



1.1                  net-misc/apt-cacher-ng/apt-cacher-ng-0.8.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.8.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.8.2.ebuild?rev=1.1&content-type=text/plain

Index: apt-cacher-ng-0.8.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/apt-cacher-ng/apt-cacher-ng-0.8.2.ebuild,v 1.1 2015/04/30 04:29:58 jer Exp $

EAPI=5
inherit cmake-utils eutils toolchain-funcs user

DESCRIPTION="Yet another implementation of an HTTP proxy for Debian/Ubuntu software packages written in C++"
HOMEPAGE="
	http://www.unix-ag.uni-kl.de/~bloch/acng/
	http://packages.qa.debian.org/a/apt-cacher-ng.html
"
LICENSE="BSD-4 ZLIB public-domain"
SLOT="0"
SRC_URI="mirror://debian/pool/main/a/${PN}/${PN}_${PV}.orig.tar.xz"

KEYWORDS="~amd64 ~x86"
IUSE="doc fuse systemd tcpd"

COMMON_DEPEND="
	app-arch/bzip2
	app-arch/xz-utils
	sys-libs/zlib
	systemd? (
		sys-apps/systemd
	)
"
DEPEND="
	${COMMON_DEPEND}
	dev-util/cmake
	>sys-devel/gcc-4.8
	virtual/pkgconfig
"
RDEPEND="
	${COMMON_DEPEND}
	dev-lang/perl
	fuse? ( sys-fs/fuse )
	tcpd? ( sys-apps/tcp-wrappers )
"

S=${WORKDIR}/${P/_}

pkg_pretend() {
	if [[ $(gcc-major-version) = 4 ]]; then
		if [[ $(gcc-minor-version) -lt 8 ]]; then
			die "GCC 4.8 or greater is required but you have $(gcc-major-version).$(gcc-minor-version)"
		fi
	else
		die "GCC 4.8 or greater is required but you have $(gcc-major-version).$(gcc-minor-version)"
	fi
}

pkg_setup() {
	# add new user & group for daemon
	enewgroup ${PN}
	enewuser ${PN} -1 -1 -1 ${PN}
}

src_configure(){
	mycmakeargs="-DCMAKE_INSTALL_PREFIX=/usr"
	if use fuse; then
		mycmakeargs="-DHAVE_FUSE_25=yes ${mycmakeargs}"
	else
		mycmakeargs="-DHAVE_FUSE_25=no ${mycmakeargs}"
	fi
	if use tcpd; then
		mycmakeargs="-DHAVE_LIBWRAP=yes ${mycmakeargs}"
	else
		mycmakeargs="-DHAVE_LIBWRAP=no ${mycmakeargs}"
	fi

	cmake-utils_src_configure
}

src_install() {
	pushd ${CMAKE_BUILD_DIR}
	dosbin ${PN}
	if use fuse; then
		dobin acngfs
	fi
	popd

	newinitd "${FILESDIR}"/initd-r1 ${PN}
	newconfd "${FILESDIR}"/confd ${PN}

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/logrotate ${PN}

	doman doc/man/${PN}*
	if use fuse; then
		doman doc/man/acngfs*
	fi

	# Documentation
	dodoc README TODO VERSION INSTALL ChangeLog
	if use doc; then
		dodoc doc/*.pdf
		dohtml doc/html/*
		docinto examples/conf
		dodoc conf/*
	fi

	# perl daily cron script
	dosbin scripts/expire-caller.pl
	exeinto /etc/cron.daily
	newexe "${FILESDIR}"/cron.daily ${PN}

	# default configuration
	insinto /etc/${PN}
	newins conf/acng.conf ${PN}.conf
	doins $( echo conf/* | sed 's|conf/acng.conf||g' )

	keepdir /var/log/${PN}
	# Some directories must exists
	keepdir /var/log/${PN}
	fowners -R ${PN}:${PN} \
		/etc/${PN} \
		/var/log/${PN}
}