[gentoo-commits] repo/user/ag-ops:master commit in: net-irc/weechat/

[ILMostro]

commit:     e166bd2e68e222e2af2ccb86a41c058487cb9727
Author:     ILMostro <ilmostro7 <AT> gmail <DOT> com>
AuthorDate: Mon Oct 22 03:14:15 2018 +0000
Commit:     ILMostro <ilmostro7 <AT> gmail <DOT> com>
CommitDate: Mon Oct 22 03:14:15 2018 +0000
URL:        https://gitweb.gentoo.org/repo/user/ag-ops.git/commit/?id=e166bd2e

net-irc/weechat: version bump

weechat v2.3 released on 20181021

 net-irc/weechat/weechat-2.3-r2.ebuild | 151 ++++++++++++++++++++++++++++++++++
 1 file changed, 151 insertions(+)

diff --git a/net-irc/weechat/weechat-2.3-r2.ebuild b/net-irc/weechat/weechat-2.3-r2.ebuild
new file mode 100644
index 0000000..43661e9
--- /dev/null
+++ b/net-irc/weechat/weechat-2.3-r2.ebuild
@@ -0,0 +1,151 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,,3_5,3_6} )
+CMAKE_MAKEFILE_GENERATOR=emake
+inherit python-single-r1 cmake-utils
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/weechat/weechat.git"
+else
+	SRC_URI="https://weechat.org/files/src/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86 ~x64-macos"
+fi
+
+DESCRIPTION="Portable and multi-interface IRC client"
+HOMEPAGE="https://weechat.org/"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+NETWORKS="+irc"
+PLUGINS="+alias +buflist +charset +exec +fset +fifo +logger +relay +scripts +spell +trigger +xfer"
+# dev-lang/v8 was dropped from Gentoo so we can't enable javascript support
+SCRIPT_LANGS="guile lua +perl php +python ruby tcl"
+LANGS=" cs de es fr hu it ja pl pt pt_BR ru tr"
+IUSE="doc nls +ssl test ${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS}"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-libs/libgcrypt:0=
+	net-misc/curl[ssl]
+	sys-libs/ncurses:0=
+	sys-libs/zlib
+	charset? ( virtual/libiconv )
+	guile? ( >=dev-scheme/guile-2.0 )
+	lua? ( dev-lang/lua:* )
+	nls? ( virtual/libintl )
+	perl? ( dev-lang/perl:= )
+	php? ( >=dev-lang/php-7.0:* )
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( || ( dev-lang/ruby:2.5 dev-lang/ruby:2.4 dev-lang/ruby:2.3 dev-lang/ruby:2.2 ) )
+	ssl? ( net-libs/gnutls )
+	spell? ( app-text/aspell )
+	tcl? ( >=dev-lang/tcl-8.4.15:0= )
+"
+DEPEND="${RDEPEND}
+	doc? (
+		>=dev-ruby/asciidoctor-1.5.4
+		dev-util/source-highlight
+	)
+	nls? ( >=sys-devel/gettext-0.15 )
+	test? ( dev-util/cpputest )
+"
+
+DOCS="AUTHORS.adoc ChangeLog.adoc Contributing.adoc ReleaseNotes.adoc README.adoc"
+
+# tests need to be fixed to not use system plugins if weechat is already installed
+RESTRICT="test"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.1-tinfo.patch )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# fix libdir placement
+	sed -i \
+		-e "s:lib/:$(get_libdir)/:g" \
+		-e "s:lib\":$(get_libdir)\":g" \
+		CMakeLists.txt || die "sed failed"
+
+	# install only required translations
+	local i
+	for i in ${LANGS} ; do
+		if ! has ${i} ${LINGUAS-${i}} ; then
+			sed -i \
+				-e "/${i}.po/d" \
+				po/CMakeLists.txt || die
+		fi
+	done
+
+	# install only required documentation ; en always
+	for i in $(grep add_subdirectory doc/CMakeLists.txt \
+			| sed -e 's/.*add_subdirectory(\(..\)).*/\1/' -e '/en/d'); do
+		if ! has ${i} ${LINGUAS-${i}} ; then
+			sed -i \
+				-e '/add_subdirectory('${i}')/d' \
+				doc/CMakeLists.txt || die
+		fi
+	done
+
+	# install docs in correct directory
+	sed -i "s#\${SHAREDIR}/doc/\${PROJECT_NAME}#\0-${PV}/html#" doc/*/CMakeLists.txt || die
+
+	if [[ ${CHOST} == *-darwin* ]]; then
+		# fix linking error on Darwin
+		sed -i "s/+ get_config_var('LINKFORSHARED')//" \
+			cmake/FindPython.cmake || die
+		# allow to find the plugins by default
+		sed -i 's/".so,.dll"/".bundle,.so,.dll"/' \
+			src/core/wee-config.c || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_NCURSES=ON
+		-DENABLE_NLS=$(usex nls)
+		-DENABLE_GNUTLS=$(usex ssl)
+		-DENABLE_LARGEFILE=ON
+		-DENABLE_ALIAS=$(usex alias)
+		-DENABLE_ASPELL=$(usex spell)
+		-DENABLE_BUFLIST=$(usex buflist)
+		-DENABLE_CHARSET=$(usex charset)
+		-DENABLE_EXEC=$(usex exec)
+		-DENABLE_FSET=$(usex fset)
+		-DENABLE_FIFO=$(usex fifo)
+		-DENABLE_IRC=$(usex irc)
+		-DENABLE_LOGGER=$(usex logger)
+		-DENABLE_RELAY=$(usex relay)
+		-DENABLE_SCRIPT=$(usex scripts)
+		-DENABLE_SCRIPTS=$(usex scripts)
+		-DENABLE_PERL=$(usex perl)
+		-DENABLE_PHP=$(usex php)
+		-DENABLE_PYTHON=$(usex python)
+		-DENABLE_RUBY=$(usex ruby)
+		-DENABLE_LUA=$(usex lua)
+		-DENABLE_TCL=$(usex tcl)
+		-DENABLE_GUILE=$(usex guile)
+		-DENABLE_JAVASCRIPT=OFF
+		-DENABLE_TRIGGER=$(usex trigger)
+		-DENABLE_XFER=$(usex xfer)
+		-DENABLE_DOC=$(usex doc)
+		-DENABLE_TESTS=$(usex test)
+	)
+
+	if use python; then
+		python_export PYTHON_LIBPATH
+		mycmakeargs+=(
+			-DPYTHON_EXECUTABLE="${PYTHON}"
+			-DPYTHON_LIBRARY="${PYTHON_LIBPATH}"
+		)
+	fi
+
+	cmake-utils_src_configure
+}