[gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-9999.ebuild ChangeLog pulseaudio-1.0-r1.ebuild pulseaudio-1.0.ebuild

[Arun Raghavan (ford_prefect)]

ford_prefect    11/09/28 14:31:56

  Modified:             pulseaudio-9999.ebuild ChangeLog
  Added:                pulseaudio-1.0-r1.ebuild
  Removed:              pulseaudio-1.0.ebuild
  Log:
  Make sure the esound module doesn't break things and some log fixes.
  
  (Portage version: 2.2.0_alpha59/cvs/Linux x86_64)

Revision  Changes    Path
1.14                 media-sound/pulseaudio/pulseaudio-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild?r1=1.13&r2=1.14

Index: pulseaudio-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- pulseaudio-9999.ebuild	27 Sep 2011 13:45:29 -0000	1.13
+++ pulseaudio-9999.ebuild	28 Sep 2011 14:31:56 -0000	1.14
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild,v 1.13 2011/09/27 13:45:29 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-9999.ebuild,v 1.14 2011/09/28 14:31:56 ford_prefect Exp $
 
 EAPI=4
 
@@ -110,7 +110,6 @@
 		$(use_with caps) \
 		$(use_with equalizer fftw) \
 		--localstatedir="${EPREFIX}"/var \
-		--disable-per-user-esound-socket \
 		--with-database=gdbm \
 		--with-udev-rules-dir="${EPREFIX}/lib/udev/rules.d"
 
@@ -187,22 +186,13 @@
 			elog "gconf module on /etc/pulse/system.pa to be able to use PulseAudio"
 			elog "with a system-wide instance."
 		fi
-		elog
-		elog "To use the ESounD wrapper while using a system-wide daemon, you also"
-		elog "need to enable auth-anonymous for the esound-unix module, or to copy"
-		elog "/var/run/pulse/.esd_auth into each home directory."
-		elog
 	fi
 	if use bluetooth; then
 		elog
-		elog "The BlueTooth proximity module is not enabled in the default"
+		elog "The Bluetooth proximity module is not enabled in the default"
 		elog "configuration file. If you do enable it, you'll have to have"
-		elog "your BlueTooth controller enabled and inserted at bootup or"
+		elog "your Bluetooth controller enabled and inserted at bootup or"
 		elog "PulseAudio will refuse to start."
-		elog
-		elog "Please note that the BlueTooth proximity module seems itself"
-		elog "still experimental, so please report to upstream if you have"
-		elog "problems with it."
 	fi
 	if use alsa; then
 		local pkg="media-plugins/alsa-plugins"



1.249                media-sound/pulseaudio/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.249&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.249&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?r1=1.248&r2=1.249

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v
retrieving revision 1.248
retrieving revision 1.249
diff -u -r1.248 -r1.249
--- ChangeLog	27 Sep 2011 13:45:29 -0000	1.248
+++ ChangeLog	28 Sep 2011 14:31:56 -0000	1.249
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/pulseaudio
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.248 2011/09/27 13:45:29 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.249 2011/09/28 14:31:56 ford_prefect Exp $
+
+*pulseaudio-1.0-r1 (28 Sep 2011)
+
+  28 Sep 2011; Arun Raghavan <ford_prefect@g.o> -pulseaudio-1.0.ebuild,
+  +pulseaudio-1.0-r1.ebuild, pulseaudio-9999.ebuild:
+  Make sure the esound module doesn't break things and some log fixes.
 
   27 Sep 2011; Arun Raghavan <ford_prefect@g.o> pulseaudio-1.0.ebuild,
   pulseaudio-9999.ebuild:



1.1                  media-sound/pulseaudio/pulseaudio-1.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-1.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-1.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: pulseaudio-1.0-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-1.0-r1.ebuild,v 1.1 2011/09/28 14:31:56 ford_prefect Exp $

EAPI=4

inherit eutils libtool flag-o-matic versionator

DESCRIPTION="A networked sound server with an advanced plugin system"
HOMEPAGE="http://www.pulseaudio.org/"

SRC_URI="http://freedesktop.org/software/pulseaudio/releases/${P}.tar.xz"

LICENSE="LGPL-2 GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="+alsa avahi +caps equalizer jack lirc oss tcpd +X dbus libsamplerate gnome bluetooth +asyncns +glib test doc +udev ipv6 system-wide realtime +orc"

RDEPEND="app-admin/eselect-esd
	X? (
		>=x11-libs/libX11-1.4.0
		>=x11-libs/libxcb-1.6
		>=x11-libs/xcb-util-0.3.1
		x11-libs/libSM
		x11-libs/libICE
		x11-libs/libXtst
	)
	caps? ( sys-libs/libcap )
	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
	alsa? ( >=media-libs/alsa-lib-1.0.19 )
	glib? ( >=dev-libs/glib-2.4.0 )
	avahi? ( >=net-dns/avahi-0.6.12[dbus] )
	jack? ( >=media-sound/jack-audio-connection-kit-0.117 )
	tcpd? ( sys-apps/tcp-wrappers )
	lirc? ( app-misc/lirc )
	dbus? ( >=sys-apps/dbus-1.0.0 )
	gnome? ( >=gnome-base/gconf-2.4.0 )
	bluetooth? (
		>=net-wireless/bluez-4
		>=sys-apps/dbus-1.0.0
	)
	asyncns? ( net-libs/libasyncns )
	udev? ( || ( >=sys-fs/udev-171[hwdb] >=sys-fs/udev-143[extras] ) )
	realtime? ( sys-auth/rtkit )
	equalizer? ( sci-libs/fftw:3.0 )
	orc? ( >=dev-lang/orc-0.4.9 )
	>=media-libs/audiofile-0.2.6-r1
	>=media-libs/speex-1.2_rc1
	>=media-libs/libsndfile-1.0.20
	sys-libs/gdbm
	dev-libs/json-c
	>=sys-devel/libtool-2.2.4" # it's a valid RDEPEND, libltdl.so is used

DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	X? (
		x11-proto/xproto
		>=x11-libs/libXtst-1.0.99.2
	)
	dev-libs/libatomic_ops
	dev-util/pkgconfig
	system-wide? ( || ( dev-util/unifdef sys-freebsd/freebsd-ubin ) )
	dev-util/intltool"

# alsa-utils dep is for the alsasound init.d script (see bug #155707)
# bluez dep is for the bluetooth init.d script
RDEPEND="${RDEPEND}
	X? ( gnome-extra/gnome-audio )
	system-wide? (
		sys-apps/openrc
		alsa? ( media-sound/alsa-utils )
		bluetooth? ( >=net-wireless/bluez-4 )
	)"

pkg_setup() {
	enewgroup audio 18 # Just make sure it exists
	enewgroup pulse-access
	enewgroup pulse
	enewuser pulse -1 -1 /var/run/pulse pulse,audio
}

src_configure() {
	# It's a binutils bug, once I can find time to fix that I'll add a
	# proper dependency and fix this up. — flameeyes
	append-ldflags $(no-as-needed)

	econf \
		--enable-largefile \
		$(use_enable glib glib2) \
		--disable-solaris \
		$(use_enable asyncns) \
		$(use_enable oss oss-output) \
		$(use_enable alsa) \
		$(use_enable lirc) \
		$(use_enable tcpd tcpwrap) \
		$(use_enable jack) \
		$(use_enable lirc) \
		$(use_enable avahi) \
		--disable-hal \
		$(use_enable dbus) \
		$(use_enable gnome gconf) \
		$(use_enable libsamplerate samplerate) \
		$(use_enable bluetooth bluez) \
		$(use_enable X x11) \
		$(use_enable test default-build-tests) \
		$(use_enable udev) \
		$(use_enable ipv6) \
		$(use_with caps) \
		$(use_with equalizer fftw) \
		--localstatedir="${EPREFIX}"/var \
		--with-database=gdbm \
		--with-udev-rules-dir="${EPREFIX}/lib/udev/rules.d"

	if use doc; then
		pushd doxygen
		doxygen doxygen.conf
		popd
	fi
}

src_test() {
	# We avoid running the toplevel check target because that will run
	# po/'s tests too, and they are broken. Officially, it should work
	# with intltool 0.41, but that doesn't look like a stable release.
	emake -C src check
}

src_install() {
	emake -j1 DESTDIR="${D}" install

	# Drop the script entirely if X is disabled
	use X || rm "${ED}"/usr/bin/start-pulseaudio-x11

	if use system-wide; then
		newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio

		use_define() {
			local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}

			use "$1" && echo "-D$define" || echo "-U$define"
		}

		unifdef $(use_define avahi) \
			$(use_define alsa) \
			$(use_define bluetooth) \
			$(use_define udev) \
			"${FILESDIR}/pulseaudio.init.d-5" \
			> "${T}/pulseaudio"

		doinitd "${T}/pulseaudio"
	fi

	use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${ED}/etc/pulse/default.pa"

	dodoc README todo

	if use doc; then
		pushd doxygen/html
		dohtml *
		popd
	fi

	# Create the state directory
	use prefix || diropts -o pulse -g pulse -m0755
	keepdir /var/run/pulse

	find "${D}" -name '*.la' -delete
}

pkg_postinst() {
	if use system-wide; then
		elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
		elog "This support is enabled by starting the pulseaudio init.d ."
		elog "To be able to access that you need to be in the group pulse-access."
		elog "If you choose to use this feature, please make sure that you"
		elog "really want to run PulseAudio this way:"
		elog "   http://pulseaudio.org/wiki/WhatIsWrongWithSystemMode"
		elog "For more information about system-wide support, please refer to:"
		elog "	 http://pulseaudio.org/wiki/SystemWideInstance"
		if use gnome ; then
			elog
			elog "By enabling gnome USE flag, you enabled gconf support. Please note"
			elog "that you might need to remove the gnome USE flag or disable the"
			elog "gconf module on /etc/pulse/system.pa to be able to use PulseAudio"
			elog "with a system-wide instance."
		fi
	fi
	if use bluetooth; then
		elog
		elog "The Bluetooth proximity module is not enabled in the default"
		elog "configuration file. If you do enable it, you'll have to have"
		elog "your Bluetooth controller enabled and inserted at bootup or"
		elog "PulseAudio will refuse to start."
	fi
	if use alsa; then
		local pkg="media-plugins/alsa-plugins"
		if has_version ${pkg} && ! has_version "${pkg}[pulseaudio]"; then
			elog
			elog "You have alsa support enabled so you probably want to install"
			elog "${pkg} with pulseaudio support to have"
			elog "alsa using applications route their sound through pulseaudio"
		fi
	fi

	eselect esd update --if-unset
}