[gentoo-commits] gentoo-x86 commit in sys-devel/gcc: ChangeLog gcc-4.3.2-r2.ebuild

[Ned Ludd (solar)]

solar       08/12/29 06:10:08

  Modified:             ChangeLog
  Added:                gcc-4.3.2-r2.ebuild
  Log:
  - next phase in pie/hardened work is complete
  (Portage version: 2.1.4.5)

Revision  Changes    Path
1.670                sys-devel/gcc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/ChangeLog?rev=1.670&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/ChangeLog?rev=1.670&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/ChangeLog?r1=1.669&r2=1.670

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/gcc/ChangeLog,v
retrieving revision 1.669
retrieving revision 1.670
diff -u -r1.669 -r1.670
--- ChangeLog	26 Dec 2008 09:11:56 -0000	1.669
+++ ChangeLog	29 Dec 2008 06:10:08 -0000	1.670
@@ -1,6 +1,11 @@
 # ChangeLog for sys-devel/gcc
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/gcc/ChangeLog,v 1.669 2008/12/26 09:11:56 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/gcc/ChangeLog,v 1.670 2008/12/29 06:10:08 solar Exp $
+
+*gcc-4.3.2-r2 (29 Dec 2008)
+
+  29 Dec 2008; <solar@g.o> +gcc-4.3.2-r2.ebuild:
+  - next phase in pie/hardened work is complete
 
 *gcc-4.3.2-r1 (26 Dec 2008)
 



1.1                  sys-devel/gcc/gcc-4.3.2-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/gcc-4.3.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-devel/gcc/gcc-4.3.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: gcc-4.3.2-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/gcc/gcc-4.3.2-r2.ebuild,v 1.1 2008/12/29 06:10:08 solar Exp $

PATCH_VER="1.4"
UCLIBC_VER="1.0"

ETYPE="gcc-compiler"

# Hardened gcc 4 stuff
PIE_VER="10.1.3"
PIE_GCC_VER="4.3.2"
SPECS_VER="0.9.1"
SPECS_GCC_VER="4.3.2"

# arch/libc configurations known to be stable or untested with {PIE,SSP,FORTIFY}-by-default
PIE_GLIBC_STABLE="x86 amd64 ~ppc ~ppc64 ~arm ~sparc"
PIE_UCLIBC_STABLE="x86 arm"
#SSP_STABLE="amd64 x86 ppc ppc64 ~arm ~sparc"
#SSP_UCLIBC_STABLE=""

# whether we should split out specs files for multiple {PIE,SSP}-by-default
# and vanilla configurations.
SPLIT_SPECS=no #${SPLIT_SPECS-true} hard disable until #106690 is fixed

inherit toolchain

DESCRIPTION="The GNU Compiler Collection.  Includes C/C++, java compilers, pie+ssp extensions, Haj Ten Brugge runtime bounds checking"

LICENSE="GPL-2 LGPL-2.1"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"

RDEPEND=">=sys-libs/zlib-1.1.4
	>=sys-devel/gcc-config-1.4
	virtual/libiconv
	>=dev-libs/gmp-4.2.1
	>=dev-libs/mpfr-2.3
	!build? (
		gcj? (
			gtk? (
				x11-libs/libXt
				x11-libs/libX11
				x11-libs/libXtst
				x11-proto/xproto
				x11-proto/xextproto
				>=x11-libs/gtk+-2.2
				x11-libs/pango
			)
			>=media-libs/libart_lgpl-2.1
			app-arch/zip
			app-arch/unzip
		)
		>=sys-libs/ncurses-5.2-r2
		nls? ( sys-devel/gettext )
	)"
DEPEND="${RDEPEND}
	test? ( sys-devel/autogen dev-util/dejagnu )
	>=sys-apps/texinfo-4.2-r4
	>=sys-devel/bison-1.875
	amd64? (
		>=sys-libs/glibc-2.7-r2
		multilib? (
			gcj? ( app-emulation/emul-linux-x86-xlibs )
		)
	)
	ppc? ( >=${CATEGORY}/binutils-2.17 )
	ppc64? ( >=${CATEGORY}/binutils-2.17 )
	>=${CATEGORY}/binutils-2.15.94"
PDEPEND=">=sys-devel/gcc-config-1.4"
if [[ ${CATEGORY} != cross-* ]] ; then
	PDEPEND="${PDEPEND} elibc_glibc? ( >=sys-libs/glibc-2.6 )"
fi

src_unpack() {
	gcc_src_unpack

	use vanilla && return 0

	[[ ${CHOST} == ${CTARGET} ]] && epatch "${FILESDIR}"/gcc-spec-env.patch

	[[ ${CTARGET} == *-softfloat-* ]] && epatch "${FILESDIR}"/4.3.2/gcc-4.3.2-softfloat.patch
}