[gentoo-commits] repo/gentoo:master commit in: app-admin/gnome-abrt/

[Matt Turner]

commit:     9c333a3bb89790ac2eb3d4798acf1a4114cf8473
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 24 21:46:35 2020 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Aug 24 22:23:44 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9c333a3b

app-admin/gnome-abrt: Version bump to 1.3.6

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 app-admin/gnome-abrt/Manifest                |  1 +
 app-admin/gnome-abrt/gnome-abrt-1.3.6.ebuild | 57 ++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/app-admin/gnome-abrt/Manifest b/app-admin/gnome-abrt/Manifest
index a5c3aff9738..b773b4cb94e 100644
--- a/app-admin/gnome-abrt/Manifest
+++ b/app-admin/gnome-abrt/Manifest
@@ -1 +1,2 @@
 DIST gnome-abrt-1.2.7.tar.gz 339961 BLAKE2B cdacc079c4661c364f13af3102e2231adbeaf4226ba937436f5ce3ae109f28b87c9424c6dfbc016b912599205386f92c32b036ca31adbea79b9a54d7f3a27c4a SHA512 57446b1c1c312f3a47ea3dd2a40ac1d4ec5392df3181eac73086675b65d45cad9a01fba5252d073970878ef97d7d272508bc5b86a56779543ffdc8d083fb5413
+DIST gnome-abrt-1.3.6.tar.gz 112255 BLAKE2B d0e87ef5543e84c246f9e98aac8f92984af9e8220357359ffa76f91e00bb35ccb9b60a00c8e0b00d3464ecfc9ddffaeb61fb15b57480066d957a2af44b49c3be SHA512 7bd15c9956d2e4bafce7d1ef73e930f679119fe8ccebda8a27171a5b3b1dfa90255c572e3a0c70606fe389d50079870399b89f61f683896d4ca6380a7d3f7cc2

diff --git a/app-admin/gnome-abrt/gnome-abrt-1.3.6.ebuild b/app-admin/gnome-abrt/gnome-abrt-1.3.6.ebuild
new file mode 100644
index 00000000000..b9ff00b24a5
--- /dev/null
+++ b/app-admin/gnome-abrt/gnome-abrt-1.3.6.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit meson python-r1
+
+DESCRIPTION="A utility for viewing problems that have occurred with the system"
+HOMEPAGE="https://github.com/abrt/gnome-abrt"
+SRC_URI="https://github.com/abrt/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="doc"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.10.0:3
+	>=dev-libs/libreport-2.0.20[python,${PYTHON_USEDEP}]
+	>=app-admin/abrt-2.10.10-r1
+	>=dev-python/pygobject-3.29.1:3[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.19[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		app-text/asciidoc
+		app-text/xmlto
+	)
+	virtual/pkgconfig
+	>=sys-devel/gettext-0.17
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc docs)
+		-Dlint=false
+	)
+
+	python_foreach_impl meson_src_configure
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_install() {
+	python_foreach_impl meson_src_install
+	python_foreach_impl python_optimize
+}
+
+src_test() {
+	python_foreach_impl meson_src_test
+}