[gentoo-commits] gentoo-x86 commit in dev-lang/rubinius: ChangeLog rubinius-2.2.7.ebuild

[Hans de Graaff (graaff)]

graaff      14/06/01 21:20:44

  Modified:             ChangeLog
  Added:                rubinius-2.2.7.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

Revision  Changes    Path
1.13                 dev-lang/rubinius/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rubinius/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rubinius/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rubinius/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/rubinius/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	23 Mar 2014 07:07:45 -0000	1.12
+++ ChangeLog	1 Jun 2014 21:20:44 -0000	1.13
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/rubinius
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/rubinius/ChangeLog,v 1.12 2014/03/23 07:07:45 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/rubinius/ChangeLog,v 1.13 2014/06/01 21:20:44 graaff Exp $
+
+*rubinius-2.2.7 (01 Jun 2014)
+
+  01 Jun 2014; Hans de Graaff <graaff@g.o> +rubinius-2.2.7.ebuild:
+  Version bump.
 
   23 Mar 2014; Hans de Graaff <graaff@g.o>
   rubinius-1.2.4.20110705.ebuild:



1.1                  dev-lang/rubinius/rubinius-2.2.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rubinius/rubinius-2.2.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rubinius/rubinius-2.2.7.ebuild?rev=1.1&content-type=text/plain

Index: rubinius-2.2.7.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/rubinius/rubinius-2.2.7.ebuild,v 1.1 2014/06/01 21:20:44 graaff Exp $

EAPI=5
inherit eutils flag-o-matic multilib versionator

DESCRIPTION="A re-implementation of the Ruby VM designed for speed"
HOMEPAGE="http://rubini.us"
SRC_URI="http://releases.rubini.us/${P}.tar.bz2"

LICENSE="BSD"
KEYWORDS="~amd64"
SLOT="0"
IUSE="+llvm"

RDEPEND="
	llvm? ( >=sys-devel/llvm-3.2 )
	dev-libs/openssl
	sys-libs/ncurses
	sys-libs/readline
	dev-libs/libyaml
	virtual/libffi
	sys-libs/zlib
"

DEPEND="${RDEPEND}
	=dev-ruby/rake-10*
	dev-ruby/bundler
"

pkg_setup() {
	unset RUBYOPT
}

src_prepare() {
	# src_test will wait until all processes are reaped, so tune down
	# the long sleep process a bit.
	sed -i -e 's/sleep 1000/sleep 300/' spec/ruby/core/io/popen_spec.rb || die

	# Drop error CFLAGS per Gentoo policy.
	sed -i -e '/Werror/ s:^:#:' rakelib/blueprint.rb || die

	bundle --local || die
}

src_configure() {
	#Rubinius uses a non-autoconf ./configure script which balks at econf
	INSTALL="${EPREFIX}/usr/bin/install -c" ./configure --skip-prebuilt \
		--prefix /usr/$(get_libdir) \
		--mandir /usr/share/man \
		--without-rpath \
		--with-vendor-zlib \
		$(use_enable llvm) \
		|| die "Configure failed"
}

src_compile() {
	rake build || die "Compilation failed"
}

src_test() {
	rake spec || die "Tests failed"
	einfo "Waiting for forked processes to die"
}

src_install() {
	# The install phase tries to determine if there are relevant
	addpredict /usr/local/lib64/ruby

	local minor_version=$(get_version_component_range 1-2)
	local librbx="usr/$(get_libdir)/rubinius"

	DESTDIR="${D}" rake install || die "Installation failed"

	dosym /${librbx}/${minor_version}/bin/rbx /usr/bin/rbx || die "Couldn't make rbx symlink"

	insinto /${librbx}/${minor_version}/site
	doins "${FILESDIR}/auto_gem.rb" || die "Couldn't install rbx auto_gem.rb"
	RBX_RUNTIME="${S}/runtime" RBX_LIB="${S}/lib" bin/rbx compile "${D}/${librbx}/${minor_version}/site/auto_gem.rb" || die "Couldn't bytecompile auto_gem.rb"
}