[gentoo-commits] repo/gentoo:master commit in: dev-db/mydumper/

[Thomas Deutschmann]

commit:     961bb8cc351caed04a4215fe950a9feef2ae7076
Author:     Tomas Mozes <hydrapolic <AT> gmail <DOT> com>
AuthorDate: Tue Oct  2 09:33:09 2018 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Tue Oct  2 09:33:10 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=961bb8cc

dev-db/mydumper: replace virtual/mysql dependency

Closes: https://bugs.gentoo.org/665844
Signed-off-by: Tomáš Mózes <hydrapolic <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/9998
Package-Manager: Portage-2.3.50, Repoman-2.3.11
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 dev-db/mydumper/mydumper-0.9.5-r1.ebuild | 44 ++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

diff --git a/dev-db/mydumper/mydumper-0.9.5-r1.ebuild b/dev-db/mydumper/mydumper-0.9.5-r1.ebuild
new file mode 100644
index 00000000000..a924406ea68
--- /dev/null
+++ b/dev-db/mydumper/mydumper-0.9.5-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="A high-performance multi-threaded backup (and restore) toolset for MySQL"
+HOMEPAGE="https://github.com/maxbube/mydumper"
+SRC_URI="https://github.com/maxbube/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+COMMON_DEPEND="dev-db/mysql-connector-c:=
+	dev-libs/glib:=
+	dev-libs/libpcre:=
+	dev-libs/openssl:=
+	sys-libs/zlib:="
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )"
+RDEPEND="${COMMON_DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-atomic.patch" #654314
+)
+
+src_prepare() {
+	# respect user cflags; do not expand ${CMAKE_C_FLAGS} (!)
+	sed -i -e 's:-Werror -O3 -g:${CMAKE_C_FLAGS}:' CMakeLists.txt || die
+
+	# fix doc install path
+	sed -i -e "s:share/doc/mydumper:share/doc/${PF}:" docs/CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=("-DBUILD_DOCS=$(usex doc)")
+
+	cmake-utils_src_configure
+}