[gentoo-commits] gentoo-x86 commit in media-libs/libquicktime: ChangeLog libquicktime-1.0.2_p20080621.ebuild

[Peter Alfredsen (loki_val)]

loki_val    08/06/21 20:41:43

  Modified:             ChangeLog
  Added:                libquicktime-1.0.2_p20080621.ebuild
  Log:
  Bump to snapshot. Fixes 218101 wrt. libquicktime. Please wait for the correct distfile to propagate.
  (Portage version: 2.2_rc1/cvs/Linux 2.6.23.12-hrt5 i686)

Revision  Changes    Path
1.112                media-libs/libquicktime/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/ChangeLog?rev=1.112&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/ChangeLog?rev=1.112&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/ChangeLog?r1=1.111&r2=1.112

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libquicktime/ChangeLog,v
retrieving revision 1.111
retrieving revision 1.112
diff -u -r1.111 -r1.112
--- ChangeLog	20 Jun 2008 21:59:10 -0000	1.111
+++ ChangeLog	21 Jun 2008 20:41:42 -0000	1.112
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libquicktime
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/ChangeLog,v 1.111 2008/06/20 21:59:10 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/ChangeLog,v 1.112 2008/06/21 20:41:42 loki_val Exp $
+
+*libquicktime-1.0.2_p20080621 (21 Jun 2008)
+
+  21 Jun 2008; Peter Alfredsen <loki_val@g.o>
+  +libquicktime-1.0.2_p20080621.ebuild:
+  Bump to snapshot. Fixes 218101 wrt. libquicktime. Please wait for the
+  correct distfile to propagate.
 
   20 Jun 2008; Alexis Ballier <aballier@g.o>
   libquicktime-1.0.2.ebuild:



1.1                  media-libs/libquicktime/libquicktime-1.0.2_p20080621.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/libquicktime-1.0.2_p20080621.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libquicktime/libquicktime-1.0.2_p20080621.ebuild?rev=1.1&content-type=text/plain

Index: libquicktime-1.0.2_p20080621.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libquicktime/libquicktime-1.0.2_p20080621.ebuild,v 1.1 2008/06/21 20:41:42 loki_val Exp $

inherit libtool eutils

DESCRIPTION="A library based on quicktime4linux with extensions"
HOMEPAGE="http://libquicktime.sourceforge.net/"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

IUSE="mmx X opengl dv gtk alsa aac encode png jpeg vorbis lame x264 ffmpeg doc"

RDEPEND="dv? ( media-libs/libdv )
	gtk? ( >=x11-libs/gtk+-2.4.0 )
	aac? (
		media-libs/faad2
		encode? ( media-libs/faac )
	)
	alsa? ( media-libs/alsa-lib )
	png? ( media-libs/libpng )
	jpeg? ( media-libs/jpeg )
	vorbis? ( media-libs/libvorbis media-libs/libogg )
	lame? ( media-sound/lame )
	ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20080206 )
	x264? ( media-libs/x264 )
	X? ( x11-libs/libXaw
		x11-libs/libXv
		x11-libs/libXext
		x11-libs/libX11
		opengl? ( media-libs/mesa )
	)
	virtual/libintl
	!virtual/quicktime"
DEPEND="${RDEPEND}
	X? (
		x11-proto/videoproto
		x11-proto/xextproto
	)
	doc? ( app-doc/doxygen )
	dev-util/pkgconfig
	sys-devel/gettext"

PROVIDE="virtual/quicktime"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Needed for sane .so versionning on g/fbsd
	elibtoolize
}
src_compile() {
	local MY_OPTS=""
	if use !encode || use !aac; then
		MY_OPTS="--without-faac"
	fi

	econf --enable-shared \
		--enable-static \
		--enable-gpl \
		$(use_with doc doxygen) \
		$(use_enable mmx asm) \
		$(use_with X x) \
		$(use_with gtk) \
		$(use_with dv libdv) \
		$(use_with alsa) \
		$(use_with aac faad2) \
		$(use_with png libpng) \
		$(use_with jpeg libjpeg) \
		$(use vorbis || echo "--without-vorbis") \
		$(use_with lame) \
		$(use_with x264) \
		$(use_with ffmpeg) \
		$(use_with opengl) \
		${MY_OPTS} \
		--without-cpuflags || die "econf failed"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc README TODO ChangeLog
	# Compatibility with software that uses quicktime prefix, but
	# don't do that when building for Darwin/MacOS
	[[ ${CHOST} != *-darwin* ]] && \
	dosym /usr/include/lqt /usr/include/quicktime
}

pkg_preinst() {
	if [[ -d /usr/include/quicktime && ! -L /usr/include/quicktime ]]; then
		elog "For compatibility with other quicktime libraries, ${PN} was"
		elog "going to create a /usr/include/quicktime symlink, but for some"
		elog "reason that is a directory on your system."

		elog "Please check that is empty, and remove it, or submit a bug"
		elog "telling us which package owns the directory."
		die "/usr/include/quicktime is a directory."
	fi
}



-- 
gentoo-commits@l.g.o mailing list