[gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/

[Mike Frysinger]

commit:     b991c01228864d2b13999efb0fb3bd756631dcb5
Author:     Mike Frysinger <vapier <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 21 18:34:36 2016 +0000
Commit:     Mike Frysinger <vapier <AT> gentoo <DOT> org>
CommitDate: Sun Feb 21 19:03:43 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b991c012

dev-libs/efl: version bump to 1.17.0 #573784

 dev-libs/efl/Manifest          |   1 +
 dev-libs/efl/efl-1.17.0.ebuild | 277 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 278 insertions(+)

diff --git a/dev-libs/efl/Manifest b/dev-libs/efl/Manifest
index 1e9d7e7..27b8be9 100644
--- a/dev-libs/efl/Manifest
+++ b/dev-libs/efl/Manifest
@@ -2,3 +2,4 @@ DIST efl-1.12.2-lauch_via_logind_or_root_privilege.patch.xz 6276 SHA256 9af4e2cc
 DIST efl-1.12.2.tar.bz2 46808743 SHA256 aa1a6b95de3d92dda819e1245254e3d9c0d68f77d27d89afb1ae3f2244c0bf0c SHA512 8d137a4cd7a11f102b949bfc7047b3be870df6d7ede72765b005914729bf291f59d1f70b69ab7fbbd3328975068aa5ded2f10e556a7d4f7c31aedfcd0d7340e9 WHIRLPOOL 531f81000dafbd88dacd24588a3832a7c2afccf466d070d78d86641b8c0e3e64854c4f9d8dfe46ab0fb84fd6890ac6eb3e8e63d02ef58bedf88c265412f3ddf7
 DIST efl-1.15.2.tar.xz 43176564 SHA256 dd738f19f454621a7fa1fdb4c008457c170989f5f0c535edfed7b6773ae6c2a4 SHA512 bee8d7473bac73545ca02180f42614b7ae6ee0628fe8879b35bbf6809353535df8b1fa01f19ddc81d2ee1ecb5e36512b63c3be4b6b982f4efe8e410aa8ad5c56 WHIRLPOOL 380debdded1989412579cbe17d057512acb8381527c6c50606e6e936ea8bd0f1f1077861ca9afbb5661f404eb658c0dc288d991b204fbca72506d7b89f511df2
 DIST efl-1.16.1.tar.xz 43216556 SHA256 ef01be81598f03aa0e873951cf8280d963fad2b543cdbd3d749916e91825da84 SHA512 85ea5ec7a0d79ce4d9b4308cc262922b0c7b21bef8e415ea774e5e1c7916519a02f9c9526dc2d47c985c055796a81df173a78ea1cb13d2440b87b865473ee38c WHIRLPOOL 03e0398fcc09ebfcbaf5567224f028da273e225d7281553e5ff1997d52b1a3ef2c74423bc58ac2eeb12ac10d20068a6062d870cbc4fdc3b746866af72f5db0db
+DIST efl-1.17.0.tar.xz 43485360 SHA256 c13540bad764d014fea2c079fad8fcca62e5c229994d43aa4eb692d2c9b73afe SHA512 e4f28f938daf4ec1cb3d761407a443e401b59c6bb0f9fa6cd771dbd256b95f4a32a5f9e6bd8ad8328708a382f732e67abd1a23c7be2ff222f08bc8135a2435da WHIRLPOOL a9687320a5a61a727dd1ad8d757b260f72165ed54fb311cb0ff0c33590b8fc083aae1850cd8bdc5ae5c7506df119a445457cda9e076193692130c92e01e2d5bf

diff --git a/dev-libs/efl/efl-1.17.0.ebuild b/dev-libs/efl/efl-1.17.0.ebuild
new file mode 100644
index 0000000..3972324
--- /dev/null
+++ b/dev-libs/efl/efl-1.17.0.ebuild
@@ -0,0 +1,277 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+MY_P=${P/_/-}
+
+if [[ "${PV}" == "9999" ]] ; then
+	EGIT_SUB_PROJECT="core"
+	EGIT_URI_APPEND="${PN}"
+elif [[ *"${PV}" == *"_pre"* ]] ; then
+	MY_P=${P%%_*}
+	SRC_URI="https://download.enlightenment.org/pre-releases/${MY_P}.tar.xz"
+	EKEY_STATE="snap"
+else
+	SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${MY_P}.tar.xz"
+	EKEY_STATE="snap"
+fi
+
+inherit enlightenment pax-utils
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+IUSE="+bmp debug drm +eet egl fbcon +fontconfig fribidi gif gles glib gnutls gstreamer harfbuzz +ico ibus jpeg2k libressl neon oldlua opengl ssl physics pixman +png +ppm +psd pulseaudio scim sdl sound systemd tga tiff tslib v4l2 valgrind wayland webp X xim xine xpm"
+
+REQUIRED_USE="
+	pulseaudio?	( sound )
+	opengl?		( || ( X sdl wayland ) )
+	gles?		( || ( X wayland ) )
+	gles?		( !sdl )
+	gles?		( egl )
+	sdl?		( opengl )
+	wayland?	( egl !opengl gles )
+	xim?		( X )
+"
+
+RDEPEND="
+	drm? (
+		>=dev-libs/libinput-0.8
+		media-libs/mesa[gbm]
+		>=x11-libs/libdrm-2.4
+		>=x11-libs/libxkbcommon-0.3.0
+	)
+	fontconfig? ( media-libs/fontconfig )
+	fribidi? ( dev-libs/fribidi )
+	gif? ( media-libs/giflib )
+	glib? ( dev-libs/glib:2 )
+	gnutls? ( net-libs/gnutls )
+	!gnutls? (
+		ssl? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl )
+		)
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	harfbuzz? ( media-libs/harfbuzz )
+	ibus? ( app-i18n/ibus )
+	jpeg2k? ( media-libs/openjpeg:0 )
+	!oldlua? ( >=dev-lang/luajit-2.0.0 )
+	oldlua? ( dev-lang/lua:* )
+	physics? ( >=sci-physics/bullet-2.80 )
+	pixman? ( x11-libs/pixman )
+	png? ( media-libs/libpng:0= )
+	pulseaudio? ( media-sound/pulseaudio )
+	scim? ( app-i18n/scim )
+	sdl? (
+		media-libs/libsdl2
+		virtual/opengl
+	)
+	sound? ( media-libs/libsndfile )
+	systemd? ( sys-apps/systemd )
+	tiff? ( media-libs/tiff:0= )
+	tslib? ( x11-libs/tslib )
+	valgrind? ( dev-util/valgrind )
+	wayland? (
+		>=dev-libs/wayland-1.8.0
+		>=x11-libs/libxkbcommon-0.3.1
+		media-libs/mesa[gles2,wayland]
+	)
+	webp? ( media-libs/libwebp )
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libX11
+		x11-libs/libXcomposite
+		x11-libs/libXdamage
+		x11-libs/libXext
+		x11-libs/libXfixes
+		x11-libs/libXinerama
+		x11-libs/libXp
+		x11-libs/libXrandr
+		x11-libs/libXrender
+		x11-libs/libXtst
+		x11-libs/libXScrnSaver
+
+		opengl? (
+			x11-libs/libX11
+			x11-libs/libXrender
+			virtual/opengl
+		)
+
+		gles? (
+			x11-libs/libX11
+			x11-libs/libXrender
+			virtual/opengl
+		)
+	)
+	xine? ( >=media-libs/xine-lib-1.1.1 )
+	xpm? ( x11-libs/libXpm )
+
+	sys-apps/dbus
+	>=sys-apps/util-linux-2.20.0
+	sys-libs/zlib
+	virtual/jpeg:0=
+
+	!dev-libs/ecore
+	!dev-libs/edbus
+	!dev-libs/eet
+	!dev-libs/eeze
+	!dev-libs/efreet
+	!dev-libs/eina
+	!dev-libs/eio
+	!dev-libs/embryo
+	!dev-libs/eobj
+	!dev-libs/ephysics
+	!media-libs/edje
+	!media-libs/emotion
+	!media-libs/ethumb
+	!media-libs/evas
+"
+#external lz4 support currently broken because of unstable ABI/API
+#	app-arch/lz4
+
+#soft blockers added above for binpkg users
+#hard blocks are needed for building
+CORE_EFL_CONFLICTS="
+	!!dev-libs/ecore
+	!!dev-libs/edbus
+	!!dev-libs/eet
+	!!dev-libs/eeze
+	!!dev-libs/efreet
+	!!dev-libs/eina
+	!!dev-libs/eio
+	!!dev-libs/embryo
+	!!dev-libs/eobj
+	!!dev-libs/ephysics
+	!!media-libs/edje
+	!!media-libs/emotion
+	!!media-libs/ethumb
+	!!media-libs/evas
+"
+
+DEPEND="
+	${CORE_EFL_CONFLICTS}
+
+	${RDEPEND}
+	doc? ( app-doc/doxygen )
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	enlightenment_src_prepare
+
+	# Remove stupid sleep command.
+	# Also back out gnu make hack that causes regen of Makefiles.
+	# Delete var setting that causes the build to abort.
+	sed -i \
+		-e '/sleep 10/d' \
+		-e '/^#### Work around bug in automake check macro$/,/^#### Info$/d' \
+		-e '/BARF_OK=/s:=.*:=:' \
+		configure || die
+}
+
+src_configure() {
+	if use ssl && use gnutls ; then
+		einfo "You enabled both USE=ssl and USE=gnutls, but only one can be used;"
+		einfo "gnutls has been selected for you."
+	fi
+	if use opengl && use gles ; then
+		einfo "You enabled both USE=opengl and USE=gles, but only one can be used;"
+		einfo "opengl has been selected for you."
+	fi
+
+	E_ECONF=(
+		--with-profile=$(usex debug debug release)
+		--with-crypto=$(usex gnutls gnutls $(usex ssl openssl none))
+		--with-x11=$(usex X xlib none)
+		$(use_with X x)
+		--with-opengl=$(usex opengl full $(usex gles es none))
+		--with-glib=$(usex glib)
+		--enable-i-really-know-what-i-am-doing-and-that-this-will-probably-break-things-and-i-will-fix-them-myself-and-send-patches-abb
+
+		$(use_enable bmp image-loader-bmp)
+		$(use_enable bmp image-loader-wbmp)
+		$(use_enable drm)
+		$(use_enable doc)
+		$(use_enable eet image-loader-eet)
+		$(use_enable egl)
+		$(use_enable fbcon fb)
+		$(use_enable fontconfig)
+		$(use_enable fribidi)
+		$(use_enable gif image-loader-gif)
+		$(use_enable gstreamer gstreamer1)
+		$(use_enable harfbuzz)
+		$(use_enable ico image-loader-ico)
+		$(use_enable ibus)
+		$(use_enable jpeg2k image-loader-jp2k)
+		$(use_enable neon)
+		$(use_enable nls)
+		$(use_enable oldlua lua-old)
+		$(use_enable physics)
+		$(use_enable pixman)
+		$(use_enable pixman pixman-font)
+		$(use_enable pixman pixman-rect)
+		$(use_enable pixman pixman-line)
+		$(use_enable pixman pixman-poly)
+		$(use_enable pixman pixman-image)
+		$(use_enable pixman pixman-image-scale-sample)
+		$(use_enable png image-loader-png)
+		$(use_enable ppm image-loader-pmaps)
+		$(use_enable psd image-loader-psd)
+		$(use_enable pulseaudio)
+		$(use_enable scim)
+		$(use_enable sdl)
+		$(use_enable sound audio)
+		$(use_enable systemd)
+		$(use_enable tga image-loader-tga)
+		$(use_enable tiff image-loader-tiff)
+		$(use_enable tslib)
+		$(use_enable v4l2)
+		$(use_enable valgrind)
+		$(use_enable wayland)
+		$(use_enable webp image-loader-webp)
+		$(use_enable xim)
+		$(use_enable xine)
+		$(use_enable xpm image-loader-xpm)
+		--enable-cserve
+		--enable-image-loader-generic
+		--enable-image-loader-jpeg
+
+		--disable-tizen
+		--disable-gesture
+		--disable-gstreamer
+		--enable-xinput2
+		--disable-xinput22
+		--disable-multisense
+		--enable-libmount
+
+		# external lz4 support currently broken because of unstable ABI/API
+		#--enable-liblz4
+	)
+
+	enlightenment_src_configure
+}
+
+src_compile() {
+	if host-is-pax && ! use oldlua ; then
+		# We need to build the lua code first so we can pax-mark it. #547076
+		local target='_e_built_sources_target_gogogo_'
+		printf '%s: $(BUILT_SOURCES)\n' "${target}" >> src/Makefile || die
+		emake -C src "${target}"
+		emake -C src bin/elua/elua
+		pax-mark m src/bin/elua/.libs/elua
+	fi
+	enlightenment_src_compile
+}
+
+src_install() {
+	MAKEOPTS+=" -j1"
+
+	enlightenment_src_install
+}