[gentoo-commits] gentoo-x86 commit in x11-wm/wmii: wmii-3.9.2-r2.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    11/12/04 21:40:47

  Modified:             ChangeLog
  Added:                wmii-3.9.2-r2.ebuild
  Log:
  Use system copy of sys-libs/libixp wrt #323037
  
  (Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

Revision  Changes    Path
1.40                 x11-wm/wmii/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/wmii/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	29 May 2011 08:36:05 -0000	1.39
+++ ChangeLog	4 Dec 2011 21:40:47 -0000	1.40
@@ -1,6 +1,11 @@
 # ChangeLog for x11-wm/wmii
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/wmii/ChangeLog,v 1.39 2011/05/29 08:36:05 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/wmii/ChangeLog,v 1.40 2011/12/04 21:40:47 ssuominen Exp $
+
+*wmii-3.9.2-r2 (04 Dec 2011)
+
+  04 Dec 2011; Samuli Suominen <ssuominen@g.o> +wmii-3.9.2-r2.ebuild:
+  Use system copy of sys-libs/libixp wrt #323037
 
   29 May 2011; Kacper Kowalik <xarthisius@g.o> wmii-3.9.2-r1.ebuild:
   Fix underlinking wrt #369115



1.1                  x11-wm/wmii/wmii-3.9.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/wmii-3.9.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/wmii/wmii-3.9.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: wmii-3.9.2-r2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/wmii/wmii-3.9.2-r2.ebuild,v 1.1 2011/12/04 21:40:46 ssuominen Exp $

EAPI=2
inherit flag-o-matic multilib toolchain-funcs

MY_P=wmii+ixp-${PV}

DESCRIPTION="A dynamic window manager for X11"
HOMEPAGE="http://wmii.suckless.org/"
SRC_URI="http://dl.suckless.org/wmii/${MY_P}.tbz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
IUSE=""

COMMON_DEPEND=">=sys-libs/libixp-0.5_p20110208-r2
	x11-libs/libXft
	x11-libs/libXext
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libX11
	x11-libs/libXinerama
	>=media-libs/freetype-2"
RDEPEND="${COMMON_DEPEND}
	x11-apps/xmessage
	x11-apps/xsetroot
	media-fonts/font-misc-misc"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}

MAKEOPTS="${MAKEOPTS} -j1"

pkg_setup() {
	mywmiiconf=(
		PREFIX=/usr
		DOC=/usr/share/doc/${PF}
		ETC=/etc
		LIBDIR=/usr/$(get_libdir)
		CC="$(tc-getCC) -c"
		LD="$(tc-getCC)"
		AR="$(tc-getAR) crs"
		DESTDIR="${D}"
		LIBIXP=/usr/$(get_libdir)/libixp.so
		)
}

src_prepare() {
	# punt internal copy of libixp and update API use wrt #323037
	rm -f include/ixp{,_srvutil}.h || die
	sed -i -e '/libixp/d' Makefile || die

	sed -i -e "/BINSH \!=/d" mk/hdr.mk || die #335083
	sed -i -e 's/-lXext/& -lXrender -lX11/' cmd/Makefile || die #369115
}

src_compile() {
	append-flags -I/usr/include/freetype2
	emake "${mywmiiconf[@]}"
}

src_install() {
	emake "${mywmiiconf[@]}" install
	dodoc NEWS NOTES README TODO

	echo wmii > "${T}"/wmii
	exeinto /etc/X11/Sessions
	doexe "${T}"/wmii

	insinto /usr/share/xsessions
	doins "${FILESDIR}"/${PN}.desktop
}