[gentoo-commits] gentoo-x86 commit in media-libs/ladspa-cmt: ladspa-cmt-1.16-r4.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      14/05/03 09:27:38

  Modified:             ChangeLog
  Added:                ladspa-cmt-1.16-r4.ebuild
  Log:
  Enable multilib support. Replace invalid userland_Darwin with elibc_Darwin.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.55                 media-libs/ladspa-cmt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-cmt/ChangeLog?rev=1.55&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-cmt/ChangeLog?rev=1.55&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-cmt/ChangeLog?r1=1.54&r2=1.55

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/ladspa-cmt/ChangeLog,v
retrieving revision 1.54
retrieving revision 1.55
diff -u -r1.54 -r1.55
--- ChangeLog	24 Apr 2014 13:30:26 -0000	1.54
+++ ChangeLog	3 May 2014 09:27:38 -0000	1.55
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/ladspa-cmt
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/ladspa-cmt/ChangeLog,v 1.54 2014/04/24 13:30:26 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/ladspa-cmt/ChangeLog,v 1.55 2014/05/03 09:27:38 mgorny Exp $
+
+*ladspa-cmt-1.16-r4 (03 May 2014)
+
+  03 May 2014; Michał Górny <mgorny@g.o> +ladspa-cmt-1.16-r4.ebuild:
+  Enable multilib support. Replace invalid userland_Darwin with elibc_Darwin.
 
   24 Apr 2014; Julian Ospald <hasufell@g.o> ladspa-cmt-1.16-r3.ebuild:
   fix deps



1.1                  media-libs/ladspa-cmt/ladspa-cmt-1.16-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-cmt/ladspa-cmt-1.16-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-cmt/ladspa-cmt-1.16-r4.ebuild?rev=1.1&content-type=text/plain

Index: ladspa-cmt-1.16-r4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/ladspa-cmt/ladspa-cmt-1.16-r4.ebuild,v 1.1 2014/05/03 09:27:38 mgorny Exp $

EAPI=5

inherit eutils multilib toolchain-funcs multilib-minimal

S="${WORKDIR}/cmt/src"
MY_P="cmt_src_${PV}"

DESCRIPTION="CMT (computer music toolkit) Lasdpa library plugins"
HOMEPAGE="http://www.ladspa.org/"
SRC_URI="http://www.ladspa.org/download/${MY_P}.tgz"

KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
LICENSE="LGPL-2.1"
SLOT="0"
IUSE=""

DEPEND="media-libs/ladspa-sdk[${MULTILIB_USEDEP}]"
RDEPEND=""

src_prepare() {
	sed -i \
		-e "/^CFLAGS/ s/-O3/${CFLAGS}/" \
		-e 's|/usr/local/include||g' \
		-e 's|/usr/local/lib||g' makefile \
			|| die "sed makefile failed"
	sed -i -e "s/^CXXFLAGS*/CXXFLAGS = ${CXXFLAGS} \$(INCLUDES) -Wall -fPIC\n#/" \
		"${S}/makefile" || die "sed makefile failed (CXXFLAGS)"

	cd "${S}" || die
	epatch "${FILESDIR}/${P}-mallocstdlib.patch"
	epatch "${FILESDIR}/${P}-respect-ldflags.patch"
	epatch "${FILESDIR}/${P}-sa.patch"
	use elibc_Darwin && epatch "${FILESDIR}/${P}-darwin.patch"
	multilib_copy_sources
}

multilib_src_compile() {
	tc-export CXX
	emake PLUGIN_LIB="cmt.so"
}

multilib_src_install() {
	insopts -m755
	insinto /usr/$(get_libdir)/ladspa
	doins *.so
}

multilib_src_install_all() {
	insinto /usr/share/ladspa/rdf/
	doins "${FILESDIR}/cmt.rdf"

	dodoc ../README
	dohtml ../doc/*
}