[gentoo-commits] gentoo-x86 commit in dev-util/buildbot: ChangeLog buildbot-0.7.6.ebuild buildbot-0.7.4.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    08/02/27 12:39:38

  Modified:             ChangeLog
  Added:                buildbot-0.7.6.ebuild
  Removed:              buildbot-0.7.4.ebuild
  Log:
  Version bump (bug #211540) with some little fixes.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.16                 dev-util/buildbot/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	17 Sep 2007 10:30:13 -0000	1.15
+++ ChangeLog	27 Feb 2008 12:39:38 -0000	1.16
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/buildbot
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.15 2007/09/17 10:30:13 jokey Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.16 2008/02/27 12:39:38 dev-zero Exp $
+
+*buildbot-0.7.6 (27 Feb 2008)
+
+  27 Feb 2008; Tiziano Müller <dev-zero@g.o>
+  -files/buildbot-0.7.4-svn-1.4.patch, -buildbot-0.7.4.ebuild,
+  +buildbot-0.7.6.ebuild:
+  Version bump (bug #211540) with some little fixes.
 
   17 Sep 2007; Markus Ullmann <jokey@g.o> buildbot-0.7.4.ebuild,
   buildbot-0.7.5.ebuild:



1.1                  dev-util/buildbot/buildbot-0.7.6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/buildbot-0.7.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/buildbot/buildbot-0.7.6.ebuild?rev=1.1&content-type=text/plain

Index: buildbot-0.7.6.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/buildbot-0.7.6.ebuild,v 1.1 2008/02/27 12:39:38 dev-zero Exp $

NEED_PYTHON="2.3"

inherit distutils eutils

DESCRIPTION="A Python system to automate the compile/test cycle to validate code changes (similar to Tinderbox, but simpler)"
HOMEPAGE="http://buildbot.net/"
SRC_URI="mirror://sourceforge/buildbot/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="doc irc mail test web"

CDEPEND=">=dev-python/twisted-2.0.1"
RDEPEND="${CDEPEND}
	mail? ( dev-python/twisted-mail )
	irc? ( dev-python/twisted-words )
	web? ( dev-python/twisted-web )"
DEPEND="${CDEPEND}
	test? ( dev-python/twisted-web
		dev-python/twisted-mail )
	doc? ( dev-python/epydoc )"

pkg_setup() {
	enewuser buildbot
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}/${PN}-0.7.5-root-skip-tests.patch"
}

src_compile() {
	distutils_src_compile
	if use doc; then
		PYTHONPATH=. "${python}" docs/epyrun -o docs/reference || \
			die "epyrun failed"
	fi
}

src_test() {
	local trialopts
	if ! has_version ">=dev-python/twisted-2.2"; then
		trialopts=-R
	fi
	PYTHONPATH=. trial ${trialopts} buildbot || die "tests failed!"
}

src_install() {
	distutils_src_install
	doinfo docs/buildbot.info
	dohtml -r docs/buildbot.html docs/images

	insinto /usr/share/doc/${PF}
	doins -r docs/examples

	use doc && doins -r docs/reference

	newconfd "${FILESDIR}/buildslave.confd" buildslave
	newinitd "${FILESDIR}/buildbot.initd" buildslave
	newconfd "${FILESDIR}/buildmaster.confd" buildmaster
	newinitd "${FILESDIR}/buildbot.initd" buildmaster

	# Make it print the right names when you start/stop the script.
	sed -i -e '/ebegin/s/Starting buildbot/Starting buildslave/' \
		"${D}/etc/init.d/buildslave" || die "buildslave sed failed"
	sed -i -e '/ebegin/s/Starting buildbot/Starting buildmaster/' \
		"${D}/etc/init.d/buildmaster" || die "buildmaster sed failed"
}

pkg_postinst() {
	elog 'The "buildbot" user and the "buildmaster" and "buildslave" init'
	elog "scripts were added to support starting buildbot through gentoo's"
	elog "init system.  To use this set up your build master or build slave"
	elog "following the buildbot documentation, make sure the resulting"
	elog 'directories are owned by the "buildbot" user and point'
	elog "${ROOT}etc/conf.d/buildmaster or ${ROOT}etc/conf.d/buildslave"
	elog "at the right location.  The scripts can run as a different user"
	elog "if desired.  If you need to run more than one master or slave"
	elog "just copy the scripts."
	elog ""
	elog "Upstream recommands the following when upgrading:"
	elog "Each time you install a new version of Buildbot, you should run the new"
	elog "'buildbot upgrade-master' command on each of your pre-existing buildmasters."
	elog "This will add files and fix (or at least detect) incompatibilities between"
	elog "your old config and the new code."
}



-- 
gentoo-commits@l.g.o mailing list