[gentoo-commits] gentoo-x86 commit in dev-lang/erlang: erlang-13.2-r1.ebuild ChangeLog

[Christian Faulhammer (fauli)]

fauli       09/04/29 05:59:10

  Modified:             ChangeLog
  Added:                erlang-13.2-r1.ebuild
  Log:
  fix runtime crash with eunit, patch found and reported by Sergey Sinkovskiy <glorybox DOT away AT gmail.com> on bug 267329
  (Portage version: 2.1.6.11/cvs/Linux i686)

Revision  Changes    Path
1.161                dev-lang/erlang/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/erlang/ChangeLog?rev=1.161&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/erlang/ChangeLog?rev=1.161&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/erlang/ChangeLog?r1=1.160&r2=1.161

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/erlang/ChangeLog,v
retrieving revision 1.160
retrieving revision 1.161
diff -u -r1.160 -r1.161
--- ChangeLog	22 Apr 2009 06:57:53 -0000	1.160
+++ ChangeLog	29 Apr 2009 05:59:10 -0000	1.161
@@ -1,6 +1,13 @@
 # ChangeLog for dev-lang/erlang
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/erlang/ChangeLog,v 1.160 2009/04/22 06:57:53 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/erlang/ChangeLog,v 1.161 2009/04/29 05:59:10 fauli Exp $
+
+*erlang-13.2-r1 (29 Apr 2009)
+
+  29 Apr 2009; Christian Faulhammer <fauli@g.o>
+  +files/erlang-13.2-eunit_fix.patch, +erlang-13.2-r1.ebuild:
+  fix runtime crash with eunit, patch found and reported by Sergey Sinkovskiy
+  <glorybox DOT away AT gmail.com> on bug 267329
 
   22 Apr 2009; Christian Faulhammer <fauli@g.o>
   -erlang-13.1-r1.ebuild:



1.1                  dev-lang/erlang/erlang-13.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/erlang/erlang-13.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/erlang/erlang-13.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: erlang-13.2-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/erlang/erlang-13.2-r1.ebuild,v 1.1 2009/04/29 05:59:10 fauli Exp $

EAPI=2

inherit autotools elisp-common eutils flag-o-matic multilib versionator

# NOTE: If you need symlinks for binaries please tell maintainers or
# open up a bug to let it be created.

# erlang uses a really weird versioning scheme which caused quite a few problems
# already. Thus we do a slight modification converting all letters to digits to
# make it more sane (see e.g. #26420)

# the next line selects the right source.
MY_PV="R$(get_major_version)B"

# ATTN!! Take care when processing the C, etc version!
MY_P=otp_src_${MY_PV}

DESCRIPTION="Erlang programming language, runtime environment, and large collection of libraries"
HOMEPAGE="http://www.erlang.org/"
SRC_URI="http://www.erlang.org/download/${MY_P}.tar.gz
	doc? ( http://erlang.org/download/otp_doc_man_${MY_PV}.tar.gz
		http://erlang.org/download/otp_doc_html_${MY_PV}.tar.gz )"

LICENSE="EPL"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="doc emacs hipe java kpoll odbc smp sctp ssl tk wxwindows"

RDEPEND=">=dev-lang/perl-5.6.1
	ssl? ( >=dev-libs/openssl-0.9.7d )
	emacs? ( virtual/emacs )
	java? ( >=virtual/jdk-1.2 )
	odbc? ( dev-db/unixODBC )"
DEPEND="${RDEPEND}
	wxwindows? ( x11-libs/wxGTK:2.8[opengl] )
	sctp? ( net-misc/lksctp-tools )
	tk? ( dev-lang/tk )"

S="${WORKDIR}/${MY_P}"

SITEFILE=50${PN}-gentoo.el

src_prepare() {
	use odbc || sed -i 's: odbc : :' lib/Makefile
	if ! use wxwindows; then
		sed -i 's: wx : :' lib/Makefile
		rm -rf lib/wx
	fi
	# bug 263129, accepted upstream for R13B1
	epatch "${FILESDIR}"/${PN}-13.1-LDFLAGS.patch
	# from upstream
	epatch "${FILESDIR}"/${P}-eunit_fix.patch

	if use hipe; then
		ewarn
		ewarn "You enabled High performance Erlang. Be aware that this extension"
		ewarn "can break the compilation in many ways, especially on hardened systems."
		ewarn "Don't cry, don't file bugs, just disable it! If you have a fix, tell us though on Bugzilla."
		ewarn
	fi
	eautoreconf
}

src_configure() {
	use java || export JAVAC=false

	econf \
		--enable-threads \
		$(use_enable sctp) \
		$(use_enable hipe) \
		$(use_with ssl) \
		$(use_enable ssl dynamic-ssl-lib) \
		$(use_enable kpoll kernel-poll) \
		$(use_enable smp smp-support) \
		|| die
}

src_compile() {
	use java || export JAVAC=false
	emake -j1 || die

	if use emacs ; then
		pushd lib/tools/emacs
		elisp-compile *.el || die
		popd
	fi
}

extract_version() {
	sed -n -e "/^$2 = \(.*\)$/s::\1:p" "${S}/$1/vsn.mk"
}

src_install() {
	local ERL_LIBDIR=/usr/$(get_libdir)/erlang
	local ERL_INTERFACE_VER=$(extract_version lib/erl_interface EI_VSN)
	local ERL_ERTS_VER=$(extract_version erts VSN)

	emake -j1 INSTALL_PREFIX="${D}" install || die
	dodoc AUTHORS README

	dosym "${ERL_LIBDIR}/bin/erl" /usr/bin/erl
	dosym "${ERL_LIBDIR}/bin/erlc" /usr/bin/erlc
	dosym "${ERL_LIBDIR}/bin/escript" /usr/bin/escript
	dosym \
		"${ERL_LIBDIR}/lib/erl_interface-${ERL_INTERFACE_VER}/bin/erl_call" \
		/usr/bin/erl_call
	dosym "${ERL_LIBDIR}/erts-${ERL_ERTS_VER}/bin/beam" /usr/bin/beam

	## Remove ${D} from the following files
	dosed "${ERL_LIBDIR}/bin/erl"
	dosed "${ERL_LIBDIR}/bin/start"
	grep -rle "${D}" "${D}/${ERL_LIBDIR}/erts-${ERL_ERTS_VER}" | xargs sed -i -e "s:${D}::g"

	## Clean up the no longer needed files
	rm "${D}/${ERL_LIBDIR}/Install"

	if use doc ; then
		for i in "${WORKDIR}"/man/man* ; do
			dodir "${ERL_LIBDIR}/${i##${WORKDIR}}"
		done
		for file in "${WORKDIR}"/man/man*/*.[1-9]; do
			# doman sucks so we can't use it
			cp ${file} "${D}/${ERL_LIBDIR}"/man/man${file##*.}/
		done
		# extend MANPATH, so the normal man command can find it
		# see bug 189639
		dodir /etc/env.d/
		echo "MANPATH=\"${ERL_LIBDIR}/man\"" > "${D}/etc/env.d/90erlang"
		dohtml -A README,erl,hrl,c,h,kwc,info -r \
			"${WORKDIR}"/doc "${WORKDIR}"/lib "${WORKDIR}"/erts-*
	fi

	if use emacs ; then
		pushd "${S}"
		elisp-install erlang lib/tools/emacs/*.{el,elc}
		elisp-site-file-install "${FILESDIR}"/${SITEFILE}
		popd
	fi

	# prepare erl for SMP, fixes bug #188112
	use smp && sed -i -e 's:\(exec.*erlexec\):\1 -smp:' \
		"${D}/${ERL_LIBDIR}/bin/erl"
}

pkg_postinst() {
	use emacs && elisp-site-regen
	elog
	elog "If you need a symlink to one of Erlang's binaries,"
	elog "please open a bug on http://bugs.gentoo.org/"
	elog
	elog "Gentoo's versioning scheme differs from the author's, so please refer to this version as ${MY_PV}"
	elog
}

pkg_postrm() {
	use emacs && elisp-site-regen
}