[gentoo-commits] gentoo-x86 commit in media-gfx/asymptote: ChangeLog asymptote-2.32.ebuild asymptote-2.24.ebuild

[Andrey Grozin (grozin)]

grozin      14/06/05 14:50:33

  Modified:             ChangeLog
  Added:                asymptote-2.32.ebuild
  Removed:              asymptote-2.24.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux i686, signed Manifest commit with key 0x3AFFCE974D34BD8C!)

Revision  Changes    Path
1.109                media-gfx/asymptote/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/asymptote/ChangeLog?rev=1.109&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/asymptote/ChangeLog?rev=1.109&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/asymptote/ChangeLog?r1=1.108&r2=1.109

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/asymptote/ChangeLog,v
retrieving revision 1.108
retrieving revision 1.109
diff -u -r1.108 -r1.109
--- ChangeLog	5 May 2014 10:28:41 -0000	1.108
+++ ChangeLog	5 Jun 2014 14:50:33 -0000	1.109
@@ -1,6 +1,15 @@
 # ChangeLog for media-gfx/asymptote
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/asymptote/ChangeLog,v 1.108 2014/05/05 10:28:41 grozin Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/asymptote/ChangeLog,v 1.109 2014/06/05 14:50:33 grozin Exp $
+
+*asymptote-2.32 (05 Jun 2014)
+
+  05 Jun 2014; Andrey Grozin <grozin@g.o> -asymptote-2.24.ebuild,
+  +asymptote-2.32.ebuild, -files/asymptote-2.24-configure-ac.patch,
+  -files/asymptote-2.24-info.patch, -files/asymptote-2.24-xdg-utils.patch,
+  +files/asymptote-2.32-configure-ac.patch, +files/asymptote-2.32-info.patch,
+  +files/asymptote-2.32-xdg-utils.patch:
+  Version bump. USE-dependent python support switched to python-single-r1.
 
 *asymptote-2.27 (05 May 2014)
 



1.1                  media-gfx/asymptote/asymptote-2.32.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/asymptote/asymptote-2.32.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/asymptote/asymptote-2.32.ebuild?rev=1.1&content-type=text/plain

Index: asymptote-2.32.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/asymptote/asymptote-2.32.ebuild,v 1.1 2014/06/05 14:50:33 grozin Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit eutils autotools elisp-common latex-package multilib python-single-r1

DESCRIPTION="A vector graphics language that provides a framework for technical drawing"
HOMEPAGE="http://asymptote.sourceforge.net/"
SRC_URI="mirror://sourceforge/asymptote/${P}.src.tgz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="+boehm-gc doc emacs examples fftw gsl +imagemagick latex offscreen +opengl python sigsegv svg vim-syntax X"
REQUIRED_USE="offscreen? ( opengl )"

RDEPEND=">=sys-libs/readline-4.3-r5
	>=sys-libs/ncurses-5.4-r5
	imagemagick? ( media-gfx/imagemagick[png] )
	opengl? ( >=media-libs/mesa-8 )
	offscreen? ( media-libs/mesa[osmesa] )
	svg? ( app-text/dvisvgm )
	sigsegv? ( dev-libs/libsigsegv )
	boehm-gc? ( >=dev-libs/boehm-gc-7.0[cxx,threads] )
	fftw? ( >=sci-libs/fftw-3.0.1 )
	gsl? ( sci-libs/gsl )
	python? ( ${PYTHON_DEPS} )
	X? ( x11-misc/xdg-utils ${PYTHON_DEPS} virtual/python-imaging[tk,${PYTHON_USEDEP}] )
	latex? ( virtual/latex-base >=dev-texlive/texlive-latexextra-2013 )
	emacs? ( virtual/emacs )
	vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )"
DEPEND="${RDEPEND}
	doc? ( dev-lang/perl virtual/texi2dvi virtual/latex-base media-gfx/imagemagick[png] )"

TEXMF=/usr/share/texmf-site

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_prepare() {
	# Fixing sigsegv enabling
	epatch "${FILESDIR}/${P}-configure-ac.patch"
	einfo "Patching configure.ac"
	sed -e "s:Datadir/doc/asymptote:Datadir/doc/${PF}:" \
		-i configure.ac \
		|| die "sed configure.ac failed"

	# Changing pdf, ps, image viewers to xdg-open
	epatch "${FILESDIR}/${P}-xdg-utils.patch"

	# Bug #322473
	epatch "${FILESDIR}/${P}-info.patch"

	eautoreconf
}

src_configure() {
	# for the CPPFLAGS see
	# http://sourceforge.net/forum/forum.php?thread_id=1683277&forum_id=409349
	econf CPPFLAGS=-DHAVE_SYS_TYPES_H \
		CFLAGS="${CXXFLAGS}" \
		--disable-gc-debug \
		$(use_enable boehm-gc gc system) \
		$(use_enable fftw) \
		$(use_enable gsl) \
		$(use_enable opengl gl) \
		$(use_enable offscreen) \
		$(use_with sigsegv)
}

src_compile() {
	emake

	cd doc
	emake asy.1
	if use doc; then
		# info
		einfo "Making info"
		emake ${PN}.info
		cd FAQ
		emake
		cd ..
		# pdf
		einfo "Making pdf docs"
		export VARTEXFONTS="${T}"/fonts
		# see bug #260606
		emake -j1 asymptote.pdf
		emake CAD.pdf
	fi
	cd ..

	if use emacs; then
		einfo "Compiling emacs lisp files"
		elisp-compile base/*.el
	fi
}

src_install() {
	# the program
	exeinto /usr/bin
	doexe asy

	# .asy files
	insinto /usr/share/${PN}
	doins base/*.asy

	# documentation
	dodoc BUGS ChangeLog README ReleaseNotes TODO
	doman doc/asy.1

	# X GUI
	if use X; then
		insinto /usr/share/${PN}/GUI
		doins GUI/*.py
		chmod 755 "${ED}"usr/share/${PN}/GUI/xasy.py
		python_fix_shebang "${ED}"usr/share/${PN}/GUI
		dosym /usr/share/${PN}/GUI/xasy.py /usr/bin/xasy
		doman doc/xasy.1x
	fi

	# examples
	if use examples; then
		insinto /usr/share/${PN}/examples
		doins examples/*.asy \
			examples/*.eps \
			doc/*.asy \
			doc/*.csv \
			doc/*.dat \
			doc/extra/*.asy
		if use X; then
			doins GUI/*.asy
		fi
		insinto /usr/share/${PN}/examples/animations
		doins examples/animations/*.asy
	fi

	# LaTeX style
	if use latex; then
		cd doc
		insinto "${TEXMF}"/tex/latex/${PN}
		doins ${PN}.sty asycolors.sty
		if use examples; then
			insinto /usr/share/${PN}/examples
			doins latexusage.tex
		fi
		cd ..
	fi

	# asymptote.py
	if use python; then
		python_moduleinto "$(python_get_sitedir)"
		python_domodule base/${PN}.py
	fi

	# emacs mode
	if use emacs; then
		elisp-install ${PN} base/*.el base/*.elc
		elisp-site-file-install "${FILESDIR}"/64${PN}-gentoo.el
	fi

	# vim syntax
	if use vim-syntax; then
		insinto /usr/share/vim/vimfiles/syntax
		doins base/asy.vim
		insinto /usr/share/vim/vimfiles/ftdetect
		doins "${FILESDIR}"/asy-ftd.vim
	fi

	# extra documentation
	if use doc; then
		cd doc
		doinfo ${PN}.info*
		cd FAQ
		dodoc asy-faq.ascii
		doinfo asy-faq.info
		insinto /usr/share/doc/${PF}/html/FAQ
		doins asy-faq.html/*
		cd ..
		insinto /usr/share/doc/${PF}
		doins ${PN}.pdf CAD.pdf
	fi
}

pkg_postinst() {
	use latex && latex-package_rehash
	use emacs && elisp-site-regen

	elog 'Use the variable ASYMPTOTE_PSVIEWER to set the postscript viewer'
	elog 'Use the variable ASYMPTOTE_PDFVIEWER to set the PDF viewer'
}

pkg_postrm() {
	use latex && latex-package_rehash
	use emacs && elisp-site-regen
}