[gentoo-commits] gentoo-x86 commit in dev-libs/icu: ChangeLog icu-4.4.1.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    10/04/29 18:22:54

  Modified:             ChangeLog
  Added:                icu-4.4.1.ebuild
  Log:
  Version bump.
  (Portage version: HEAD/cvs/Linux x86_64)

Revision  Changes    Path
1.107                dev-libs/icu/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/ChangeLog?rev=1.107&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/ChangeLog?rev=1.107&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/ChangeLog?r1=1.106&r2=1.107

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/icu/ChangeLog,v
retrieving revision 1.106
retrieving revision 1.107
diff -u -r1.106 -r1.107
--- ChangeLog	15 Apr 2010 23:31:43 -0000	1.106
+++ ChangeLog	29 Apr 2010 18:22:54 -0000	1.107
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/icu
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/ChangeLog,v 1.106 2010/04/15 23:31:43 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/ChangeLog,v 1.107 2010/04/29 18:22:54 arfrever Exp $
+
+*icu-4.4.1 (29 Apr 2010)
+
+  29 Apr 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  -icu-4.4.ebuild, +icu-4.4.1.ebuild:
+  Version bump.
 
 *icu-4.4-r1 (15 Apr 2010)
 



1.1                  dev-libs/icu/icu-4.4.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/icu-4.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/icu-4.4.1.ebuild?rev=1.1&content-type=text/plain

Index: icu-4.4.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/icu-4.4.1.ebuild,v 1.1 2010/04/29 18:22:54 arfrever Exp $

EAPI="3"

inherit flag-o-matic versionator

MAJOR_MINOR_VERSION="$(get_version_component_range 1-2)"

DESCRIPTION="International Components for Unicode"
HOMEPAGE="http://www.icu-project.org/"

BASE_URI="http://download.icu-project.org/files/icu4c/${PV}"
DOCS_BASE_URI="http://download.icu-project.org/files/icu4c/${MAJOR_MINOR_VERSION}"
SRC_ARCHIVE="icu4c-${PV//./_}-src.tgz"
DOCS_ARCHIVE="icu4c-${MAJOR_MINOR_VERSION//./_}-docs.zip"

SRC_URI="${BASE_URI}/${SRC_ARCHIVE}
	doc? ( ${DOCS_BASE_URI}/${DOCS_ARCHIVE} )"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc examples"

DEPEND="doc? ( app-arch/unzip )"
RDEPEND=""

S="${WORKDIR}/${PN}/source"

QA_DT_NEEDED="/usr/lib.*/libicudata.so.${MAJOR_MINOR_VERSION/./}.0"

src_unpack() {
	unpack "${SRC_ARCHIVE}"
	if use doc; then
		mkdir docs
		pushd docs > /dev/null
		unpack "${DOCS_ARCHIVE}"
		popd > /dev/null
	fi
}

src_prepare() {
	# Do not hardcode used CFLAGS, LDFLAGS etc. into icu-config
	# Bug 202059
	# https://bugs.icu-project.org/trac/ticket/6102
	for x in ARFLAGS CFLAGS CPPFLAGS CXXFLAGS FFLAGS LDFLAGS; do
		sed -i -e "/^${x} =.*/s:@${x}@::" "config/Makefile.inc.in" || die "sed failed"
	done
}

src_configure() {
	econf \
		--enable-static \
		$(use_enable debug) \
		$(use_enable examples samples)
}

src_test() {
	emake check || die "emake check failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dohtml ../readme.html
	dodoc ../unicode-license.txt
	if use doc; then
		insinto /usr/share/doc/${PF}/html/api
		doins -r "${WORKDIR}/docs/"*
	fi
}