[gentoo-commits] gentoo-x86 commit in x11-wm/fluxbox: ChangeLog fluxbox-1.0.0-r1.ebuild fluxbox-1.0.0-r2.ebuild

[Jim Ramsay (lack)]

lack        08/02/28 15:25:45

  Modified:             ChangeLog fluxbox-1.0.0-r1.ebuild
  Added:                fluxbox-1.0.0-r2.ebuild
  Log:
  Patch for gcc-4.3 compatibility, from bug #211675
  (Portage version: 2.1.4.1)

Revision  Changes    Path
1.246                x11-wm/fluxbox/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/ChangeLog?rev=1.246&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/ChangeLog?rev=1.246&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/ChangeLog?r1=1.245&r2=1.246

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v
retrieving revision 1.245
retrieving revision 1.246
diff -u -r1.245 -r1.246
--- ChangeLog	28 Jan 2008 14:45:11 -0000	1.245
+++ ChangeLog	28 Feb 2008 15:25:44 -0000	1.246
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/fluxbox
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.245 2008/01/28 14:45:11 lack Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.246 2008/02/28 15:25:44 lack Exp $
+
+*fluxbox-1.0.0-r2 (28 Feb 2008)
+
+  28 Feb 2008; Jim Ramsay <lack@g.o> +files/1.0.0/gcc-4.3.patch,
+  fluxbox-1.0.0-r1.ebuild, +fluxbox-1.0.0-r2.ebuild:
+  Patch for gcc-4.3 compatibility, from bug #211675
 
   28 Jan 2008; Jim Ramsay <lack@g.o>
   -files/1.0_rc3/gentoo_style_location.patch, -fluxbox-1.0_rc3_p4983.ebuild:



1.2                  x11-wm/fluxbox/fluxbox-1.0.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/fluxbox-1.0.0-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/fluxbox-1.0.0-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/fluxbox-1.0.0-r1.ebuild?r1=1.1&r2=1.2

Index: fluxbox-1.0.0-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.0.0-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- fluxbox-1.0.0-r1.ebuild	26 Dec 2007 19:27:02 -0000	1.1
+++ fluxbox-1.0.0-r1.ebuild	28 Feb 2008 15:25:44 -0000	1.2
@@ -1,6 +1,6 @@
-# Copyright 1999-2007 Gentoo Foundation
+# Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.0.0-r1.ebuild,v 1.1 2007/12/26 19:27:02 lack Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.0.0-r1.ebuild,v 1.2 2008/02/28 15:25:44 lack Exp $
 
 EAPI=1
 inherit eutils
@@ -59,6 +59,9 @@
 	# A couple menu generation fixes, #199437 and #199439
 	epatch "${FILESDIR}/${PV}/generate-menu.patch"
 
+	# Patch for gcc-4.3, #211675
+	epatch "${FILESDIR}/${PV}/gcc-4.3.patch"
+
 	# Add in the Gentoo -r number to fluxbox -version output.
 	if [[ "${PR}" == "r0" ]] ; then
 		suffix="gentoo"



1.1                  x11-wm/fluxbox/fluxbox-1.0.0-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/fluxbox-1.0.0-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/fluxbox/fluxbox-1.0.0-r2.ebuild?rev=1.1&content-type=text/plain

Index: fluxbox-1.0.0-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.0.0-r2.ebuild,v 1.1 2008/02/28 15:25:44 lack Exp $

EAPI=1
inherit eutils

IUSE="nls xinerama truetype kde gnome imlib +slit +toolbar vim-syntax"

DESCRIPTION="Fluxbox is an X11 window manager featuring tabs and an iconbar"

SRC_URI="mirror://sourceforge/fluxbox/${P}.tar.bz2"
HOMEPAGE="http://www.fluxbox.org"

# Please note that USE="kde gnome" simply adds support for the respective
# protocols, and does not depend on external libraries. They do, however,
# make the binary a fair bit bigger, so we don't want to turn them on unless
# the user actually wants them.

RDEPEND="x11-libs/libXpm
	x11-libs/libXrandr
	xinerama? ( x11-libs/libXinerama )
	x11-apps/xmessage
	virtual/xft
	truetype? ( media-libs/freetype )
	imlib? ( >=media-libs/imlib2-1.2.0 )
	vim-syntax? ( app-vim/fluxbox-syntax )
	!<x11-themes/fluxbox-styles-fluxmod-20040809-r1
	!<=x11-misc/fluxconf-0.9.9
	!<=x11-misc/fbdesk-1.2.1"
DEPEND="nls? ( sys-devel/gettext )
	x11-proto/xextproto
	xinerama? ( x11-proto/xineramaproto )
	${RDEPEND}"
PROVIDE="virtual/blackbox"

SLOT="0"
LICENSE="MIT"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

pkg_setup() {
	if use imlib && ! built_with_use media-libs/imlib2 X ; then
			eerror "To build fluxbox with imlib in USE, you need an X enabled"
			eerror "media-libs/imlib2 . Either recompile imlib2 with the X"
			eerror "USE flag turned on or disable the imlib USE flag for fluxbox."
			die "USE=imlib requires imlib2 with USE=X"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# We need to be able to include directories rather than just plain
	# files in menu [include] items. This patch will allow us to do clever
	# things with style ebuilds.
	epatch "${FILESDIR}/${PV}/gentoo_style_location.patch"

	# A couple menu generation fixes, #199437 and #199439
	epatch "${FILESDIR}/${PV}/generate-menu.patch"

	# Add in the Gentoo -r number to fluxbox -version output.
	if [[ "${PR}" == "r0" ]] ; then
		suffix="gentoo"
	else
		suffix="gentoo-${PR}"
	fi
	sed -i \
		-e "s~\(__fluxbox_version .@VERSION@\)~\1-${suffix}~" \
		version.h.in || die "version sed failed"
}

src_compile() {
	econf \
		$(use_enable nls) \
		$(use_enable xinerama) \
		$(use_enable truetype xft) \
		$(use_enable kde) \
		$(use_enable gnome) \
		$(use_enable imlib imlib2) \
		$(use_enable slit ) \
		$(use_enable toolbar ) \
		--sysconfdir=/etc/X11/${PN} \
		--with-style=/usr/share/fluxbox/styles/Emerge \
		${myconf} || die "configure failed"

	emake || die "make failed"

	ebegin "Creating a menu file (may take a while)"
	mkdir -p "${T}/home/.fluxbox" || die "mkdir home failed"
	MENUFILENAME="${S}/data/menu" MENUTITLE="Fluxbox ${PV}" \
		CHECKINIT="no. go away." HOME="${T}/home" \
		"${S}/util/fluxbox-generate_menu" -is -ds \
		|| die "menu generation failed"
	eend $?
}

src_install() {
	dodir /usr/share/fluxbox
	emake DESTDIR="${D}" install || die "install failed"
	dodoc README* AUTHORS TODO* ChangeLog NEWS

	dodir /usr/share/xsessions
	insinto /usr/share/xsessions
	doins "${FILESDIR}/${PN}.desktop"

	exeinto /etc/X11/Sessions
	newexe "${FILESDIR}/${PN}.xsession" fluxbox

	dodir /usr/share/fluxbox/menu.d

	# Styles menu framework
	dodir /usr/share/fluxbox/menu.d/styles
	insinto /usr/share/fluxbox/menu.d/styles
	doins "${FILESDIR}/styles-menu-fluxbox" || die
	doins "${FILESDIR}/styles-menu-commonbox" || die
	doins "${FILESDIR}/styles-menu-user" || die
}



-- 
gentoo-commits@l.g.o mailing list