[gentoo-commits] gentoo-x86 commit in app-admin/syslog-ng: ChangeLog syslog-ng-2.0.8.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    08/01/31 18:41:36

  Modified:             ChangeLog
  Added:                syslog-ng-2.0.8.ebuild
  Log:
  version bump
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.179                app-admin/syslog-ng/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/syslog-ng/ChangeLog?rev=1.179&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/syslog-ng/ChangeLog?rev=1.179&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/syslog-ng/ChangeLog?r1=1.178&r2=1.179

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v
retrieving revision 1.178
retrieving revision 1.179
diff -u -r1.178 -r1.179
--- ChangeLog	16 Jan 2008 07:45:35 -0000	1.178
+++ ChangeLog	31 Jan 2008 18:41:36 -0000	1.179
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/syslog-ng
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.178 2008/01/16 07:45:35 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.179 2008/01/31 18:41:36 mr_bones_ Exp $
+
+*syslog-ng-2.0.8 (31 Jan 2008)
+
+  31 Jan 2008; Michael Sterrett <mr_bones_@g.o>
+  +syslog-ng-2.0.8.ebuild:
+  version bump
 
   16 Jan 2008; Michael Sterrett <mr_bones_@g.o> -files/syslog-ng.rc6,
   -syslog-ng-1.6.11-r1.ebuild:



1.1                  app-admin/syslog-ng/syslog-ng-2.0.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/syslog-ng/syslog-ng-2.0.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/syslog-ng/syslog-ng-2.0.8.ebuild?rev=1.1&content-type=text/plain

Index: syslog-ng-2.0.8.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/syslog-ng-2.0.8.ebuild,v 1.1 2008/01/31 18:41:36 mr_bones_ Exp $

inherit fixheadtails

MY_PV=${PV/_/}
DESCRIPTION="syslog replacement with advanced filtering features"
HOMEPAGE="http://www.balabit.com/products/syslog_ng/"
SRC_URI="http://www.balabit.com/downloads/files/syslog-ng/sources/2.0/src/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="hardened ipv6 selinux spoof-source static tcpd"

RDEPEND=">=dev-libs/eventlog-0.2
	spoof-source? ( net-libs/libnet )
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
	>=dev-libs/glib-2.2"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/flex"
PROVIDE="virtual/logger"

src_unpack() {
	unpack ${A}
	cd "${S}"
	ht_fix_file configure
	cd "${S}/doc/reference"
	tar xzf syslog-ng.html.tar.gz || die "tar failed"
}

src_compile() {
	econf \
		--sysconfdir=/etc/syslog-ng \
		--disable-dependency-tracking \
		$(use_enable ipv6) \
		$(use_enable !static dynamic-linking) \
		$(use_enable static static-linking) \
		$(use_enable spoof-source) \
		$(use_enable tcpd tcp-wrapper) \
		|| die
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog NEWS README \
		doc/examples/{syslog-ng.conf.sample,syslog-ng.conf.solaris} \
		contrib/syslog-ng.conf* \
		doc/reference/syslog-ng.txt \
		contrib/syslog2ng "${FILESDIR}/syslog-ng.conf."*
	dohtml doc/reference/syslog-ng.html/*

	# Install default configuration
	insinto /etc/syslog-ng
	if use hardened || use selinux ; then
		newins "${FILESDIR}/syslog-ng.conf.gentoo.hardened" syslog-ng.conf
	elif use userland_BSD ; then
		newins "${FILESDIR}/syslog-ng.conf.gentoo.fbsd" syslog-ng.conf
	else
		newins "${FILESDIR}/syslog-ng.conf.gentoo" syslog-ng.conf
	fi

	insinto /etc/logrotate.d
	# Install snippet for logrotate, which may or may not be installed
	if use hardened || use selinux ; then
		newins "${FILESDIR}/syslog-ng.logrotate.hardened" syslog-ng
	else
		newins "${FILESDIR}/syslog-ng.logrotate" syslog-ng
	fi

	newinitd "${FILESDIR}/syslog-ng.rc6-r1" syslog-ng
	newconfd "${FILESDIR}/syslog-ng.confd" syslog-ng
}

pkg_postinst() {
	echo
	elog "It is highly recommended that app-admin/logrotate be emerged to"
	elog "manage the log files.  ${PN} installs a file in /etc/logrotate.d"
	elog "for logrotate to use."
	echo
}



-- 
gentoo-commits@l.g.o mailing list