[gentoo-commits] gentoo-x86 commit in sys-apps/usb_modeswitch: usb_modeswitch-1.2.5_p20121109.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    12/11/28 23:00:08

  Modified:             ChangeLog
  Added:                usb_modeswitch-1.2.5_p20121109.ebuild
  Log:
  Version bump (of both, the program and the data files)
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.38                 sys-apps/usb_modeswitch/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	28 Nov 2012 22:53:09 -0000	1.37
+++ ChangeLog	28 Nov 2012 23:00:08 -0000	1.38
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/usb_modeswitch
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog,v 1.37 2012/11/28 22:53:09 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/ChangeLog,v 1.38 2012/11/28 23:00:08 ssuominen Exp $
+
+*usb_modeswitch-1.2.5_p20121109 (28 Nov 2012)
+
+  28 Nov 2012; Samuli Suominen <ssuominen@g.o>
+  +usb_modeswitch-1.2.5_p20121109.ebuild:
+  Version bump (of both, the program and the data files)
 
   28 Nov 2012; Samuli Suominen <ssuominen@g.o>
   usb_modeswitch-1.2.4_p20120815.ebuild:



1.1                  sys-apps/usb_modeswitch/usb_modeswitch-1.2.5_p20121109.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/usb_modeswitch-1.2.5_p20121109.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/usb_modeswitch/usb_modeswitch-1.2.5_p20121109.ebuild?rev=1.1&content-type=text/plain

Index: usb_modeswitch-1.2.5_p20121109.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/usb_modeswitch/usb_modeswitch-1.2.5_p20121109.ebuild,v 1.1 2012/11/28 23:00:08 ssuominen Exp $

EAPI=5
inherit linux-info toolchain-funcs udev

MY_PN=${PN/_/-}
MY_P=${MY_PN}-${PV/_p*}
DATA_VER=${PV/*_p}

DESCRIPTION="USB_ModeSwitch is a tool for controlling 'flip flop' (multiple devices) USB gear like UMTS sticks"
HOMEPAGE="http://www.draisberghof.de/usb_modeswitch/ http://www.draisberghof.de/usb_modeswitch/device_reference.txt"
SRC_URI="http://www.draisberghof.de/${PN}/${MY_P}.tar.bz2
	http://www.draisberghof.de/${PN}/${MY_PN}-data-${DATA_VER}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

COMMON_DEPEND="virtual/udev
	virtual/libusb:0"
RDEPEND="${COMMON_DEPEND}
	dev-lang/tcl" # usb_modeswitch script is tcl
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"

S=${WORKDIR}/${MY_P}

CONFIG_CHECK="~USB_SERIAL"

src_prepare() {
	# NOTE: This one can be removed once >= kmod-11-r3 is marked stable since it
	# puts modprobe back to /sbin which is already in the search patch earlier.
	sed -i -e 's:/usr/sbin/modprobe:& /usr/bin/modprobe:' ${PN}.tcl || die #416223

	sed -i -e '/install.*BIN/s:-s::' Makefile || die
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		UDEVDIR="${D}/$(udev_get_udevdir)" \
		install

	dodoc ChangeLog README

	pushd ../${MY_PN}-data-${DATA_VER} >/dev/null
	emake \
		DESTDIR="${D}" \
		RULESDIR="${D}/$(udev_get_udevdir)/rules.d" \
		files-install db-install
	docinto data
	dodoc ChangeLog README
	popd >/dev/null
}