[gentoo-commits] gentoo-x86 commit in media-video/mkvtoolnix: ChangeLog mkvtoolnix-5.0.0.ebuild

[Tim Harder (radhermit)]

radhermit    11/09/28 20:57:56

  Modified:             ChangeLog
  Added:                mkvtoolnix-5.0.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha59/cvs/Linux x86_64)

Revision  Changes    Path
1.151                media-video/mkvtoolnix/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?rev=1.151&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?rev=1.151&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/ChangeLog?r1=1.150&r2=1.151

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v
retrieving revision 1.150
retrieving revision 1.151
diff -u -r1.150 -r1.151
--- ChangeLog	18 Sep 2011 21:38:46 -0000	1.150
+++ ChangeLog	28 Sep 2011 20:57:56 -0000	1.151
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/mkvtoolnix
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.150 2011/09/18 21:38:46 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/ChangeLog,v 1.151 2011/09/28 20:57:56 radhermit Exp $
+
+*mkvtoolnix-5.0.0 (28 Sep 2011)
+
+  28 Sep 2011; Tim Harder <radhermit@g.o> +mkvtoolnix-5.0.0.ebuild:
+  Version bump.
 
   18 Sep 2011; Markus Meier <maekke@g.o> mkvtoolnix-4.9.1.ebuild:
   x86 stable, bug #381643



1.1                  media-video/mkvtoolnix/mkvtoolnix-5.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-5.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-5.0.0.ebuild?rev=1.1&content-type=text/plain

Index: mkvtoolnix-5.0.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mkvtoolnix/mkvtoolnix-5.0.0.ebuild,v 1.1 2011/09/28 20:57:56 radhermit Exp $

EAPI=4

inherit wxwidgets autotools

DESCRIPTION="Tools to create, alter, and inspect Matroska files"
HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="bzip2 debug lzo pch wxwidgets"

RDEPEND="
	>=dev-libs/libebml-1.2.2
	>=media-libs/libmatroska-1.3.0
	>=dev-libs/boost-1.36.0
	dev-libs/expat
	media-libs/flac
	media-libs/libogg
	media-libs/libvorbis
	sys-apps/file
	sys-libs/zlib
	bzip2? ( app-arch/bzip2 )
	lzo? ( dev-libs/lzo )
	wxwidgets? ( x11-libs/wxGTK:2.8[X] )
"
DEPEND="${RDEPEND}
	dev-ruby/rake
"

src_prepare() {
	# Disable automagic curl dep used for online update checking
	sed -i -e '/curl/d' configure.in
	export CURL_CFLAGS="" CURL_LIBS=""

	eautoreconf
}

src_configure() {
	local myconf

	use pch || myconf="${myconf} --disable-precompiled-headers"

	if use wxwidgets ; then
		WX_GTK_VER="2.8"
		need-wxwidgets unicode
		myconf="${myconf} --with-wx-config=${WX_CONFIG}"
	fi

	econf \
		$(use_enable lzo) \
		$(use_enable bzip2 bz2) \
		$(use_enable wxwidgets) \
		$(use_enable debug) \
		--disable-qt \
		${myconf} \
		--with-boost-regex=boost_regex \
		--with-boost-filesystem=boost_filesystem \
		--with-boost-system=boost_system
}

src_compile() {
	rake || die "rake failed"
}

src_install() {
	# Don't run strip while installing stuff, leave to portage the job.
	DESTDIR="${D}" rake install || die

	dodoc AUTHORS ChangeLog README TODO
	doman doc/man/*.1
}