[gentoo-commits] repo/gentoo:master commit in: sys-cluster/kronosnet/

[Sam James]

commit:     c5770d163a136f521cdfba187278aca2958514ba
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu May 12 19:25:45 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu May 12 19:26:11 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c5770d16

sys-cluster/kronosnet: add 1.23

Closes: https://bugs.gentoo.org/805359
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-cluster/kronosnet/Manifest              |  1 +
 sys-cluster/kronosnet/kronosnet-1.23.ebuild | 53 +++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/sys-cluster/kronosnet/Manifest b/sys-cluster/kronosnet/Manifest
index c5eb97255671..99424e262803 100644
--- a/sys-cluster/kronosnet/Manifest
+++ b/sys-cluster/kronosnet/Manifest
@@ -1 +1,2 @@
 DIST kronosnet-1.19.tar.xz 461952 BLAKE2B ea6da6c760d73eb3d0b24827d019b479fe2d021f1eea8cb0e0497b390c04b64f99802159e61b1a8b26f38da542cbd52987504cb7c667a9b22ecb53b2fffdf20f SHA512 32b9d7254e9cf5768648aafe5cb019105e247edc1b8a427cc4e655ab4bd9d6a44614f67ba2ac4779f4d11d829d86e6fb8ceb27838dbb44bcefc351db76a41705
+DIST kronosnet-1.23.tar.xz 474048 BLAKE2B 47dd0ddfd59dd25091cffd85950be962747a5f7a6ccecbcdc921f4079a937186a6c3e03f75d8df80bf43441d761420b7d2f9e6fc6dce57f9c61a7ee1c63a2d9c SHA512 b3905affe35e88bed7a4a9e483ad81f46f5514495dd537e14734788933e573c679b8f971f5fef6a023dee852de2bed8250adc34c84e0d70fe4d506dd1782e105

diff --git a/sys-cluster/kronosnet/kronosnet-1.23.ebuild b/sys-cluster/kronosnet/kronosnet-1.23.ebuild
new file mode 100644
index 000000000000..115a30239682
--- /dev/null
+++ b/sys-cluster/kronosnet/kronosnet-1.23.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Network abstraction layer designed for High Availability use cases"
+HOMEPAGE="https://kronosnet.org"
+SRC_URI="https://kronosnet.org/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="doc nss +openssl lz4 lzo2 test zstd"
+RESTRICT="!test? ( test )"
+
+DEPEND=">=sys-cluster/libqb-2.0.0:=
+	dev-libs/libnl:3
+	sys-libs/zlib:=
+	app-arch/bzip2:=
+	app-arch/xz-utils
+	zstd? ( app-arch/zstd:= )
+	lzo2? ( dev-libs/lzo:2 )
+	lz4? ( app-arch/lz4:= )
+	nss? ( dev-libs/nss )
+	openssl? ( dev-libs/openssl:= )"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	doc? (
+		>=sys-cluster/libqb-2.0.0
+		app-doc/doxygen[dot]
+	)"
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable doc man)
+
+		--enable-libnozzle
+		--disable-libknet-sctp
+		--enable-compress-zlib
+		--enable-compress-bzip2
+		--enable-compress-lzma
+
+		$(use_enable nss crypto-nss)
+		$(use_enable openssl crypto-openssl)
+		$(use_enable zstd compress-zstd)
+		$(use_enable lz4 compress-lz4)
+		$(use_enable lzo2 compress-lzo2)
+
+		$(use_enable test functional-tests)
+	)
+
+	econf "${myeconfargs[@]}"
+}