[gentoo-commits] gentoo-x86 commit in sci-chemistry/raster3d: ChangeLog raster3d-2.9.2.ebuild

[Justin Lecher (jlec)]

jlec        10/04/02 08:31:46

  Modified:             ChangeLog
  Added:                raster3d-2.9.2.ebuild
  Log:
  Version Bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.19                 sci-chemistry/raster3d/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/raster3d/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/raster3d/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/raster3d/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/raster3d/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	1 Apr 2010 19:58:32 -0000	1.18
+++ ChangeLog	2 Apr 2010 08:31:46 -0000	1.19
@@ -1,6 +1,11 @@
 # ChangeLog for sci-chemistry/raster3d
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/raster3d/ChangeLog,v 1.18 2010/04/01 19:58:32 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/raster3d/ChangeLog,v 1.19 2010/04/02 08:31:46 jlec Exp $
+
+*raster3d-2.9.2 (02 Apr 2010)
+
+  02 Apr 2010; Justin Lecher <jlec@g.o> +raster3d-2.9.2.ebuild:
+  Version Bump
 
   01 Apr 2010; Justin Lecher <jlec@g.o> raster3d-2.9.1.ebuild:
   Fixed Prefix support, #312117



1.1                  sci-chemistry/raster3d/raster3d-2.9.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/raster3d/raster3d-2.9.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/raster3d/raster3d-2.9.2.ebuild?rev=1.1&content-type=text/plain

Index: raster3d-2.9.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/raster3d/raster3d-2.9.2.ebuild,v 1.1 2010/04/02 08:31:46 jlec Exp $

EAPI="3"

inherit fortran flag-o-matic multilib toolchain-funcs versionator

MY_PN="Raster3D"
MY_PV=$(replace_version_separator 2 -)
MY_P="${MY_PN}_${MY_PV}"

DESCRIPTION="A set of tools for generating high quality raster images of proteins or other molecules"
HOMEPAGE="http://www.bmsc.washington.edu/raster3d/raster3d.html"
SRC_URI="http://www.bmsc.washington.edu/${PN}/${MY_P}.tar.gz -> ${MY_P}.tar"

LICENSE="as-is"
SLOT="0"
IUSE=""
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"

RDEPEND="
	media-libs/jpeg
	media-libs/libpng
	media-libs/tiff"
DEPEND="${RDEPEND}"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	epatch "${FILESDIR}"/2.9.1-as-needed.patch
}

src_compile() {
	sed -e "s:prefix  = /usr/local:prefix  = ${EPREFIX}/usr:" \
		-i Makefile.template || \
		die "Failed to patch makefile.template"

	if [[ ${FORTRANC} == gfortran ]]; then
		append-cflags -Dgfortran
	fi

	append-fflags -ffixed-line-length-132

	for target in linux-gfortran all; do
		emake \
			CFLAGS="${CFLAGS}" \
			LDFLAGS="${LDFLAGS}" \
			FFLAGS="${FFLAGS}" \
			CC="$(tc-getCC)"\
			FC="${FORTRANC}" \
			INCDIRS="-I${EPREFIX}"/usr/include \
			LIBDIRS="-L${EPREFIX}"/usr/$(get_libdir) \
			${target} || die
	done
}

src_install() {
	emake prefix="${ED}"/usr \
			bindir="${ED}"/usr/bin \
			datadir="${ED}"/usr/share/Raster3D/materials \
			mandir="${ED}"/usr/share/man/man1 \
			htmldir="${ED}"/usr/share/Raster3D/html \
			examdir="${ED}"/usr/share/Raster3D/examples \
			install || die "Failed to install application."

	dodir /etc/env.d
	echo -e "R3D_LIB=${EPREFIX}/usr/share/${NAME}/materials" > \
		"${ED}"/etc/env.d/10raster3d || \
		die "Failed to install env file."
}

pkg_postinst() {
	elog "Add following line:"
	elog "<delegate decode=\"r3d\" command='\"render\" < \"%i\" > \"%o\"' />"
	elog "to ${EPREFIX}/usr/$(get_libdir)/ImageMagick-6.5.8/config/delegates.xml"
	elog "to make imagemagick use raster3d for .r3d files"
}