[gentoo-commits] repo/gentoo:master commit in: media-sound/amsynth/

[Miroslav Šulc]

commit:     200891884c96538c5c9ebb361c715739a346e2d4
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  3 08:23:58 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Mon Jan  3 08:23:58 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=20089188

media-sound/amsynth: bump to 1.12.3

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/amsynth/Manifest              |  1 +
 media-sound/amsynth/amsynth-1.12.3.ebuild | 64 +++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/media-sound/amsynth/Manifest b/media-sound/amsynth/Manifest
index ee25e88819f9..0a84c283309a 100644
--- a/media-sound/amsynth/Manifest
+++ b/media-sound/amsynth/Manifest
@@ -1 +1,2 @@
 DIST amsynth-1.12.2.tar.gz 1607129 BLAKE2B 8308a8a595dfe7b2c9924ff183134fdd5ad20ac2c957b1f52e474a8cb297cd73ee9f8b9938212deb21701e11ccbf776ea22cab763fb71940bf1df5c169e309db SHA512 a1eef3d5a0d0f0ec1edb93d89b3e456ea133a8445a9be73ba338771ae651a2008aea8dd077a9bcf0cd50e6bcc97ad98ab4c44a9baefd9f3381287afdf3325e8f
+DIST amsynth-1.12.3.tar.gz 1624332 BLAKE2B a78317a08c4b02c14578f68fb0fbd7de9380f439c8bc737321c253df5effcd23219ff02d50520768ed5c698b4f284a87435640e965ee4f1cd6023ae770dfd10a SHA512 ac4f32b2a35ebe15c0c63ded213c2ab73bb3a105ce9c857811f095807a1c032dfd518eea5709ea58594c54324bca194236d5fe4606fac274772c9012be2b1110

diff --git a/media-sound/amsynth/amsynth-1.12.3.ebuild b/media-sound/amsynth/amsynth-1.12.3.ebuild
new file mode 100644
index 000000000000..e42fb11b9d12
--- /dev/null
+++ b/media-sound/amsynth/amsynth-1.12.3.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg
+
+DESCRIPTION="Virtual analogue synthesizer"
+HOMEPAGE="https://github.com/amsynth/amsynth"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/release-${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa dssi gtk jack lash lv2 nsm oss vst"
+
+REQUIRED_USE="dssi? ( gtk ) lv2? ( gtk )"
+
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+"
+RDEPEND="
+	alsa? (
+		media-libs/alsa-lib:=
+		media-sound/alsa-utils
+	)
+	dssi? (
+		media-libs/dssi:=
+		media-libs/liblo:=
+	)
+	gtk? (
+		x11-libs/gtk+:2
+		x11-libs/libX11
+	)
+	jack? ( virtual/jack )
+	lash? ( media-sound/lash )
+	lv2? ( media-libs/lv2 )
+"
+DEPEND="${RDEPEND}
+	oss? ( virtual/os-headers )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.12.2-metadata.patch"
+)
+
+src_prepare() {
+	default
+	! use gtk && eapply "${FILESDIR}/${PN}-1.12.2-x11.patch"
+}
+
+src_configure() {
+	econf \
+		$(use_with alsa) \
+		$(use_with dssi) \
+		$(use_with gtk gui) \
+		$(use_with jack) \
+		$(use_with lash) \
+		$(use_with lv2) \
+		$(use_with nsm) \
+		$(use_with oss) \
+		$(use_with vst)
+}