[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-firewall/

[Sam James]

commit:     9c2b446e009b17f3aa6ef9491ea9fe85173414e6
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue May  3 22:38:46 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue May  3 22:41:24 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9c2b446e

kde-plasma/plasma-firewall: 5.24.5 version bump

Signed-off-by: Sam James <sam <AT> gentoo.org>

 kde-plasma/plasma-firewall/Manifest                |  1 +
 .../plasma-firewall/plasma-firewall-5.24.5.ebuild  | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index 5a78bfc32f39..662ce320e994 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.23.5.tar.xz 344132 BLAKE2B 3277329f223f5b4afe33bcf663b8c9f999a8dda4cab593e04d57fb8b2d6d4d899f76f803ca6cc8e3ef718bbcb09f2cb6d24dbaa1c3abcbfa5e163dd791f066ca SHA512 c18b25ad85f57da80edfc03cd445d317162ad2f952fe7ecd09f43af274798acd965de0f8643a636bee74e3572f0ab66f3db876126009b9c98f486a1cfe0e386e
 DIST plasma-firewall-5.24.4.tar.xz 346676 BLAKE2B bbd7e460910b6437c29871814c11c08bb2cb36976a92c70cb7afafbf865d99db73d6ef2c0f0502d990df6c4c72c789f5153ceecd732b2dcb994db330035448d5 SHA512 320066a2339eae7113a3a8b50a01d8ef11c4ba2e9bed48a4f919cae0d1964246ad0beef02f3bc26c8e7ea63214037683552c1004d8b98cfcece52e2ee131b3cc
+DIST plasma-firewall-5.24.5.tar.xz 346660 BLAKE2B 767cd4722325e8035735b744afdccfe4114e68756919f3904fcbd2aa25879b09b7bb4fcaffcaf0a2687f5744e1177fb177658b6af0ed3fef7838498c99f583a3 SHA512 4c774b10c32929399a8b01007e3c34ab702803a0aa80ea812bbcc4d4ead02d0e64136f575454fdc2f0e938740afbf6d48025c654831aa5485b86253418bf13d1

diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.24.5.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.24.5.ebuild
new file mode 100644
index 000000000000..5ac26b7e39d1
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.24.5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+KFMIN=5.90.0
+QTMIN=5.15.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}