[gentoo-commits] gentoo-x86 commit in net-misc/rsync: ChangeLog rsync-3.0.9.ebuild

[Mike Frysinger (vapier)]

vapier      11/10/30 23:18:05

  Modified:             ChangeLog
  Added:                rsync-3.0.9.ebuild
  Log:
  Version bump #387999 by Kilburn Abrahams.
  
  (Portage version: 2.2.0_alpha71/cvs/Linux x86_64)

Revision  Changes    Path
1.214                net-misc/rsync/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/ChangeLog?rev=1.214&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/ChangeLog?rev=1.214&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/ChangeLog?r1=1.213&r2=1.214

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/rsync/ChangeLog,v
retrieving revision 1.213
retrieving revision 1.214
diff -u -r1.213 -r1.214
--- ChangeLog	2 Apr 2011 14:30:36 -0000	1.213
+++ ChangeLog	30 Oct 2011 23:18:05 -0000	1.214
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/rsync
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/ChangeLog,v 1.213 2011/04/02 14:30:36 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/ChangeLog,v 1.214 2011/10/30 23:18:05 vapier Exp $
+
+*rsync-3.0.9 (30 Oct 2011)
+
+  30 Oct 2011; Mike Frysinger <vapier@g.o> +rsync-3.0.9.ebuild:
+  Version bump #387999 by Kilburn Abrahams.
 
   02 Apr 2011; Raúl Porcel <armin76@g.o> rsync-3.0.8.ebuild:
   alpha/arm/ia64/m68k/s390/sh/sparc stable wrt #360891



1.1                  net-misc/rsync/rsync-3.0.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/rsync-3.0.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rsync/rsync-3.0.9.ebuild?rev=1.1&content-type=text/plain

Index: rsync-3.0.9.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rsync/rsync-3.0.9.ebuild,v 1.1 2011/10/30 23:18:05 vapier Exp $

EAPI="2"

inherit eutils flag-o-matic

DESCRIPTION="File transfer program to keep remote files into sync"
HOMEPAGE="http://rsync.samba.org/"
SRC_URI="http://rsync.samba.org/ftp/rsync/src/${P/_/}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="acl iconv ipv6 static xattr"

DEPEND=">=dev-libs/popt-1.5
	acl? ( virtual/acl )
	xattr? ( kernel_linux? ( sys-apps/attr ) )
	iconv? ( virtual/libiconv )"

S=${WORKDIR}/${P/_/}

src_prepare() {
	epatch_user
}

src_configure() {
	use static && append-ldflags -static
	econf \
		--without-included-popt \
		$(use_enable acl acl-support) \
		$(use_enable xattr xattr-support) \
		$(use_enable ipv6) \
		$(use_enable iconv) \
		--with-rsyncd-conf=/etc/rsyncd.conf \
		|| die
}

src_install() {
	emake DESTDIR="${D}" install || die
	newconfd "${FILESDIR}"/rsyncd.conf.d rsyncd
	newinitd "${FILESDIR}"/rsyncd.init.d rsyncd || die
	dodoc NEWS OLDNEWS README TODO tech_report.tex
	insinto /etc
	doins "${FILESDIR}"/rsyncd.conf || die

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/rsyncd.logrotate rsyncd

	insinto /etc/xinetd.d
	newins "${FILESDIR}"/rsyncd.xinetd rsyncd

	# Install the useful contrib scripts
	exeinto /usr/share/rsync
	doexe support/* || die
	rm -f "${D}"/usr/share/rsync/{Makefile*,*.c}
}

pkg_postinst() {
	if egrep -qis '^[[:space:]]use chroot[[:space:]]*=[[:space:]]*(no|0|false)' \
		"${ROOT}"/etc/rsyncd.conf "${ROOT}"/etc/rsync/rsyncd.conf ; then
		ewarn "You have disabled chroot support in your rsyncd.conf.  This"
		ewarn "is a security risk which you should fix.  Please check your"
		ewarn "/etc/rsyncd.conf file and fix the setting 'use chroot'."
	fi
}